Improvements for Web Components

Improvements that allow applications with Web Components to run with a lower overhead.

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/instance/createCache.st

@@ -0,0 +1,3 @@
+private
+createCache
+	^ WASingleElementCache new

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/instance/testClear.st

@@ -0,0 +1,5 @@
+testing
+testClear
+	cache at: 1 put: 'one'.
+	cache clear.
+	self assert: (cache at: 1 ifAbsent: [ 'two' ]) = 'two'.

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/instance/testKeyAtValue.st

@@ -0,0 +1,5 @@
+testing
+testKeyAtValue
+	cache at: 1 put: 'one'.
+	self assert: (cache keyAtValue: 'one' ifAbsent: [ 2 ]) = 1.
+	self assert: (cache keyAtValue: 'two' ifAbsent: [ 2 ]) = 2.

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/instance/testKeysAndValuesDo.st

@@ -0,0 +1,13 @@
+testing
+testKeysAndValuesDo
+	| reference readBack |
+	reference := Dictionary new.
+
+	cache at: 1 put: 'one'.
+	reference at: 1 put: 'one'.
+
+	readBack := Dictionary new.
+	cache keysAndValuesDo: [ :key :value |
+		readBack at: key put: value ].
+
+	self assert: readBack = reference

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/instance/testSize.st

@@ -0,0 +1,7 @@
+testing
+testSize
+	self assert: cache size = 0.
+	cache at: 1 put: 'one'.
+	self assert: cache size = 1.
+	cache at: 2 put: 'two'.
+	self assert: cache size = 1.

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/instance/testStore.st

@@ -0,0 +1,10 @@
+testing
+testStore
+	| generator |
+	generator := WAPrecomputedKeyGenerator keys: #(1 2 3).
+	WAKeyGenerator
+		use: generator
+		during: [
+			self assert: (cache store: 'key1') = 1.
+			self assert: (cache store: 'key2') = 2.
+			self assert: (cache store: 'key3') = 3 ]

repository/Seaside-Tests-WebComponents.package/WASingleElementCacheTest.class/properties.json

@@ -0,0 +1,11 @@
+{
+	"commentStamp" : "",
+	"super" : "WACacheTest",
+	"category" : "Seaside-Tests-WebComponents",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [ ],
+	"name" : "WASingleElementCacheTest",
+	"type" : "normal"
+}

repository/Seaside-WebComponents-Core.package/WASingleContinuationSession.class/README.md

@@ -0,0 +1 @@
+I am a session that stores only a single continuation. I am usesful for cases where state snapshots are not used.

repository/Seaside-WebComponents-Core.package/WASingleContinuationSession.class/instance/createContinuationCache.st

@@ -0,0 +1,3 @@
+initialization
+createContinuationCache
+	^ WASingleElementCache new

repository/Seaside-WebComponents-Core.package/WASingleContinuationSession.class/properties.json

@@ -0,0 +1,11 @@
+{
+	"commentStamp" : "xxx 7/11/2024 13:25",
+	"super" : "WASession",
+	"category" : "Seaside-WebComponents-Core",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [ ],
+	"name" : "WASingleContinuationSession",
+	"type" : "normal"
+}

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/README.md

@@ -0,0 +1 @@
+I am a cache that contains at most one element.

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/at.ifAbsent..st

@@ -0,0 +1,5 @@
+accessing
+at: aKey ifAbsent: aBlock
+	^ key = aKey
+		ifTrue: [ value ]
+		ifFalse: [ aBlock value ]

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/at.put..st

@@ -0,0 +1,5 @@
+putting
+at: aKey put: anObject
+	key := aKey.
+	value := anObject.
+	^ anObject

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/clear.st

@@ -0,0 +1,4 @@
+public
+clear
+	key := nil.
+	value := nil

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/keyAtValue.ifAbsent..st

@@ -0,0 +1,5 @@
+accessing
+keyAtValue: anObject ifAbsent: aBlock
+	^ value = anObject
+		ifTrue: [ key ]
+		ifFalse: [ aBlock value ]

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/keysAndValuesDo..st

@@ -0,0 +1,4 @@
+enumerating
+keysAndValuesDo: aTwoArgumentBlock
+	key isNil ifFalse: [
+		aTwoArgumentBlock value: key value: value ]

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/remove..st

@@ -0,0 +1,5 @@
+removing
+remove: anObject
+	value = anObject ifTrue: [
+		key := nil.
+		value := nil ]

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/size.st

@@ -0,0 +1,5 @@
+accessing
+size
+	^ key isNil
+		ifTrue: [ 0 ]
+		ifFalse: [ 1 ]

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/instance/store..st

@@ -0,0 +1,5 @@
+putting
+store: anObject
+	key := WAKeyGenerator current keyOfLength: self keySize.
+	value := anObject.
+	^ key

repository/Seaside-WebComponents-Core.package/WASingleElementCache.class/properties.json

@@ -0,0 +1,14 @@
+{
+	"commentStamp" : "xxx 7/11/2024 10:46",
+	"super" : "WACache",
+	"category" : "Seaside-WebComponents-Core",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [
+		"key",
+		"value"
+	],
+	"name" : "WASingleElementCache",
+	"type" : "normal"
+}

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/README.md

@@ -0,0 +1,7 @@
+I am a special action continuation with optimizations for web components.
+
+Since web components have no back button and a full page reload results in an entire new page I perform the following optimizations.
+
+- I do not redirect.
+- I do not capture the state.
+- I do not restore the state.

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/instance/basicPerformAction.st

@@ -0,0 +1,4 @@
+processing
+basicPerformAction
+	super basicPerformAction.
+	self renderContext callbacks handle: self requestContext

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/instance/continue.st

@@ -0,0 +1,4 @@
+processing
+continue
+	"do not capture state"
+	self createRenderContinuation handle: self requestContext

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/instance/handle..st

@@ -0,0 +1,4 @@
+handling
+handle: aRequestContext
+	"don't restore states"
+	self withUnregisteredHandlerDo: [ super handle: aRequestContext ]

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/instance/jumpToAnchor..st

@@ -0,0 +1,3 @@
+public
+jumpToAnchor: aString
+	"Intentionally empty for compatibility with WACallbackProcessingActionContinuation"

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/instance/shouldRedirect.st

@@ -0,0 +1,3 @@
+private
+shouldRedirect
+	^ false

repository/Seaside-WebComponents-Core.package/WAWebComponentActionContinuation.class/properties.json

@@ -0,0 +1,11 @@
+{
+	"commentStamp" : "xxx 7/11/2024 13:24",
+	"super" : "WAActionPhaseContinuation",
+	"category" : "Seaside-WebComponents-Core",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [ ],
+	"name" : "WAWebComponentActionContinuation",
+	"type" : "normal"
+}

repository/Seaside-WebComponents-Examples.package/WAHeadlessCounter.class/class/initialize.st

@@ -4,5 +4,8 @@ initialize
 	"register such that we do not have the developer tools"
 	application := WAAdmin register: WAApplication at: 'examples/headless-counter' in: WAAdmin defaultDispatcher.
 	application configuration addParent: WARenderLoopConfiguration instance.
-	application rootClass: self.
-	application preferenceAt: #renderPhaseContinuationClass put: WAFragmentRenderPhaseContinuation
+	application
+		rootClass: self;
+		sessionClass: WASingleContinuationSession;
+		preferenceAt: #renderPhaseContinuationClass put: WAFragmentRenderPhaseContinuation;
+		preferenceAt: #actionPhaseContinuationClass put: WAWebComponentActionContinuation