init grafana service

nix/default.nix

@@ -13,5 +13,6 @@ in
     ./redis-cluster.nix
     ./redis.nix
     ./zookeeper.nix
+    ./grafana
   ];
 }

nix/grafana/default.nix

@@ -0,0 +1,83 @@
+{ pkgs, lib, name, config, ... }:
+let
+  inherit (lib) types;
+  iniFormat = pkgs.formats.ini { };
+in
+{
+  options = {
+    description = ''
+      Configure grafana.
+    '';
+    enable = lib.mkEnableOption name;
+
+    package = lib.mkPackageOption pkgs "grafana" { };
+
+    port = lib.mkOption {
+      type = types.int;
+      description = "Which port to run grafana on.";
+      default = 3000;
+    };
+
+    dataDir = lib.mkOption {
+      type = types.str;
+      description = "Directory where grafana stores its logs and data.";
+      default = "./data/${name}";
+    };
+
+    extraConf = lib.mkOption {
+      type = iniFormat.type;
+      description = "Extra configuration for grafana.";
+      default = { };
+      example = ''
+        {
+          security.admin_user = "patato";
+          security.admin_password = "potato";
+        }
+      '';
+    };
+
+    outputs.settings = lib.mkOption {
+      type = types.deferredModule;
+      internal = true;
+      readOnly = true;
+      default = {
+        processes."${name}" =
+          let
+            grafanaConfig =
+              {
+                server = {
+                  protocol = "http";
+                  http_port = config.port;
+                  domain = "localhost";
+                };
+              } // config.extraConf;
+            grafanaConfigIni = iniFormat.generate "defaults.ini" grafanaConfig;
+            startScript = pkgs.writeShellApplication {
+              name = "start-grafana";
+              runtimeInputs = [ config.package ];
+              text = ''
+                grafana server --config ${grafanaConfigIni} \
+                               --homepath ${config.package}/share/grafana \
+                               cfg:paths.data="$(readlink -m ${config.dataDir})"
+              '';
+            };
+          in
+          {
+            command = startScript;
+            readiness_probe = {
+              exec.command = "${pkgs.curl}/bin/curl -f ${grafanaConfig.server.protocol}://${grafanaConfig.server.domain}:${builtins.toString grafanaConfig.server.http_port}/api/health";
+              initial_delay_seconds = 15;
+              period_seconds = 10;
+              timeout_seconds = 2;
+              success_threshold = 1;
+              failure_threshold = 5;
+            };
+            namespace = name;
+
+            # https://github.com/F1bonacc1/process-compose#-auto-restart-if-not-healthy
+            availability.restart = "on_failure";
+          };
+      };
+    };
+  };
+}

nix/grafana/grafana_test.nix

@@ -0,0 +1,31 @@
+{ pkgs, config, ... }: {
+  services.grafana."gf1" =
+    {
+      enable = true;
+      port = 3000;
+      extraConf = {
+        security.admin_user = "patato";
+        security.admin_password = "potato";
+      };
+    };
+
+  settings.processes.test =
+    let
+      cfg = config.services.grafana."gf1";
+    in
+    {
+      # Tests based on: https://github.com/NixOS/nixpkgs/blob/master/nixos/tests/grafana/basic.nix
+      command = pkgs.writeShellApplication {
+        runtimeInputs = [ cfg.package pkgs.gnugrep pkgs.curl pkgs.uutils-coreutils-noprefix ];
+        text =
+          ''
+            ADMIN=${cfg.extraConf.security.admin_user}
+            PASSWORD=${cfg.extraConf.security.admin_password}
+            curl -sSfN -u $ADMIN:$PASSWORD http://127.0.0.1:3000/api/org/users -i
+            curl -sSfN -u $ADMIN:$PASSWORD http://127.0.0.1:3000/api/org/users | grep admin\@localhost
+          '';
+        name = "grafana-test";
+      };
+      depends_on."gf1".condition = "process_healthy";
+    };
+}

test/flake.nix

@@ -46,6 +46,7 @@
             "${inputs.services-flake}/nix/redis_test.nix"
             "${inputs.services-flake}/nix/redis-cluster_test.nix"
             "${inputs.services-flake}/nix/zookeeper_test.nix"
+            "${inputs.services-flake}/nix/grafana/grafana_test.nix"
           ]);
       };
     };