add: midround space wizards!

code/game/gamemodes/wizard/spellbook.dm

@@ -753,7 +753,7 @@
 	var/entry_types = subtypesof(/datum/spellbook_entry) - /datum/spellbook_entry/item - /datum/spellbook_entry/summon - /datum/spellbook_entry/loadout
 	for(var/T in entry_types)
 		var/datum/spellbook_entry/E = new T
-		if(GAMEMODE_IS_RAGIN_MAGES && E.is_ragin_restricted)
+		if((GAMEMODE_IS_RAGIN_MAGES || (GLOB.wizard_events_triggered > 0)) && E.is_ragin_restricted)
 			qdel(E)
 			continue
 		entries |= E

code/modules/events/event_container.dm

@@ -249,6 +249,7 @@ GLOBAL_LIST_EMPTY(event_last_fired)
 		new /datum/event_meta(EVENT_LEVEL_MAJOR, "Теневой Демон", /datum/event/spawn_slaughter/shadow,	20, 	is_one_shot = TRUE),
 		//new /datum/event_meta(EVENT_LEVEL_MAJOR, "Floor Cluwne",	/datum/event/spawn_floor_cluwne,	15, is_one_shot = TRUE)
 		new /datum/event_meta(EVENT_LEVEL_MAJOR, "Космический Дракон", /datum/event/space_dragon, 20, 						list(ASSIGNMENT_SECURITY = 4), TRUE),
+		new /datum/event_meta(EVENT_LEVEL_MAJOR, "Рейд ФКВ",		/datum/event/space_wizards,		30,						list(ASSIGNMENT_SECURITY = 5), TRUE),
 	)
 
 

code/modules/events/wizards.dm

@@ -0,0 +1,44 @@
+#define MINIMUM_CREW_REQ 10
+#define CREW_PER_WIZARD 30
+GLOBAL_VAR_INIT(wizard_events_triggered, 0)
+/datum/event/space_wizards
+	name = "Рейд ФКВ"
+	var/mages_made
+
+/datum/event/space_wizards/start()
+	INVOKE_ASYNC(src, PROC_REF(wrappedstart))
+
+/datum/event/space_wizards/proc/get_wizards_number()
+	if(num_station_players() <= MINIMUM_CREW_REQ)
+		return 0
+
+	return floor(num_station_players() / CREW_PER_WIZARD) || 1 //every mage each 30 crew
+
+
+/datum/event/space_wizards/proc/wrappedstart()
+	var/mages_number = get_wizards_number()
+
+	if(mages_number < 1)
+		log_and_message_admins("Warning: Could not spawn any mobs for event Wizard Raid. Reason - not enough players.")
+		var/datum/event_container/EC = SSevents.event_containers[EVENT_LEVEL_MAJOR]
+		EC.next_event_time = world.time + (60 SECONDS)
+		return
+
+	var/image/source = image('icons/obj/cardboard_cutout.dmi', "cutout_wizard")
+	var/list/mob/dead/observer/candidates = SSghost_spawns.poll_candidates("Do you want to play as a Space Wizard?", ROLE_WIZARD, TRUE, poll_time = 60 SECONDS, source = source)
+	if(!candidates.len)
+		log_and_message_admins("Warning: Could not spawn any mobs for event Wizard Raid. Reason - not enough candidates.")
+		var/datum/event_container/EC = SSevents.event_containers[EVENT_LEVEL_MAJOR]
+		EC.next_event_time = world.time + (60 SECONDS)
+
+	while(mages_number && length(candidates))
+		var/mob/new_mage = pick_n_take(candidates)
+		if(new_mage)
+			GLOB.wizard_events_triggered += 1
+			var/mob/living/carbon/human/new_character= makeBody(new_mage)
+			new_character.mind.make_Wizard() // This puts them at the wizard spawn, worry not
+			mages_number--
+			log_game("Spawned [new_character] (ckey: [new_character.key]) as midround Wizard.")
+
+#undef MINIMUM_CREW_REQ
+#undef CREW_PER_WIZARD

paradise.dme

@@ -2053,6 +2053,7 @@
 #include "code\modules\events\undead.dm"
 #include "code\modules\events\vent_clog.dm"
 #include "code\modules\events\wallrot.dm"
+#include "code\modules\events\wizards.dm"
 #include "code\modules\events\wormholes.dm"
 #include "code\modules\events\wizard\ghost.dm"
 #include "code\modules\fish\fish_eggs.dm"