Add faketime tests

ports/libfaketime/CMakeLists.txt

@@ -0,0 +1,58 @@
+cmake_minimum_required(VERSION 3.12)
+
+project(libfaketime VERSION 0.9.10)
+
+add_library(
+        ${PROJECT_NAME}
+        SHARED
+        src/libfaketime.c
+)
+
+target_include_directories(${PROJECT_NAME}
+        PUBLIC
+        "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>"
+        "$<INSTALL_INTERFACE:include>"
+)
+
+file(GLOB_RECURSE PUBLIC_HEADERS "src/*.h")
+
+target_sources(
+        ${PROJECT_NAME}
+        PUBLIC
+        FILE_SET HEADERS
+        BASE_DIRS src
+        FILES ${PUBLIC_HEADERS}
+)
+
+install(TARGETS ${PROJECT_NAME}
+        EXPORT ${PROJECT_NAME}
+        FILE_SET HEADERS
+        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+        INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+)
+
+install(EXPORT ${PROJECT_NAME}
+        FILE ${PROJECT_NAME}-targets.cmake
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
+        NAMESPACE libfaketime::
+)
+
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+configure_package_config_file(
+        ${PROJECT_NAME}-config.cmake.in
+        ${PROJECT_NAME}-config.cmake
+        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
+
+write_basic_package_version_file(
+        ${PROJECT_NAME}-config-version.cmake
+        VERSION ${CMAKE_PROJECT_VERSION}
+        COMPATIBILITY SameMajorVersion)
+
+install(FILES
+        ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-config.cmake
+        ${CMAKE_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})

ports/libfaketime/libfaketime-config.cmake.in

@@ -0,0 +1,8 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/libfaketime-targets.cmake")
+
+set(libfaketime_VERSION @CMAKE_PROJECT_VERSION@)
+set(libfaketime_FOUND true)
+
+check_required_components("libfaketime")

ports/libfaketime/portfile.cmake

@@ -0,0 +1,26 @@
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO wolfcw/libfaketime
+    REF v0.9.10
+    SHA512 07c431bee21e31343b680d1322dd529ea276e3cc4dbec61646c12bf5d0263163faf6186efeb36b199e24b655578a493c43e3b7a7acf8eba8b9ff84a1e94d618b
+)
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}")
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/libfaketime-config.cmake.in" DESTINATION "${SOURCE_PATH}")
+
+vcpkg_cmake_configure(
+    SOURCE_PATH ${SOURCE_PATH}
+)
+
+vcpkg_cmake_install()
+vcpkg_copy_pdbs()
+vcpkg_fixup_pkgconfig()
+# vcpkg_copy_tools(TOOL_NAMES faketime AUTO_CLEAN)
+vcpkg_cmake_config_fixup(
+        CONFIG_PATH lib/cmake/libfaketime
+        PACKAGE_NAME libfaketime)
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+
+# Handle copyright and usage
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/COPYING")

ports/libfaketime/vcpkg.json

@@ -0,0 +1,16 @@
+{
+  "name": "libfaketime",
+  "version-string": "v0.9.10",
+  "description": "",
+  "homepage": "https://github.com/wolfcw/libfaketime",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}

test/CMakeLists.txt

@@ -362,6 +362,46 @@ if (${CMAKE_SYSTEM_NAME} MATCHES "Linux" AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU
     )
 endif()
 
+find_package(libfaketime REQUIRED)
+
+# unit test executable
+add_executable(
+        tiledb_timing_unit EXCLUDE_FROM_ALL
+        $<TARGET_OBJECTS:TILEDB_CORE_OBJECTS>
+        "src/unit-capi-metadata.cc"
+        "src/unit.cc"
+)
+
+target_include_directories(
+        tiledb_timing_unit BEFORE PRIVATE
+        ${TILEDB_CORE_INCLUDE_DIR}
+        ${TILEDB_EXPORT_HEADER_DIR}
+)
+
+target_link_libraries(
+        tiledb_timing_unit
+        PUBLIC
+        libfaketime::libfaketime
+        TILEDB_CORE_OBJECTS_ILIB
+        TILEDB_CORE_OBJECTS
+        Catch2::Catch2
+        tiledb_test_support_lib
+)
+
+# We want tests to continue as normal even as the API is changing,
+# so don't warn for deprecations, since they'll be escalated to errors.
+if (NOT MSVC)
+  target_compile_options(tiledb_timing_unit PRIVATE -Wno-deprecated-declarations)
+endif()
+
+add_test(
+        NAME "tiledb_timing_unit"
+        COMMAND tiledb_timing_unit --durations=yes
+        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+)
+
+set_property(TEST tiledb_timing_unit PROPERTY ENVIRONMENT_MODIFICATION "FAKETIME=set:2020-12-24 20:30:00")
+
 add_test(
   NAME "tiledb_unit"
   COMMAND tiledb_unit --durations=yes

vcpkg.json

@@ -66,7 +66,8 @@
         "tests": {
             "description": "Build tiledb tests",
             "dependencies": [
-                "catch2"
+                "catch2",
+                "libfaketime"
             ]
         },
         "tools": {