Add nix flake (#183)

README.md

@@ -189,6 +189,34 @@ The `zwift.sh` script will update zwift by checking for new image versions on ev
 
 There is a github action in place that will update zwift on a scheduled basis and publish new versions to docker hub.
 
+## How can I install this on NixOS?
+
+To use the NixOS module, configure your flake.nix:
+
+```nix
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    zwift.url = "github:netbrain/zwift";
+  };
+
+  outputs = { nixpkgs, zwift, ... }: {
+    nixosConfigurations."«hostname»" = nixpkgs.lib.nixosSystem {
+      system = "x86_64-linux";
+      modules = [ zwift.nixosModules.zwift ./configuration.nix ];
+    };
+  };
+}
+```
+
+Then enable the module in your NixOS configuration:
+
+```nix
+{
+  programs.zwift.enable = true;
+}
+```
+
 ## Sponsors 💖
 
 These are our really cool sponsors!

flake.nix

@@ -0,0 +1,48 @@
+{
+  description = "Easily zwift on linux";
+
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+
+  outputs =
+    { nixpkgs, self }:
+    let
+      pkgs = nixpkgs.legacyPackages.x86_64-linux;
+    in
+    {
+      nixosModules = {
+        zwift =
+          { config, lib, ... }:
+          {
+            options.programs.zwift.enable = lib.mkEnableOption "zwift on linux";
+
+            config = lib.mkIf config.programs.zwift.enable {
+              virtualisation.podman.enable = true;
+              environment.systemPackages = [ self.packages.x86_64-linux.zwift ];
+            };
+          };
+        default = self.nixosModules.zwift;
+      };
+
+      packages.x86_64-linux = {
+        zwift = pkgs.stdenv.mkDerivation rec {
+          pname = "zwift";
+          version = "0-unstable";
+
+          src = ./.;
+
+          nativeBuildInputs = [ pkgs.copyDesktopItems ];
+
+          installPhase = ''
+            runHook preInstall
+            install -Dm755 zwift.sh -T $out/bin/${pname}
+            install -Dm644 $src/assets/hicolor/scalable/apps/Zwift\ Logogram.svg \
+              -T $out/share/icons/hicolor/scalable/apps/zwift.svg
+            runHook postInstall
+          '';
+
+          desktopItems = [ "assets/Zwift.desktop" ];
+        };
+        default = self.packages.x86_64-linux.zwift;
+      };
+    };
+}