Issue1576 Heat pump model integration

IBPSA/Fluid/Chillers/ModularReversible/BaseClasses/RefrigerantCycle.mo

@@ -0,0 +1,184 @@
+within IBPSA.Fluid.Chillers.ModularReversible.BaseClasses;
+model RefrigerantCycle "Refrigerant cycle model of a chiller"
+  extends IBPSA.Fluid.HeatPumps.ModularReversible.BaseClasses.PartialModularRefrigerantCycle;
+
+  parameter Boolean allowDifferentDeviceIdentifiers=false
+    "if use_rev=true, device data for cooling and heating need to entered. Set allowDifferentDeviceIdentifiers=true to allow different device identifiers devIde"
+    annotation(Dialog(enable=use_rev));
+
+  replaceable model RefrigerantCycleChillerCooling =
+      IBPSA.Fluid.Chillers.ModularReversible.RefrigerantCycle.BaseClasses.NoCooling(
+        useInChi=true)
+    constrainedby
+      IBPSA.Fluid.Chillers.ModularReversible.RefrigerantCycle.BaseClasses.PartialChillerCycle
+    "Replaceable model for refrigerant cycle of a chiller in main operation mode"
+    annotation (choicesAllMatching=true);
+
+  replaceable model RefrigerantCycleChillerHeating =
+      IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.BaseClasses.NoHeating(
+        useInHeaPum=true)
+    constrainedby
+      IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.BaseClasses.PartialHeatPumpCycle
+    "Replaceable model for refrigerant cycle of a chiller in reversed operation mode"
+    annotation (Dialog(enable=use_rev),choicesAllMatching=true);
+
+  RefrigerantCycleChillerCooling refCycChiCoo
+    "Refrigerant cycle instance for cooling"
+    annotation (Placement(transformation(extent={{21,40},{60,80}}, rotation=0)));
+  RefrigerantCycleChillerHeating refCycChiHea
+    "Refrigerant cycle instance for heating"
+    annotation (Placement(transformation(extent={{-60,38},{-19,80}}, rotation=0)));
+
+protected
+  parameter String devIde =
+    if use_rev then refCycChiHea.devIde else refCycChiCoo.devIde
+    "Data source for refrigerant cycle";
+
+initial algorithm
+  if not allowDifferentDeviceIdentifiers then
+    assert(
+      devIde == refCycChiCoo.devIde,
+      "In " + getInstanceName() + ": Device identifiers devIde for reversible operation are not equal.
+      Cooling device identifier is '" + refCycChiCoo.devIde + "' but heating is '"
+      + devIde + "'. To allow this, set 'allowDifferentDeviceIdentifiers=true'.",
+      AssertionLevel.error);
+  end if;
+equation
+  connect(pasTrhModSet.u, sigBus.coo);
+
+  connect(sigBus,refCycChiHea.sigBus)  annotation (Line(
+      points={{0,100},{0,92},{-39.3292,92},{-39.3292,80}},
+      color={255,204,51},
+      thickness=0.5));
+  connect(sigBus,refCycChiCoo.sigBus)  annotation (Line(
+      points={{0,100},{0,92},{40.6625,92},{40.6625,80}},
+      color={255,204,51},
+      thickness=0.5));
+
+  connect(swiPEle.u2, sigBus.coo) annotation (Line(points={{2.22045e-15,-58},{
+          2.22045e-15,-2},{0,-2},{0,100}},
+                               color={255,0,255}), Text(
+      string="%second",
+      index=1,
+      extent={{-3,6},{-3,6}},
+      horizontalAlignment=TextAlignment.Right));
+  connect(swiQEva.u2, sigBus.coo) annotation (Line(points={{-58,0},{0,0},{0,100}},
+        color={255,0,255}), Text(
+      string="%second",
+      index=1,
+      extent={{6,3},{6,3}},
+      horizontalAlignment=TextAlignment.Left));
+  connect(swiQCon.u2, sigBus.coo) annotation (Line(points={{58,0},{0,0},{0,100}},
+        color={255,0,255}), Text(
+      string="%second",
+      index=1,
+      extent={{-6,3},{-6,3}},
+      horizontalAlignment=TextAlignment.Right));
+  connect(refCycChiCoo.QEva_flow, swiQEva.u1) annotation (Line(points={{53.5,
+          38.3333},{53.5,24},{-10,24},{-10,8},{-58,8}}, color={0,0,127}));
+  connect(refCycChiCoo.QCon_flow, swiQCon.u1)
+    annotation (Line(points={{27.5,38.3333},{27.5,8},{58,8}}, color={0,0,127}));
+  connect(refCycChiCoo.PEle, swiPEle.u1) annotation (Line(points={{40.5,38.3333},
+          {40.5,-48},{8,-48},{8,-58}}, color={0,0,127}));
+  connect(refCycChiHea.PEle, swiPEle.u3) annotation (Line(points={{-39.5,36.25},{
+          -39.5,-48},{-8,-48},{-8,-58}}, color={0,0,127}));
+  connect(refCycChiHea.QCon_flow, swiQEva.u3) annotation (Line(points={{-53.1667,
+          36.25},{-53.1667,-8},{-58,-8}}, color={0,0,127}));
+  connect(refCycChiHea.QEva_flow, swiQCon.u3) annotation (Line(points={{-25.8333,
+          36.25},{-25.8333,-8},{58,-8}}, color={0,0,127}));
+
+  annotation (Icon(coordinateSystem(preserveAspectRatio=false), graphics={
+        Rectangle(
+          extent={{-100,100},{100,-100}},
+          lineColor={238,46,47},
+          fillColor={0,0,0},
+          fillPattern=FillPattern.Solid),
+        Ellipse(
+          extent={{-24,88},{22,44}},
+          lineColor={28,108,200},
+          lineThickness=0.5),
+        Line(
+          points={{-16,82},{20,74}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{-18,52},{20,58}},
+          color={28,108,200},
+          thickness=0.5),
+        Rectangle(
+          extent={{-98,40},{-60,-28}},
+          lineColor={28,108,200},
+          lineThickness=0.5),
+        Line(
+          points={{-20,-60},{-20,-70},{-20,-80},{20,-60},{20,-80},{-20,-60}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{-122,34},{-66,34},{-82,10},{-66,-22},{-120,-22}},
+          color={28,108,200},
+          thickness=0.5),
+        Rectangle(
+          extent={{60,40},{98,-28}},
+          lineColor={28,108,200},
+          lineThickness=0.5),
+        Line(
+          points={{120,34},{64,34},{80,10},{64,-22},{118,-22}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{-80,40},{-80,68},{-24,68}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{22,66},{80,66},{80,40}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{78,-28},{78,-70}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{78,-70},{62,-70},{20,-70}},
+          color={28,108,200},
+          thickness=0.5),
+        Line(
+          points={{-80,-26},{-80,-68},{-20,-68}},
+          color={28,108,200},
+          thickness=0.5),
+        Text(
+          extent={{-151,147},{149,107}},
+          textColor={0,0,255},
+          fillPattern=FillPattern.HorizontalCylinder,
+          fillColor={0,127,255},
+          textString="%name")}), Diagram(coordinateSystem(preserveAspectRatio=false)),
+    Documentation(revisions="<html>
+  <ul>
+  <li>
+  May 2, 2024, by Michael Wetter:<br/>
+  Refactored check for device identifiers.<br/>
+  This is for <a href=\"https://github.com/ibpsa/modelica-ibpsa/issues/1576\">IBPSA, #1576</a>.
+  </li>
+  <li>
+    <i>May 22, 2019,</i> by Julian Matthes:<br/>
+    First implementation (see issue <a href=
+    \"https://github.com/RWTH-EBC/AixLib/issues/715\">AixLib #715</a>)
+  </li>
+</ul>
+</html>", info="<html>
+<p>
+  Modular refrigerant cycle model for chiller applications used in
+  the model <a href=\"modelica://IBPSA.Fluid.Chillers.ModularReversible.Modular\">
+  IBPSA.Fluid.Chillers.ModularReversible.Modular</a> and extending models
+  of the modular approach.
+</p>
+<p>
+  This model adds the replaceable model approaches for cooling and heating data
+  to the partial refrigerant cylce.
+</p>
+<p>
+  Further, an asseration warning is raised if the model approaches or
+  sources for performance data differ. This indicates that they are not
+  for the same device.
+</p>
+</html>"));
+end RefrigerantCycle;

IBPSA/Fluid/Chillers/ModularReversible/BaseClasses/package.mo

@@ -0,0 +1,11 @@
+within IBPSA.Fluid.Chillers.ModularReversible;
+package BaseClasses "Package with base classes for IBPSA.Fluid.Chillers.ModularReversible"
+  extends Modelica.Icons.BasesPackage;
+
+  annotation (preferredView="info", Documentation(info="<html>
+<p>
+This package contains base classes that are used to construct the models in
+<a href=\"modelica://IBPSA.Fluid.Chillers.ModularReversible\">IBPSA.Fluid.Chillers.ModularReversible</a>.
+</p>
+</html>"));
+end BaseClasses;

IBPSA/Fluid/Chillers/ModularReversible/BaseClasses/package.order

@@ -0,0 +1 @@
+RefrigerantCycle

IBPSA/Fluid/Chillers/ModularReversible/CarnotWithLosses.mo

@@ -0,0 +1,92 @@
+within IBPSA.Fluid.Chillers.ModularReversible;
+model CarnotWithLosses
+  "Reversible chiller using Carnot approach with losses (frost, heat, inertia)"
+  extends IBPSA.Fluid.Chillers.ModularReversible.Modular(
+    QHea_flow_nominal=PEle_nominal*refCyc.refCycChiHea.COP_nominal,
+    redeclare model RefrigerantCycleChillerHeating =
+        IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.ConstantCarnotEffectiveness
+        (
+        PEle_nominal=PEle_nominal,
+        redeclare
+          IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Frosting.NoFrosting
+          iceFacCal,
+        etaCarnot_nominal=etaCarnot_nominal,
+        use_constAppTem=true,
+        TAppCon_nominal=TAppCon_nominal,
+        TAppEva_nominal=TAppEva_nominal),
+    redeclare model RefrigerantCycleChillerCooling =
+        IBPSA.Fluid.Chillers.ModularReversible.RefrigerantCycle.ConstantCarnotEffectiveness
+        (
+        redeclare
+          IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Frosting.FunctionalIcingFactor
+          iceFacCal(redeclare function icingFactor =
+              IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Frosting.Functions.wetterAfjei1997),
+        TAppCon_nominal=TAppCon_nominal,
+        TAppEva_nominal=TAppEva_nominal,
+        etaCarnot_nominal=etaCarnot_nominal),
+    final allowDifferentDeviceIdentifiers=false,
+    redeclare model RefrigerantCycleInertia =
+        IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.Inertias.VariableOrder
+        (
+        final refIneFreConst=1/refIneTimCon,
+        final nthOrd=1,
+        initType=Modelica.Blocks.Types.Init.InitialOutput));
+
+  parameter Real etaCarnot_nominal=0.3 "Constant Carnot effectiveness";
+  parameter Modelica.Units.SI.TemperatureDifference TAppCon_nominal=if
+      cpCon < 1500 then 5 else 2
+    "Temperature difference between refrigerant and working fluid outlet in condenser"
+    annotation(Dialog(group="Nominal condition"));
+  parameter Modelica.Units.SI.TemperatureDifference TAppEva_nominal=if
+      cpEva < 1500 then 5 else 2
+    "Temperature difference between refrigerant and working fluid outlet in evaporator"
+    annotation(Dialog(group="Nominal condition"));
+  parameter Modelica.Units.SI.Time refIneTimCon = 300
+    "Refrigerant cycle inertia time constant for first order delay"
+    annotation(Dialog(group="Refrigerant cycle inertia"));
+  parameter Integer nthOrd=1 "Order of refrigerant cycle interia"
+    annotation(Dialog(group="Refrigerant cycle inertia"));
+
+
+  annotation (Documentation(revisions="<html>
+<ul>
+<li>
+  <i>October 2, 2022</i> by Fabian Wuellhorst:<br/>
+  First implementation (see issue <a href=
+  \"https://github.com/ibpsa/modelica-ibpsa/issues/1576\">#1576</a>)
+</li>
+</ul>
+</html>", info="<html>
+<p>
+  Model of a reversible chiller.
+</p>
+<p>
+  This model extends
+  <a href=\"modelica://IBPSA.Fluid.Chillers.ModularReversible.Modular\">
+  IBPSA.Fluid.Chillers.ModularReversible.Modular</a> and selects the
+  constant Carnot effectiveness module for chillers
+  (<a href=\"modelica://IBPSA.Fluid.Chillers.ModularReversible.RefrigerantCycle.ConstantCarnotEffectiveness\">
+  IBPSA.Fluid.Chillers.ModularReversible.RefrigerantCycle.ConstantCarnotEffectiveness</a>)
+  and heat pumps
+  (<a href=\"modelica://IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.ConstantCarnotEffectiveness\">
+  IBPSA.Fluid.HeatPumps.ModularReversible.RefrigerantCycle.ConstantCarnotEffectiveness</a>)
+  to model a reversible chiller.
+  For the heating operation, the nominal approach temperatures are used
+  as a constant to avoid nonlinear system of equations.
+</p>
+<p>
+  Furthermore, losses are enabled to model
+  the chiller with a more realistic behaviour:
+</p>
+<ul>
+<li>Heat losses to the ambient (can be disabled)</li>
+<li>Refrigerant inertia using a first order delay</li>
+<li>Evaporator frosting assuming an air-sink chiller</li>
+</ul>
+<p>
+For more information, see
+  <a href=\"modelica://IBPSA.Fluid.HeatPumps.ModularReversible.UsersGuide\">
+  IBPSA.Fluid.HeatPumps.ModularReversible.UsersGuide</a>.
+</p>
+</html>"));
+end CarnotWithLosses;

IBPSA/Fluid/Chillers/ModularReversible/Controls/Safety/OperationalEnvelope.mo

@@ -0,0 +1,78 @@
+within IBPSA.Fluid.Chillers.ModularReversible.Controls.Safety;
+model OperationalEnvelope
+  "Indicates if the chiller operation is within a defined envelope"
+  extends
+    HeatPumps.ModularReversible.Controls.Safety.BaseClasses.PartialOperationalEnvelope;
+  Modelica.Blocks.Logical.Not notCoo "=true for heating" annotation (Placement(
+        transformation(
+        extent={{-10,-10},{10,10}},
+        rotation=0,
+        origin={-50,0})));
+equation
+    if use_TEvaOutHea then
+    connect(bouMapHea.TUseSid, sigBus.TEvaOutMea) annotation (Line(points={{-84.2,
+            82},{-104,82},{-104,-61},{-119,-61}},                       color={0,
+            0,127}));
+  else
+    connect(bouMapHea.TUseSid, sigBus.TEvaInMea) annotation (Line(points={{-84.2,
+            82},{-104,82},{-104,-61},{-119,-61}},                       color={0,
+            0,127}));
+  end if;
+  if use_TConOutCoo then
+    connect(bouMapCoo.TAmbSid, sigBus.TConOutMea) annotation (Line(points={{-84.8,
+            -62},{-104,-62},{-104,-61},{-119,-61}},
+                                                color={0,0,127}));
+  else
+    connect(bouMapCoo.TAmbSid, sigBus.TConInMea) annotation (Line(points={{-84.8,
+            -62},{-104,-62},{-104,-61},{-119,-61}},
+                                                color={0,0,127}));
+  end if;
+  if use_TConOutHea then
+    connect(bouMapHea.TAmbSid, sigBus.TConOutMea) annotation (Line(points={{-84.8,
+            58},{-104,58},{-104,-60},{-106,-60},{-106,-61},{-119,-61}},
+                                                color={0,0,127}));
+  else
+    connect(bouMapHea.TAmbSid, sigBus.TConInMea) annotation (Line(points={{-84.8,
+            58},{-104,58},{-104,-60},{-112,-60},{-112,-61},{-119,-61}},
+                                                color={0,0,127}));
+  end if;
+  if use_TEvaOutCoo then
+    connect(bouMapCoo.TUseSid, sigBus.TEvaOutMea) annotation (Line(points={{-84.2,
+            -38},{-104,-38},{-104,-60},{-112,-60},{-112,-61},{-119,-61}},
+                                                      color={0,0,127}));
+  else
+    connect(bouMapCoo.TUseSid, sigBus.TEvaInMea) annotation (Line(points={{-84.2,
+            -38},{-104,-38},{-104,-60},{-112,-60},{-112,-61},{-119,-61}},
+                                                      color={0,0,127}));
+  end if;
+  connect(notCoo.y, swiHeaCoo.u2)
+    annotation (Line(points={{-39,0},{-6,0}}, color={255,0,255}));
+  connect(notCoo.u, sigBus.coo) annotation (Line(points={{-62,0},{-70,0},{-70,
+          -8},{-104,-8},{-104,-60},{-112,-60},{-112,-61},{-119,-61}},
+                       color={255,0,255}), Text(
+      string="%second",
+      index=1,
+      extent={{-6,3},{-6,3}},
+      horizontalAlignment=TextAlignment.Right));
+  annotation (Diagram(coordinateSystem(extent={{-120,-120},{120,120}})),
+    Documentation(revisions="<html><ul>
+  <li>
+    <i>November 26, 2018</i> by Fabian Wuellhorst:<br/>
+    First implementation (see issue <a href=
+    \"https://github.com/RWTH-EBC/AixLib/issues/577\">AixLib #577</a>)
+  </li>
+</ul>
+</html>", info="<html>
+<p>
+  Model to check if the operating conditions of a chiller are inside
+  the given boundaries. If not, the heat pump or chiller will switch off.
+</p>
+<p>
+  Read the documentation of
+  <a href=\"modelica://IBPSA.Fluid.HeatPumps.ModularReversible.Controls.Safety.BaseClasses.PartialOperationalEnvelope\">
+  IBPSA.Fluid.HeatPumps.ModularReversible.Controls.Safety.BaseClasses.PartialOperationalEnvelope</a>
+  for more information.
+</p>
+
+</html>"));
+end OperationalEnvelope;