エンティティのダメージ管理 (#674)

data/entity/damage_type/magic.json

@@ -0,0 +1,5 @@
+{
+  "exhaustion": 0,
+  "scaling": "never",
+  "message_id": "tusb:magic"
+}

data/entity/damage_type/physical.json

@@ -0,0 +1,5 @@
+{
+  "exhaustion": 0,
+  "scaling": "never",
+  "message_id": "tusb:physical"
+}

data/entity/damage_type/unreasonable.json

@@ -0,0 +1,5 @@
+{
+  "exhaustion": 0,
+  "scaling": "never",
+  "message_id": "tusb:unreasonable"
+}

data/entity/function/damage/apply/.mcfunction

@@ -0,0 +1,11 @@
+#> entity:damage/apply/
+# 設定された物理、魔法、理外のダメージを実行者に与える。
+
+# 物理ダメージ
+function entity:damage/apply/physical
+
+# 魔法ダメージ
+function entity:damage/apply/magic
+
+# 理外ダメージ
+function entity:damage/apply/unreasonable

data/entity/function/damage/apply/core/.mcfunction

@@ -0,0 +1,15 @@
+#> entity:damage/apply/core/
+
+## ダメージ処理の実行チェック
+# ダメージ値が指定されていなければ中断
+execute unless data storage entity:_ damage.value run return fail
+# 実行者が死亡していれば中断
+execute if predicate entity:damage/check_death run return fail
+
+
+# ダメージ値が割合設定ならば解決する
+execute if data storage entity:_ damage.value{} run function entity:damage/apply/core/resolve_percentage_damage/
+
+# 実行者のentity_typeによって処理を変更する
+execute if entity @s[type=player] run function entity:damage/apply/core/player
+execute unless entity @s[type=player] run function entity:damage/apply/core/mob

data/entity/function/damage/apply/core/apply.macro.mcfunction

@@ -0,0 +1,3 @@
+#> entity:damage/apply/core/apply.macro
+# 受け取ったダメージ属性とダメージ値からdamageコマンドを実行する
+$damage @s $(value) $(type)

data/entity/function/damage/apply/core/mob.mcfunction

@@ -0,0 +1,11 @@
+#> entity:damage/apply/core/mob
+# モブへダメージを与える
+
+# damageコマンドを実行する
+function entity:damage/apply/core/apply.macro with storage entity:_ damage
+
+# HPを更新する
+function enemy:damage/update_health
+
+# Hitダメージフラグを付与
+execute if data storage entity: damage{hit:1b} run tag @s add HitDamageTaken

data/entity/function/damage/apply/core/player.mcfunction

@@ -0,0 +1,12 @@
+#> entity:damage/apply/core/player
+# プレイヤーへダメージを与える
+
+# カスタム死亡ログがあればそれを表示するためにデフォルト死亡ログを非表示
+execute if data storage entity: damage.deathcause run gamerule showDeathMessages false
+
+# damageコマンドを実行する
+function entity:damage/apply/core/apply.macro with storage entity:_ damage
+
+# カスタム死亡ログがあって死亡すればログを表示
+execute if data storage entity: damage.deathcause if data entity @s {Health:0f} run tellraw @a {"storage":"entity:","nbt":"damage.deathcause","interpret":true}
+execute if data storage entity: damage.deathcause run gamerule showDeathMessages true

data/entity/function/damage/apply/core/resolve_percentage_damage/.mcfunction

@@ -0,0 +1,12 @@
+#> entity:damage/apply/core/resolve_percentage_damage/
+# 割合ダメージを実際のダメージへ計算する
+
+# 計算に必要な数値をentity_typeに合わせて取得する
+execute if entity @s[type=player] run function entity:damage/apply/core/resolve_percentage_damage/player
+execute unless entity @s[type=player] run function entity:damage/apply/core/resolve_percentage_damage/mob
+
+# 計算
+execute store result score _ _ run data get storage entity:_ damage.value.percent 100
+scoreboard players operation _ HP *= _ _
+data modify storage entity:_ damage.value set value 0d
+execute store result storage entity:_ damage.value double 0.01 run scoreboard players get _ HP

data/entity/function/damage/apply/core/resolve_percentage_damage/mob.mcfunction

@@ -0,0 +1,6 @@
+#> entity:damage/apply/core/resolve_percentage_damage/mob
+
+# 現在HPを取得
+execute if data storage entity:_ damage.value{select:"current"} run scoreboard players operation _ HP = @s HP
+# 最大HPを取得
+execute if data storage entity:_ damage.value{select:"max"} run scoreboard players operation _ HP = @s HPMax

data/entity/function/damage/apply/core/resolve_percentage_damage/player.mcfunction

@@ -0,0 +1,6 @@
+#> entity:damage/apply/core/resolve_percentage_damage/player
+
+# 現在HPを取得
+execute if data storage entity:_ damage.value{select:"current"} store result score _ HP run data get entity @s Health
+# 最大HPを取得
+execute if data storage entity:_ damage.value{select:"max"} store result score _ HP run attribute @s generic.max_health get

data/entity/function/damage/apply/magic.mcfunction

@@ -0,0 +1,9 @@
+#> entity:damage/apply/magic
+# 設定された魔法ダメージを実行者に与える
+
+# このダメージについての指定
+data modify storage entity:_ damage set value {type:"entity:magic"}
+data modify storage entity:_ damage.value set from storage entity: damage.magic
+
+# core処理を実行
+function entity:damage/apply/core/

data/entity/function/damage/apply/physical.mcfunction

@@ -0,0 +1,9 @@
+#> entity:damage/apply/physical
+# 設定された物理ダメージを実行者に与える
+
+# このダメージについての指定
+data modify storage entity:_ damage set value {type:"entity:physical"}
+data modify storage entity:_ damage.value set from storage entity: damage.physical
+
+# core処理を実行
+function entity:damage/apply/core/

data/entity/function/damage/apply/unreasonable.mcfunction

@@ -0,0 +1,9 @@
+#> entity:damage/apply/unreasonable
+# 設定された理外ダメージを実行者に与える
+
+# このダメージについての指定
+data modify storage entity:_ damage set value {type:"entity:unreasonable"}
+data modify storage entity:_ damage.value set from storage entity: damage.unreasonable
+
+# core処理を実行
+function entity:damage/apply/core/

data/entity/predicate/damage/check_death.json

@@ -0,0 +1,19 @@
+{
+  "condition": "any_of",
+  "terms": [
+    {
+      "condition": "entity_properties",
+      "entity": "this",
+      "predicate": {
+        "nbt": "{Health:0f}"
+      }
+    },
+    {
+      "condition": "entity_properties",
+      "entity": "this",
+      "predicate": {
+        "nbt": "{Tags:[Garbage]}"
+      }
+    }
+  ]
+}

data/minecraft/tags/damage_type/bypasses_cooldown.json

@@ -1,7 +1,7 @@
 {
   "values": [
-    "tusb:unreasonable",
-    "tusb:magic",
-    "tusb:physics"
+    "entity:physical",
+    "entity:magic",
+    "entity:unreasonable"
   ]
-}
+}

data/minecraft/tags/damage_type/no_knockback.json

@@ -1,7 +1,7 @@
 {
   "values": [
-    "tusb:unreasonable",
-    "tusb:magic",
-    "tusb:physics"
+    "entity:physical",
+    "entity:magic",
+    "entity:unreasonable"
   ]
-}
+}