init grafana service

doc/grafana.md

@@ -0,0 +1,62 @@
+# Grafana Open Source
+
+Grafana open source is open source visualization and analytics software. It allows you to query, visualize, alert on, and explore your metrics, logs, and traces no matter where they are stored. It provides you with tools to turn your time-series database (TSDB) data into insightful graphs and visualizations.
+
+## Getting Started
+
+```nix
+# In `perSystem.process-compose.<name>`
+{
+  services.grafana."gf1".enable = true;
+}
+```
+
+{#tips}
+## Tips & Tricks
+
+{#change-database}
+### Changing Grafana database
+
+By default, Grafana stores data in the `sqlite3` [database](https://grafana.com/docs/grafana/latest/setup-grafana/configure-grafana/#database). It also supports `mysql` and `postgres`.
+
+To change the database to `postgres`, we can use the following config:
+
+1. Create `postgres` service.
+
+```nix
+services.postgres."pg1" = {
+  enable = true;
+  listen_addresses = "127.0.0.1";
+  port = 5435;
+  initialDatabases = [{
+    name = "grafana-db";
+  }];
+  initialScript.after = ''
+    CREATE USER gfuser with PASSWORD 'gfpassword' SUPERUSER;
+  '';
+};
+```
+
+2. Create `grafana` service, and change its config to use the `postgres` database.
+
+```nix
+services.grafana."gf1" = {
+  enable = true;
+  http_port = 3001;
+  extraConf = {
+    database = {
+      type = "postgres";
+      host = "127.0.0.1:5435";
+      name = "grafana-db";
+      user = "gfuser";
+      password = "gfpassword";
+    };
+  };
+};
+```
+
+3. Add a setting to start `grafana` only after `postgres` is running.
+
+```nix
+settings.processes."gf1".depends_on."pg1".condition = "process_healthy";
+```

doc/services.md

@@ -16,6 +16,7 @@ short-title: Services
 - [ ] Redis
 - [ ] Redis Cluster
 - [ ] Zookeeper
+- [ ] [[grafana]]#
 - [ ] ...
 
 [gh]: https://github.com/juspay/services-flake

nix/default.nix

@@ -13,5 +13,6 @@ in
     ./redis-cluster.nix
     ./redis.nix
     ./zookeeper.nix
+    ./grafana
   ];
 }

nix/grafana/default.nix

@@ -0,0 +1,105 @@
+{ pkgs, lib, name, config, ... }:
+let
+  inherit (lib) types;
+  iniFormat = pkgs.formats.ini { };
+in
+{
+  options = {
+    description = ''
+      Configure grafana.
+    '';
+    enable = lib.mkEnableOption name;
+
+    package = lib.mkPackageOption pkgs "grafana" { };
+
+    http_port = lib.mkOption {
+      type = types.int;
+      description = "Which port to run grafana on.";
+      default = 3000;
+    };
+
+    domain = lib.mkOption {
+      type = types.str;
+      description = "The public facing domain name used to access grafana from a browser.";
+      default = "localhost";
+    };
+
+    protocol = lib.mkOption {
+      type = types.str;
+      description = "Protocol (http, https, h2, socket).";
+      default = "http";
+    };
+
+    root_url = lib.mkOption {
+      type = types.str;
+      description = "The full public facing url.";
+      default = "${config.protocol}://${config.domain}:${builtins.toString config.http_port}";
+    };
+
+    dataDir = lib.mkOption {
+      type = types.str;
+      description = "Directory where grafana stores its logs and data.";
+      default = "./data/${name}";
+    };
+
+    extraConf = lib.mkOption {
+      type = iniFormat.type;
+      description = "Extra configuration for grafana.";
+      default = { };
+      example = ''
+        {
+          security.admin_user = "patato";
+          security.admin_password = "potato";
+        }
+      '';
+    };
+
+    outputs.settings = lib.mkOption {
+      type = types.deferredModule;
+      internal = true;
+      readOnly = true;
+      default = {
+        processes."${name}" =
+          let
+            grafanaConfig = lib.recursiveUpdate
+              config.extraConf
+              {
+                server = {
+                  inherit (config) protocol http_port domain root_url;
+                };
+              };
+            grafanaConfigIni = iniFormat.generate "defaults.ini" grafanaConfig;
+            startScript = pkgs.writeShellApplication {
+              name = "start-grafana";
+              runtimeInputs = [ config.package ];
+              text = ''
+                grafana server --config ${grafanaConfigIni} \
+                               --homepath ${config.package}/share/grafana \
+                               cfg:paths.data="$(readlink -m ${config.dataDir})"
+              '';
+            };
+          in
+          {
+            command = startScript;
+            readiness_probe = {
+              http_get = {
+                host = config.domain;
+                scheme = config.protocol;
+                port = config.http_port;
+                path = "/api/health";
+              };
+              initial_delay_seconds = 15;
+              period_seconds = 10;
+              timeout_seconds = 2;
+              success_threshold = 1;
+              failure_threshold = 5;
+            };
+            namespace = name;
+
+            # https://github.com/F1bonacc1/process-compose#-auto-restart-if-not-healthy
+            availability.restart = "on_failure";
+          };
+      };
+    };
+  };
+}

nix/grafana/grafana_test.nix

@@ -0,0 +1,31 @@
+{ pkgs, config, ... }: {
+  services.grafana."gf1" =
+    {
+      enable = true;
+      http_port = 3000;
+      extraConf = {
+        security.admin_user = "patato";
+        security.admin_password = "potato";
+      };
+    };
+
+  settings.processes.test =
+    let
+      cfg = config.services.grafana."gf1";
+    in
+    {
+      # Tests based on: https://github.com/NixOS/nixpkgs/blob/master/nixos/tests/grafana/basic.nix
+      command = pkgs.writeShellApplication {
+        runtimeInputs = [ cfg.package pkgs.gnugrep pkgs.curl pkgs.uutils-coreutils-noprefix ];
+        text =
+          ''
+            ADMIN=${cfg.extraConf.security.admin_user}
+            PASSWORD=${cfg.extraConf.security.admin_password}
+            curl -sSfN -u $ADMIN:$PASSWORD ${cfg.root_url}/api/org/users -i
+            curl -sSfN -u $ADMIN:$PASSWORD ${cfg.root_url}/api/org/users | grep admin\@localhost
+          '';
+        name = "grafana-test";
+      };
+      depends_on."gf1".condition = "process_healthy";
+    };
+}

test/flake.nix

@@ -46,6 +46,7 @@
             "${inputs.services-flake}/nix/redis_test.nix"
             "${inputs.services-flake}/nix/redis-cluster_test.nix"
             "${inputs.services-flake}/nix/zookeeper_test.nix"
+            "${inputs.services-flake}/nix/grafana/grafana_test.nix"
           ]);
       };
     };