Add more supported languages

Cargo.toml

@@ -55,6 +55,18 @@ tower-layer = "0.3"
 tower-service = "0.3"
 tracing = "0.1"
 tracing-subscriber = { version = "0.3", features = ["env-filter"] }
+tree-sitter-bash = "0.23"
+tree-sitter-c = "0.23"
+tree-sitter-cpp = "0.23"
+tree-sitter-c-sharp = "0.23"
+tree-sitter-elixir = "0.3"
+tree-sitter-go = "0.23"
+tree-sitter-php = "0.23"
+tree-sitter-json = "0.23"
+tree-sitter-ocaml = "0.23"
+tree-sitter-python = "0.23"
+tree-sitter-regex = "0.23"
+tree-sitter-ruby = "0.23"
 tree-sitter-css = "0.23"
 tree-sitter-fortran = "0.1"
 tree-sitter-haskell = "0.23"

grammar/fortran/highlights.scm

@@ -0,0 +1,197 @@
+(identifier) @variable
+(string_literal) @string
+(number_literal) @number
+(boolean_literal) @boolean
+(comment) @comment
+
+[
+ (intrinsic_type)
+ "allocatable"
+ "attributes"
+ "device"
+ "dimension"
+ "endtype"
+ "global"
+ "grid_global"
+ "host"
+ "import"
+ "in"
+ "inout"
+ "intent"
+ "optional"
+ "out"
+ "pointer"
+ "type"
+ "value"
+ ] @type
+
+[
+ "contains"
+ "private"
+ "public"
+ ] @include
+
+[
+ (none)
+ "implicit"
+ ] @attribute
+
+[
+ "endfunction"
+ "endprogram"
+ "endsubroutine"
+ "function"
+ "procedure"
+ "subroutine"
+ ] @keyword.function
+
+[
+ (default)
+ (procedure_qualifier)
+ "abstract"
+ "bind"
+ "call"
+ "class"
+ "continue"
+ "cycle"
+ "endenum"
+ "endinterface"
+ "endmodule"
+ "endprocedure"
+ "endprogram"
+ "endsubmodule"
+ "enum"
+ "enumerator"
+ "equivalence"
+ "exit"
+ "extends"
+ "format"
+ "goto"
+ "include"
+ "interface"
+ "intrinsic"
+ "non_intrinsic"
+ "module"
+ "namelist"
+ "only"
+ "parameter"
+ "print"
+ "procedure"
+ "program"
+ "read"
+ "stop"
+ "submodule"
+ "use"
+ "write"
+ ] @keyword
+
+"return" @keyword.return
+
+[
+ "else"
+ "elseif"
+ "elsewhere"
+ "endif"
+ "endwhere"
+ "if"
+ "then"
+ "where"
+ ] @conditional
+
+[
+ "do"
+ "enddo"
+ "forall"
+ "while"
+ ] @repeat
+
+[
+ "*"
+ "+"
+ "-"
+ "/"
+ "="
+ "<"
+ ">"
+ "<="
+ ">="
+ "=="
+ "/="
+ ] @operator
+
+[
+ "\\.and\\."
+ "\\.or\\."
+ "\\.lt\\."
+ "\\.gt\\."
+ "\\.ge\\."
+ "\\.le\\."
+ "\\.eq\\."
+ "\\.eqv\\."
+ "\\.neqv\\."
+ ] @keyword.operator
+
+;; Brackets
+[
+ "("
+ ")"
+ "["
+ "]"
+ "<<<"
+ ">>>"
+ ] @punctuation.bracket
+
+;; Delimiter
+[
+ "::"
+ ","
+ "%"
+ ] @punctuation.delimiter
+
+(parameters
+  (identifier) @parameter)
+
+(program_statement
+  (name) @namespace)
+
+(module_statement
+  (name) @namespace)
+
+(submodule_statement
+  (module_name) (name) @namespace)
+
+(function_statement
+  (name) @function)
+
+(subroutine_statement
+  (name) @function)
+
+(module_procedure_statement
+  (name) @function)
+
+(end_program_statement
+  (name) @namespace)
+
+(end_module_statement
+  (name) @namespace)
+
+(end_submodule_statement
+  (name) @namespace)
+
+(end_function_statement
+  (name) @function)
+
+(end_subroutine_statement
+  (name) @function)
+
+(end_module_procedure_statement
+  (name) @function)
+
+(subroutine_call
+  (identifier) @function)
+
+(keyword_argument
+  name: (identifier) @keyword)
+
+(derived_type_member_expression
+  (type_member) @property)