feat: Unathi racial medical drugs (#734)

# Описание

ПР делает что-то умное во славу Лиги!
- Присвоение имени яду йоза'унати
- Добавление двух новых реагентов, использующих в составе яд йоза

## Основные изменения

* Яд йоза теперь называется Esh Hashaar Haashane
* Добавлены новые медикаменты - Paashe Meish Sunn и Arhishaap, по
рецептам йоза'унати

## Changelog

<!-- С помощью этого раздела можно подготовить список изменений, которые
попадут в игровой чейндж-лог. --->
<!-- Вам нужно указать префикс изменения (Он идёт до двоеточия) и дать
описание, как на примере. --->
<!-- Префиксы можно использовать несколько раз. --->
<!-- Если Вы не планируете добавлять записи в чейндж-лог - просто
удалите из пулл-реквеста этот раздел. --->

:cl: UEDHighCommand
tweak: Yeosa venom now know as Esh Hashaar Haashane
rscadd: Added new medical drugs - Paashe Meish Sunn and Arhishaap, of
Unathi origin
/:cl:

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Medicine.dm

@@ -1056,3 +1056,74 @@
 	..()
 	M.add_chemical_effect(CE_TOXIN, 1)
 	M.immunity -= 0.5 //inverse effects when abused
+
+	// Unathi reagents
+/datum/reagent/paashe
+	name = "Paashe Meish Sunn"
+	description = "An effective natural painkiller, produced from Yeosa'Unathi innate venom. Has similar effect to Tramadol, but doesn't feature any significant side effects."
+	taste_description = "way too much sweetness"
+	reagent_state = LIQUID
+	color = "#aea0c9"
+	overdose = 30
+	scannable = 1
+	metabolism = 0.05
+	ingest_met = 0.02
+	flags = IGNORE_MOB_SIZE
+	value = 3.1
+	var/pain_power = 80 //magnitide of painkilling effect
+	var/effective_dose = 0.5 //how many units it need to process to reach max power
+
+/datum/reagent/paashe/affect_blood(var/mob/living/carbon/M, var/alien, var/removed)
+	var/effectiveness = 1
+	if(M.chem_doses[type] < effective_dose) //some ease-in ease-out for the effect
+		effectiveness = M.chem_doses[type]/effective_dose
+	else if(volume < effective_dose)
+		effectiveness = volume/effective_dose
+	M.add_chemical_effect(CE_PAINKILLER, pain_power * effectiveness)
+	if(M.chem_doses[type] > 0.5 * overdose)
+		M.add_chemical_effect(CE_SLOWDOWN, 1)
+		if(prob(1))
+			M.slurring = max(M.slurring, 10)
+	if(M.chem_doses[type] > 0.75 * overdose)
+		M.add_chemical_effect(CE_SLOWDOWN, 1)
+		if(prob(5))
+			M.slurring = max(M.slurring, 20)
+	if(M.chem_doses[type] > overdose)
+		M.add_chemical_effect(CE_SLOWDOWN, 1)
+		M.slurring = max(M.slurring, 30)
+		if(prob(1))
+			M.Weaken(2)
+			M.drowsyness = max(M.drowsyness, 5)
+
+/datum/reagent/arhishaap
+	name = "Arhishaap"
+	description = "An advanced Yeosa'Unathi anti-toxin, significantly more effective than synthetic alternatives."
+	taste_description = "way too much sweetness"
+	reagent_state = LIQUID
+	color = "#49bc4b"
+	scannable = 1
+	flags = IGNORE_MOB_SIZE
+	value = 2.1
+	var/remove_generic = 1
+	var/list/remove_toxins = list(
+		/datum/reagent/toxin/zombiepowder
+	)
+
+/datum/reagent/arhishaap/affect_blood(var/mob/living/carbon/M, var/alien, var/removed)
+	M.radiation = max(M.radiation - 30 * removed, 0)
+
+	if(remove_generic)
+		M.drowsyness = max(0, M.drowsyness - 10 * removed)
+		M.adjust_hallucination(-14 * removed)
+		M.add_up_to_chemical_effect(CE_ANTITOX, 1)
+
+	var/removing = (8 * removed)
+	var/datum/reagents/ingested = M.get_ingested_reagents()
+	for(var/datum/reagent/R in ingested.reagent_list)
+		if((remove_generic && istype(R, /datum/reagent/toxin)) || (R.type in remove_toxins))
+			ingested.remove_reagent(R.type, removing)
+			return
+	for(var/datum/reagent/R in M.reagents.reagent_list)
+		if((remove_generic && istype(R, /datum/reagent/toxin)) || (R.type in remove_toxins))
+			M.reagents.remove_reagent(R.type, removing)
+			return

code/modules/reagents/Chemistry-Reagents/Chemistry-Reagents-Toxins.dm

@@ -77,7 +77,7 @@
 	strength = 10
 
 /datum/reagent/toxin/yeosvenom
-	name = "Yeosa'Unathi Venom"
+	name = "Esh Hashaar Haashane"
 	description = "A non-lethal toxin produced by Yeosa'Unathi"
 	taste_description = "absolutely vile"
 	color = "#91d895"

code/modules/reagents/Chemistry-Recipes.dm

@@ -478,6 +478,26 @@
 	required_reagents = list(/datum/reagent/inaprovaline = 1, /datum/reagent/hyperzine = 1, /datum/reagent/dexalinp = 1)
 	result_amount = 3
 
+/* Unathi reagents reactions */
+/datum/chemical_reaction/paashe
+	name = "Paashe Meish Sunn"
+	result = /datum/reagent/paashe
+	required_reagents = list(/datum/reagent/toxin/yeosvenom = 1, /datum/reagent/ethanol = 1, /datum/reagent/acetone = 1)
+	result_amount = 3
+
+/datum/chemical_reaction/arhishaap
+	name = "Arhishaap"
+	result = /datum/reagent/arhishaap
+	required_reagents = list(/datum/reagent/toxin/yeosvenom = 1, /datum/reagent/diethylamine = 2, /datum/reagent/radium = 1)
+	result_amount = 4
+
+/datum/chemical_reaction/oxycodonealt
+	name = "Oxycodone Alt"
+	result = /datum/reagent/tramadol/oxycodone
+	required_reagents = list(/datum/reagent/ethanol = 1, /datum/reagent/paashe = 1)
+	catalysts = list(/datum/reagent/toxin/phoron = 5)
+	result_amount = 1
+
 /* Solidification */
 /datum/chemical_reaction/phoronsolidification
 	name = "Solid Phoron"