Migrated project build.gradle file to kts

build.gradle.kts

@@ -0,0 +1,55 @@
+buildscript {
+
+    repositories {
+        google()
+        mavenCentral()
+        maven(url = "https://jitpack.io")
+    }
+
+    dependencies {
+        classpath(libs.android.gradle)
+        classpath(libs.kotlin.gradle)
+        classpath(libs.jacoco.gradle)
+        classpath(libs.version.gradle)
+        classpath(libs.dokka.gradle)
+        classpath(libs.dokka.android.gradle)
+        classpath(libs.maven.publish.gradle)
+    }
+}
+
+apply(plugin = "com.github.ben-manes.versions")
+apply(plugin = "org.jetbrains.dokka")
+apply(from = "gradle/jacoco.gradle")
+apply(from = "gradle/merge-reports.gradle")
+
+allprojects {
+    repositories {
+        google()
+        mavenCentral()
+    }
+
+    tasks.withType<org.jetbrains.dokka.gradle.DokkaTaskPartial>().configureEach {
+        dokkaSourceSets.named("main") {
+            jdkVersion.set(8)
+            skipDeprecated.set(true)
+            skipEmptyPackages.set(true)
+            reportUndocumented.set(false)
+        }
+    }
+}
+
+tasks.register("clean", Delete::class) {
+    delete(rootProject.buildDir)
+}
+
+tasks.register("install") {
+    val publishTasks = mutableListOf<Task>()
+    project.subprojects.forEach { project ->
+        val installTask = project.tasks.findByName("install") ?: project.tasks.findByName("publishToMavenLocal")
+        if (installTask != null) {
+            publishTasks.add(installTask)
+        }
+    }
+    dependsOn(publishTasks)
+}
+

gradle/jacoco.gradle

@@ -0,0 +1,21 @@
+apply plugin: "com.vanniktech.android.junit.jacoco"
+
+junitJacoco {
+    // WARNING! Don"t upgrade unless https://github.com/Malinskiy/danger-jacoco/issues/10 is fixed
+    jacocoVersion = '0.8.2'
+    excludes = [
+            // Defaults
+            '**/androidx/**/*.*',
+            '**/*$$*',
+            '**/BuildConfig.*',
+            '**/Manifest*.*',
+            '**/*$Lambda$*.*', // Jacoco can not handle several "$" in class name.
+            '**/*$inlined$*.*', // Kotlin specific, Jacoco can not handle several "$" in class name.
+            '**/com/instacart/formula/test/**/*.*'
+    ]
+    ignoreProjects = [
+            "samples/*"
+    ]
+    includeNoLocationClasses = true
+    includeInstrumentationCoverageInMergedReport = true
+}

gradle/libs.versions.toml

@@ -1,4 +1,7 @@
 [versions]
+android-gradle = "7.0.4"
+dokka-gradle = "1.4.32"
+
 minSdk = "21"
 compileSdk = "30"
 targetSdk = "30"
@@ -17,6 +20,14 @@ lint = "30.0.0"
 autoService = "1.0-rc7"
 
 [libraries]
+android-gradle = { module = "com.android.tools.build:gradle", version.ref = "android-gradle" }
+kotlin-gradle = { module = "org.jetbrains.kotlin:kotlin-gradle-plugin", version.ref = "kotlin" }
+dokka-gradle = { module = "org.jetbrains.dokka:dokka-gradle-plugin", version.ref = "dokka-gradle" }
+dokka-android-gradle = { module = "org.jetbrains.dokka:android-documentation-plugin", version.ref = "dokka-gradle" }
+maven-publish-gradle = { module = "com.vanniktech:gradle-maven-publish-plugin", version = "0.14.2" }
+version-gradle = { module = "com.github.ben-manes:gradle-versions-plugin", version = "0.38.0" }
+jacoco-gradle = { module = "com.vanniktech:gradle-android-junit-jacoco-plugin", version = "0.16.0" }
+
 kotlin = { module = "org.jetbrains.kotlin:kotlin-stdlib-jdk8", version.ref = "kotlin" }
 kotlin-reflect = { module = "org.jetbrains.kotlin:kotlin-reflect", version.ref = "kotlin" }
 

settings.gradle.kts

@@ -1,17 +1,21 @@
 enableFeaturePreview("VERSION_CATALOGS")
 
-include(":formula")
-include(":formula-android")
-include(":formula-android-compose")
-include(":formula-android-tests")
-include(":formula-lint")
-include(":formula-rxjava3")
-include(":formula-coroutines")
-include(":formula-test")
-include(":samples:composition")
-include(":samples:counter")
-include(":samples:custom-network-state-stream")
-include(":samples:stopwatch")
-include(":samples:stopwatch-coroutines")
-include(":samples:stopwatch-compose")
-include(":samples:todoapp")
+include(
+    ":formula",
+    ":formula-android",
+    ":formula-android-compose",
+    ":formula-android-tests",
+    ":formula-lint",
+    ":formula-rxjava3",
+    ":formula-coroutines",
+    ":formula-test",
+)
+include(
+    ":samples:composition",
+    ":samples:counter",
+    ":samples:custom-network-state-stream",
+    ":samples:stopwatch",
+    ":samples:stopwatch-coroutines",
+    ":samples:stopwatch-compose",
+    ":samples:todoapp"
+)