Add onix-based flake, associated make task, and .envrc template

.envrc.tmpl

@@ -0,0 +1,13 @@
+# rebuild the environment on `nix-direnv-reload` only
+nix_direnv_manual_reload
+
+# direnv will consider the environment changed if these files change, and
+# nix-direnv will then prompt for the manual reload
+watch_file flake.nix flake.lock onix-lock.json onix-lock-dev.json
+
+# use the flake with the `default` devShell:
+use flake
+
+# To use another devShell, you can use (e.g. for devShell.other:
+# use flake .#other
+

.github/workflows/main.yml

@@ -7,7 +7,7 @@ jobs:
     strategy:
       matrix:
         operating-system: [ubuntu-latest]
-        ocaml-compiler: [ '4.08.1', '4.11.0' ]
+        ocaml-compiler: [ '4.08.1', '4.11.0', '4.12.1' ]
     steps:
     - uses: actions/checkout@master
     - uses: ocaml/setup-ocaml@v2

Makefile

@@ -6,3 +6,19 @@ clean:
 
 watch:
 	@dune build @all -w
+
+nix-lock:
+	nix run .#onix-lock
+
+.PHONY: onix-lock.json
+onix-lock.json:
+	onix lock ./imandra-document.opam --resolutions="ocaml-system=5.2.0" --lock-file ./onix-lock.json
+
+.PHONY: onix-lock-dev.json
+onix-lock-dev.json:
+	onix lock ./imandra-document.opam --resolutions="ocaml-system=5.2.0,ocaml-lsp-server,utop" --with-test=true --lock-file ./onix-lock-dev.json
+
+.PHONY: lock
+lock: onix-lock.json onix-lock-dev.json
+	git add onix-lock.json onix-lock-dev.json
+

flake.nix

@@ -0,0 +1,102 @@
+{
+  inputs = {
+    nixpkgs.url = "nixpkgs/nixpkgs-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+
+    onix = {
+      url = "github:rizo/onix/3740a2beb84bc21860385f8bbb0d5f557842de03";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+  };
+
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-utils,
+      onix,
+    }@inputs:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        onix' = onix.packages.${system}.latest;
+        compilerVersion = "5.2.0";
+        opamFiles = [
+          ./imandra-document.opam
+        ];
+        onixEnv = onix'.env {
+          path = ./.;
+          roots = opamFiles;
+          lock = ./onix-lock.json;
+          deps = {
+            "ocaml-system" = compilerVersion;
+          };
+        };
+        onixEnvDev = onix'.env {
+          path = ./.;
+          roots = opamFiles;
+          lock = ./onix-lock-dev.json;
+          deps = {
+            "ocaml-system" = compilerVersion;
+            "ocaml-lsp-server" = "*";
+            "utop" = "*";
+          };
+        };
+        onixLock =
+          let
+            shellHook = pkgs.writeText "onix-lock-shellHook" onixEnv.lock.shellHook;
+            lockPatched = pkgs.runCommand "onix-lock-shellHook-patched" { } ''
+              sed 's:--lock-file=/nix/store/.*/onix-lock.json:--lock-file=./onix-lock.json:' "${shellHook}" > "$out"
+              chmod +x "$out"
+            '';
+          in
+          pkgs.writeShellApplication {
+            name = "onix-lock";
+            runtimeInputs = [ onix' ];
+            text = lockPatched;
+          };
+        onixLockDev =
+          let
+            shellHook = pkgs.writeText "onix-lock-dev-shellHook" onixEnvDev.lock.shellHook;
+            lockPatched = pkgs.runCommand "onix-lock-dev-shellHook-patched" { } ''
+              sed 's:--lock-file=/nix/store/.*/onix-lock-dev.json:--lock-file=./onix-lock-dev.json:' "${shellHook}" > "$out"
+              chmod +x "$out"
+            '';
+          in
+          pkgs.writeShellApplication {
+            name = "onix-lock-dev";
+            runtimeInputs = [ onix' ];
+            text = lockPatched;
+          };
+      in
+      rec {
+        formatter = pkgs.nixfmt-rfc-style;
+
+        packages.imandra-document = onixEnv.pkgs.imandra-document;
+        packages.default = onixEnv.pkgs.imandra-document;
+
+        packages.onix-lock = onixLock;
+        packages.onix-lock-dev = onixLockDev;
+        devShells.onixLock = pkgs.mkShell {
+          buildInputs = [
+            onix'
+          ];
+        };
+
+        devShells.default = onixEnvDev.shell.overrideAttrs (
+          final: prev: {
+            buildInputs = prev.buildInputs ++ [
+              pkgs.ocamlformat_0_22_4
+              pkgs.dune_3
+              pkgs.ocaml
+              onix'
+            ];
+          }
+        );
+
+        # Allows the default devshell to be cached
+        packages.devShell-default = devShells.default.inputDerivation;
+      }
+    );
+}