Issue2180 boiler plant main controller oct 2021

Buildings/Applications/DataCenters/ChillerCooled/Examples/BaseClasses/PartialDataCenter.mo

@@ -171,18 +171,15 @@ partial model PartialDataCenter
     annotation (Placement(transformation(extent={{10,-10},{-10,10}},
         rotation=90,
         origin={-50,-150})));
-  Buildings.Examples.ChillerPlant.BaseClasses.SimplifiedRoom roo(
+  Buildings.Examples.ChillerPlants.DataCenter.BaseClasses.SimplifiedRoom roo(
     redeclare replaceable package Medium = MediumA,
     rooLen=50,
     rooWid=30,
     rooHei=3,
     m_flow_nominal=mAir_flow_nominal,
     QRoo_flow=500000,
-    nPorts=2)
-    "Room model"
-    annotation (Placement(transformation(
-        extent={{10,-10},{-10,10}},
-        origin={4,-180})));
+    nPorts=2) "Room model" annotation (Placement(transformation(extent={{10,-10},
+            {-10,10}}, origin={4,-180})));
   Buildings.Fluid.Actuators.Valves.TwoWayLinear val[numChi](
     redeclare each package Medium = MediumW,
     each m_flow_nominal=m1_flow_chi_nominal,

Buildings/Applications/DataCenters/DXCooled/Examples/DXCooledAirsideEconomizer.mo

@@ -38,7 +38,7 @@ model DXCooledAirsideEconomizer
   parameter Real minSpeFan = 0.2
     "Minimum fan speed ratio required by variable speed fans";
 
-  Buildings.Examples.ChillerPlant.BaseClasses.SimplifiedRoom roo(
+  Buildings.Examples.ChillerPlants.DataCenter.BaseClasses.SimplifiedRoom roo(
     redeclare package Medium = Medium,
     rooLen=50,
     rooHei=3,

Buildings/Controls/OBC/ASHRAE/PrimarySystem/BoilerPlant/BypassValve/BypassValvePosition.mo

@@ -0,0 +1,194 @@
+within Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve;
+block BypassValvePosition
+  "Sequence for controlling minimum flow bypass valve position"
+
+  parameter Integer nPum = 2
+    "Number of pumps";
+
+  parameter Buildings.Controls.OBC.CDL.Types.SimpleController controllerType= Buildings.Controls.OBC.CDL.Types.SimpleController.PI
+    "Type of controller";
+
+  parameter Real k(
+    final min=0,
+    final unit="1",
+    displayUnit="1") = 1
+    "Gain of controller";
+
+  parameter Real Ti(
+    final min=0,
+    final unit="s",
+    displayUnit="s",
+    final quantity="time") = 0.5
+    "Time constant of integrator block";
+
+  parameter Real Td(
+    final min=0,
+    final unit="s",
+    displayUnit="s",
+    final quantity="time") = 0.1
+    "Time constant of derivative block";
+
+  Buildings.Controls.OBC.CDL.Interfaces.BooleanInput uPumSta[nPum]
+    "Input signals indicating pump statuses"
+    annotation (Placement(transformation(extent={{-140,-20},{-100,20}}),
+      iconTransformation(extent={{-140,-40},{-100,0}})));
+
+  Buildings.Controls.OBC.CDL.Interfaces.RealInput VHotWat_flow(
+    final unit="m3/s",
+    displayUnit="m3/s",
+    final quantity="VolumeFlowRate")
+    "Measured hot-water flow-rate through primary circuit"
+    annotation (Placement(transformation(extent={{-140,20},{-100,60}}),
+      iconTransformation(extent={{-140,0},{-100,40}})));
+
+  Buildings.Controls.OBC.CDL.Interfaces.RealInput VHotWatMinSet_flow(
+    final unit="m3/s",
+    displayUnit="m3/s",
+    final quantity="VolumeFlowRate")
+    "Calculated hot water minimum flow setpoint through boilers"
+    annotation (Placement(transformation(extent={{-140,60},{-100,100}}),
+      iconTransformation(extent={{-140,40},{-100,80}})));
+
+  Buildings.Controls.OBC.CDL.Interfaces.RealInput uMinBypValPos(
+    final unit="1",
+    displayUnit="1",
+    final min=0)
+    "Minimum bypass valve position for condensation control in non-condensing boilers"
+    annotation (Placement(transformation(extent={{-140,-80},{-100,-40}}),
+      iconTransformation(extent={{-140,-80},{-100,-40}})));
+
+  Buildings.Controls.OBC.CDL.Interfaces.RealOutput yBypValPos(
+    final unit="1",
+    displayUnit="1",
+    final min=0)
+    "Bypass valve opening position"
+    annotation (Placement(transformation(extent={{100,-50},{140,-10}}),
+      iconTransformation(extent={{100,-20},{140,20}})));
+
+protected
+  Buildings.Controls.OBC.CDL.Continuous.Subtract sub2
+    "Difference between measured flowrate and minimum flow setpoint"
+    annotation (Placement(transformation(extent={{-70,30},{-50,50}})));
+
+  Buildings.Controls.OBC.CDL.Logical.MultiOr mulOr(
+    final nin=nPum)
+    "Block to detect if any of the pumps are proved ON"
+    annotation (Placement(transformation(extent={{-70,-10},{-50,10}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Divide div
+    "Normalize measured hot water flowrate"
+    annotation (Placement(transformation(extent={{-20,30},{0,50}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Sources.Constant con(
+    final k=0)
+    "Constant Real source"
+    annotation (Placement(transformation(extent={{-20,60},{0,80}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Max max
+    "Ensure bypass valve position is greater than lower limit for condensation control"
+    annotation (Placement(transformation(extent={{70,-40},{90,-20}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.AddParameter addPar(
+    final p=1e-6)
+    "Prevent division by zero"
+    annotation (Placement(transformation(extent={{-70,70},{-50,90}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.PIDWithReset conPID(
+    final controllerType=controllerType,
+    final k=k,
+    final Ti=Ti,
+    final Td=Td,
+    final yMax=1,
+    final yMin=0,
+    xi_start=1,
+    reverseActing=false)
+    "PID loop to regulate flow through primary loop using bypass valve"
+    annotation (Placement(transformation(extent={{20,60},{40,80}})));
+
+  Buildings.Controls.OBC.CDL.Logical.Edge edg
+    "Reset PID loop when it is activated"
+    annotation (Placement(transformation(extent={{-20,-10},{0,10}})));
+
+equation
+
+  connect(mulOr.u[1:nPum], uPumSta) annotation (Line(points={{-72,0},{-120,0}},
+                                  color={255,0,255}));
+
+  connect(uMinBypValPos, max.u2) annotation (Line(points={{-120,-60},{50,-60},{50,
+          -36},{68,-36}}, color={0,0,127}));
+  connect(max.y, yBypValPos)
+    annotation (Line(points={{92,-30},{120,-30}}, color={0,0,127}));
+  connect(VHotWatMinSet_flow, addPar.u)
+    annotation (Line(points={{-120,80},{-72,80}}, color={0,0,127}));
+  connect(addPar.y, div.u2) annotation (Line(points={{-48,80},{-40,80},{-40,34},
+          {-22,34}}, color={0,0,127}));
+  connect(con.y, conPID.u_s)
+    annotation (Line(points={{2,70},{18,70}},   color={0,0,127}));
+  connect(div.y, conPID.u_m)
+    annotation (Line(points={{2,40},{30,40},{30,58}},   color={0,0,127}));
+  connect(mulOr.y, edg.u) annotation (Line(points={{-48,0},{-22,0}},
+                    color={255,0,255}));
+  connect(edg.y, conPID.trigger)
+    annotation (Line(points={{2,0},{24,0},{24,58}}, color={255,0,255}));
+
+  connect(conPID.y, max.u1) annotation (Line(points={{42,70},{50,70},{50,-24},{68,
+          -24}}, color={0,0,127}));
+  connect(sub2.y, div.u1) annotation (Line(points={{-48,40},{-28,40},{-28,46},{-22,
+          46}}, color={0,0,127}));
+  connect(VHotWatMinSet_flow,sub2. u1) annotation (Line(points={{-120,80},{-80,80},
+          {-80,46},{-72,46}}, color={0,0,127}));
+  connect(VHotWat_flow,sub2. u2) annotation (Line(points={{-120,40},{-80,40},{-80,
+          34},{-72,34}}, color={0,0,127}));
+annotation (defaultComponentName="bypValPos",
+  Icon(coordinateSystem(preserveAspectRatio=false, extent={{-100,-100},{100,100}}),
+    graphics={Rectangle(
+                extent={{-100,100},{100,-100}},
+                lineColor={28,108,200},
+                fillColor={255,255,255},
+                fillPattern=FillPattern.Solid),
+              Text(
+                extent={{-70,20},{70,-20}},
+                textColor={0,0,0},
+                fillColor={255,255,255},
+                fillPattern=FillPattern.None,
+                textString="bypValPos"),
+              Text(
+                extent={{-100,146},{100,108}},
+                textColor={0,0,255},
+                textString="%name")}),
+  Diagram(coordinateSystem(preserveAspectRatio=false, extent={{-100,-100},{100,100}})),
+  Documentation(info="<html>
+    <p>
+    Control sequence for bypass circuit valve position <code>yBypValPos</code>
+    for boiler plant loop.
+    </p>
+    <ul>
+    <li>
+    The bypass valve is enabled when any of the hot-water supply pumps are proven on
+    <code>uPumSta = true</code>, and disabled otherwise.
+    </li>
+    <li>
+    When enabled, a PID control loop modulates the bypass valve to maintain
+    a primary circuit flow rate of <code>VHotWatMinSet_flow</code>, calculated in class
+    <a href=\"modelica://Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.SetPoints.MinimumFlowSetpoint\">
+    Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.SetPoints.MinimumFlowSetpoint</a>.
+    </li>
+    <li>
+    When all the pumps are not proved on <code>uPumSta = false</code>, the valve
+    is fully opened.
+    </li>
+    <li>
+    When a non-condensing boiler is enabled, the bypass valve position is set to the
+    higher value between the signal generated by the PID loop, and the minimum valve
+    position for condensation control <code>uMinBypValPos</code>.
+    </li>
+    </ul>
+    </html>", revisions="<html>
+    <ul>
+    <li>
+    August 17, 2020, by Karthik Devaprasad:<br/>
+    First implementation.
+    </li>
+    </ul>
+    </html>"));
+end BypassValvePosition;

Buildings/Controls/OBC/ASHRAE/PrimarySystem/BoilerPlant/BypassValve/Validation/BypassValvePosition.mo

@@ -0,0 +1,105 @@
+within Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve.Validation;
+block BypassValvePosition
+
+  Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve.BypassValvePosition
+    bypValPos(
+    final nPum=2,
+    final k=1,
+    final Ti=10,
+    final Td=10e-6)
+    "Test instance for bypass valve controller"
+    annotation (Placement(transformation(extent={{10,-10},{30,10}})));
+
+protected
+  Buildings.Controls.OBC.CDL.Continuous.Sources.Constant con(
+    final k=1.2)
+    "Minimum flow setpoint"
+    annotation (Placement(transformation(extent={{-40,50},{-20,70}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Sources.Sine sin(
+    final amplitude=0.5,
+    final freqHz=1/75,
+    final phase=0,
+    final offset=1.2,
+    final startTime=1)
+    "Sine input"
+    annotation (Placement(transformation(extent={{-80,10},{-60,30}})));
+
+  Buildings.Controls.OBC.CDL.Logical.Sources.Pulse booPul(
+    final width=0.5,
+    final period=300)
+    "Boolean pulse generator"
+    annotation (Placement(transformation(extent={{-80,-30},{-60,-10}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Sources.Constant con1(
+    final k=0.2)
+    "Minimum valve position for condensation control"
+    annotation (Placement(transformation(extent={{-40,-70},{-20,-50}})));
+
+  Buildings.Controls.OBC.CDL.Routing.BooleanScalarReplicator booRep(
+    final nout=2)
+    "Boolean replicator"
+    annotation (Placement(transformation(extent={{-40,-30},{-20,-10}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Sources.Constant con2(
+    final k=0)
+    "Constant zero signal"
+    annotation (Placement(transformation(extent={{-80,50},{-60,70}})));
+
+  Buildings.Controls.OBC.CDL.Continuous.Switch swi
+    "Pass zero flowrate when pumps are switched off"
+    annotation (Placement(transformation(extent={{-40,10},{-20,30}})));
+
+equation
+  connect(con.y, bypValPos.VHotWatMinSet_flow) annotation (Line(points={{-18,60},
+          {0,60},{0,6},{8,6}},         color={0,0,127}));
+  connect(con1.y, bypValPos.uMinBypValPos) annotation (Line(points={{-18,-60},{0,
+          -60},{0,-6},{8,-6}},   color={0,0,127}));
+  connect(booPul.y, booRep.u)
+    annotation (Line(points={{-58,-20},{-42,-20}}, color={255,0,255}));
+  connect(booRep.y, bypValPos.uPumSta) annotation (Line(points={{-18,-20},{-10,-20},
+          {-10,-2},{8,-2}}, color={255,0,255}));
+
+  connect(swi.y, bypValPos.VHotWat_flow) annotation (Line(points={{-18,20},{-10,
+          20},{-10,2},{8,2}}, color={0,0,127}));
+  connect(sin.y, swi.u1) annotation (Line(points={{-58,20},{-50,20},{-50,28},{-42,
+          28}}, color={0,0,127}));
+  connect(con2.y, swi.u3) annotation (Line(points={{-58,60},{-54,60},{-54,12},{-42,
+          12}}, color={0,0,127}));
+  connect(booPul.y, swi.u2) annotation (Line(points={{-58,-20},{-46,-20},{-46,20},
+          {-42,20}}, color={255,0,255}));
+annotation (
+Documentation(info="<html>
+<p>
+This example validates
+<a href=\"modelica://Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve.BypassValvePosition\">
+Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve.BypassValvePosition</a>.
+</p>
+</html>", revisions="<html>
+<ul>
+<li>
+August 17, 2020, by Karthik Devaprasad:<br/>
+First implementation.
+</li>
+</ul>
+</html>"),
+  Icon(coordinateSystem(preserveAspectRatio=false), graphics={
+        Ellipse(lineColor = {75,138,73},
+                fillColor={255,255,255},
+                fillPattern = FillPattern.Solid,
+                extent={{-100,-100},{100,100}}),
+        Polygon(lineColor = {0,0,255},
+                fillColor = {75,138,73},
+                pattern = LinePattern.None,
+                fillPattern = FillPattern.Solid,
+                points={{-36,60},{64,0},{-36,-60},{-36,60}})}),  Diagram(
+        coordinateSystem(preserveAspectRatio=false)),
+    __Dymola_Commands(file=
+          "./Resources/Scripts/Dymola/Controls/OBC/ASHRAE/PrimarySystem/BoilerPlant/BypassValve/Validation/BypassValvePosition.mos"
+        "Simulate and plot"),
+    experiment(
+      StartTime=0,
+      StopTime=300,
+      Interval=1,
+      Tolerance=1e-06));
+end BypassValvePosition;

Buildings/Controls/OBC/ASHRAE/PrimarySystem/BoilerPlant/BypassValve/Validation/package.mo

@@ -0,0 +1,32 @@
+within Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve;
+package Validation "Validation models for BypassValve sequences"
+
+
+
+
+  annotation (Icon(graphics={
+        Rectangle(
+          lineColor={200,200,200},
+          fillColor={248,248,248},
+          fillPattern=FillPattern.HorizontalCylinder,
+          extent={{-100,-100},{100,100}},
+          radius=25.0),
+        Rectangle(
+          lineColor={128,128,128},
+          extent={{-100,-100},{100,100}},
+          radius=25.0),
+        Polygon(
+          origin={8,14},
+          lineColor={78,138,73},
+          fillColor={78,138,73},
+          pattern=LinePattern.None,
+          fillPattern=FillPattern.Solid,
+          points={{-58.0,46.0},{42.0,-14.0},{-58.0,-74.0},{-58.0,46.0}})}),
+    Documentation(info="<html>
+<p>
+This package contains validation models for the classes in
+<a href=\"modelica://Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve\">
+Buildings.Controls.OBC.ASHRAE.PrimarySystem.BoilerPlant.BypassValve</a>.
+</p>
+</html>"));
+end Validation;

Buildings/Controls/OBC/ASHRAE/PrimarySystem/BoilerPlant/BypassValve/Validation/package.order

@@ -0,0 +1 @@
+BypassValvePosition