Add faketime tests

.github/workflows/ci-linux_mac.yml

@@ -192,6 +192,7 @@ jobs:
           ./tiledb/test/ci/test_assert -d yes
           ./tiledb/test/tiledb_unit -d yes | awk '/1: ::set-output/{sub(/.*1: /, ""); print; next} 1'
           ./tiledb/tiledb/sm/filesystem/test/unit_vfs -d yes | awk '/1: ::set-output/{sub(/.*1: /, ""); print; next} 1'
+          ./tiledb/test/tiledb_timing_unit -d yes | awk '/1: ::set-output/{sub(/.*1: /, ""); print; next} 1'
 
           ###################################################
           # Stop helper processes, if applicable

ports/README.md

@@ -28,9 +28,10 @@ After copying the port, add an entry to the table below. You should also contrib
 
 ## List of port overlays
 
-|Port|Reason|
-|----|------|
-|`libmagic`|Updating to the upstream port deferred due to failures.|
-|`openssl`|Pinning to OpenSSL 1.1 until we can move to 3.0 in January 2024.|
-|`pcre2`|To be removed alongside libmagic.|
-|`azure-storage-common-cpp`|Patching to disable default features on libxml2 (https://github.com/Azure/azure-sdk-for-cpp/pull/5221).|
+| Port                       | Reason                                                                                                  |
+|----------------------------|---------------------------------------------------------------------------------------------------------|
+| `libmagic`                 | Updating to the upstream port deferred due to failures.                                                 |
+| `openssl`                  | Pinning to OpenSSL 1.1 until we can move to 3.0 in January 2024.                                        |
+| `pcre2`                    | To be removed alongside libmagic.                                                                       |
+| `azure-storage-common-cpp` | Patching to disable default features on libxml2 (https://github.com/Azure/azure-sdk-for-cpp/pull/5221). |
+| `libfaketime`              | Mock time in timing unit tests                                                                          |

ports/libfaketime/CMakeLists.txt

@@ -0,0 +1,64 @@
+cmake_minimum_required(VERSION 3.12)
+
+project(libfaketime VERSION 0.9.10)
+
+add_library(
+        ${PROJECT_NAME}
+        src/libfaketime.c
+)
+
+if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
+    target_link_libraries(
+            ${PROJECT_NAME}
+            rt
+    )
+endif()
+
+target_include_directories(${PROJECT_NAME}
+        PUBLIC
+        "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>"
+        "$<INSTALL_INTERFACE:include>"
+)
+
+file(GLOB_RECURSE PUBLIC_HEADERS "src/*.h")
+
+target_sources(
+        ${PROJECT_NAME}
+        PUBLIC
+        FILE_SET HEADERS
+        BASE_DIRS src
+        FILES ${PUBLIC_HEADERS}
+)
+
+install(TARGETS ${PROJECT_NAME}
+        EXPORT ${PROJECT_NAME}
+        FILE_SET HEADERS
+        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+        INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
+)
+
+install(EXPORT ${PROJECT_NAME}
+        FILE unofficial-${PROJECT_NAME}-targets.cmake
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/unofficial-${PROJECT_NAME}
+        NAMESPACE unofficial::libfaketime::
+)
+
+include(GNUInstallDirs)
+include(CMakePackageConfigHelpers)
+
+configure_package_config_file(
+        unofficial-${PROJECT_NAME}-config.cmake.in
+        unofficial-${PROJECT_NAME}-config.cmake
+        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/unofficial-${PROJECT_NAME})
+
+write_basic_package_version_file(
+        unofficial-${PROJECT_NAME}-config-version.cmake
+        VERSION ${CMAKE_PROJECT_VERSION}
+        COMPATIBILITY SameMajorVersion)
+
+install(FILES
+        ${CMAKE_BINARY_DIR}/unofficial-${PROJECT_NAME}-config.cmake
+        ${CMAKE_BINARY_DIR}/unofficial-${PROJECT_NAME}-config-version.cmake
+        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/unofficial-${PROJECT_NAME})

ports/libfaketime/portfile.cmake

@@ -0,0 +1,27 @@
+vcpkg_check_linkage(ONLY_DYNAMIC_LIBRARY)
+
+vcpkg_from_github(
+    OUT_SOURCE_PATH SOURCE_PATH
+    REPO wolfcw/libfaketime
+    REF v${VERSION}
+    SHA512 07c431bee21e31343b680d1322dd529ea276e3cc4dbec61646c12bf5d0263163faf6186efeb36b199e24b655578a493c43e3b7a7acf8eba8b9ff84a1e94d618b
+)
+
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/CMakeLists.txt" DESTINATION "${SOURCE_PATH}")
+file(COPY "${CMAKE_CURRENT_LIST_DIR}/unofficial-libfaketime-config.cmake.in" DESTINATION "${SOURCE_PATH}")
+
+vcpkg_cmake_configure(
+    SOURCE_PATH ${SOURCE_PATH}
+)
+
+vcpkg_cmake_install()
+vcpkg_copy_pdbs()
+vcpkg_fixup_pkgconfig()
+vcpkg_cmake_config_fixup(
+        CONFIG_PATH lib/cmake/unofficial-libfaketime
+        PACKAGE_NAME unofficial-libfaketime)
+
+file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
+
+# Handle copyright and usage
+vcpkg_install_copyright(FILE_LIST "${SOURCE_PATH}/COPYING")

ports/libfaketime/unofficial-libfaketime-config.cmake.in

@@ -0,0 +1,5 @@
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/unofficial-libfaketime-targets.cmake")
+
+check_required_components("unofficial-libfaketime")

ports/libfaketime/vcpkg.json

@@ -0,0 +1,18 @@
+{
+  "name": "libfaketime",
+  "version": "0.9.10",
+  "license": "GPL-2.0-only",
+  "description": "libfaketime modifies the system time for a single application",
+  "supports": "!windows",
+  "homepage": "https://github.com/wolfcw/libfaketime",
+  "dependencies": [
+    {
+      "name": "vcpkg-cmake",
+      "host": true
+    },
+    {
+      "name": "vcpkg-cmake-config",
+      "host": true
+    }
+  ]
+}

scripts/ci/build_libtiledb.sh

@@ -38,6 +38,7 @@ make -C tiledb install
 ls -la
 
 make -j4 -C tiledb tiledb_unit
+make -j4 -C tiledb tiledb_timing_unit
 make -j4 -C tiledb unit_vfs
 make -j4 -C tiledb tiledb_regression
 make -j4 -C tiledb all_link_complete

test/CMakeLists.txt

@@ -362,6 +362,45 @@ if (${CMAKE_SYSTEM_NAME} MATCHES "Linux" AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU
     )
 endif()
 
+# Only produce timing tests for UNIX based systems (faketime constraint)
+if (NOT MSVC)
+    find_package(unofficial-libfaketime REQUIRED)
+
+    # unit test executable
+    add_executable(
+            tiledb_timing_unit EXCLUDE_FROM_ALL
+            $<TARGET_OBJECTS:TILEDB_CORE_OBJECTS>
+            "src/unit-capi-metadata.cc"
+            "src/unit.cc"
+    )
+
+    target_include_directories(
+            tiledb_timing_unit BEFORE PRIVATE
+            ${TILEDB_CORE_INCLUDE_DIR}
+            ${TILEDB_EXPORT_HEADER_DIR}
+    )
+
+    target_link_libraries(
+            tiledb_timing_unit
+            PUBLIC
+            unofficial::libfaketime::libfaketime
+            TILEDB_CORE_OBJECTS_ILIB
+            TILEDB_CORE_OBJECTS
+            Catch2::Catch2
+            tiledb_test_support_lib
+    )
+
+    target_compile_options(tiledb_timing_unit PRIVATE -Wno-deprecated-declarations)
+
+    add_test(
+            NAME "tiledb_timing_unit"
+            COMMAND tiledb_timing_unit --durations=yes
+            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+    )
+
+    set_property(TEST tiledb_timing_unit PROPERTY ENVIRONMENT_MODIFICATION "FAKETIME=set:2020-12-24 20:30:00")
+endif()
+
 add_test(
   NAME "tiledb_unit"
   COMMAND tiledb_unit --durations=yes

vcpkg.json

@@ -66,7 +66,11 @@
         "tests": {
             "description": "Build tiledb tests",
             "dependencies": [
-                "catch2"
+                "catch2",
+                {
+                  "name": "libfaketime",
+                  "platform": "!windows"
+                }
             ]
         },
         "tools": {