build.gradle

plugins {
    id 'fabric-loom' version '1.0-SNAPSHOT'
    id "me.shedaniel.unified-publishing" version "0.1.+"
    id "com.github.breadmoirai.github-release" version "2.4.1"
}

def runNumber = (System.getenv("GITHUB_RUN_NUMBER") == null ? "9999" : System.getenv('GITHUB_RUN_NUMBER'))

archivesBaseName = project.archives_base_name
version = project.mod_version + "." + runNumber
group = project.maven_group

repositories {
    maven {
        url = "https://maven.parchmentmc.org"
    }
    maven {
        url "https://maven.kosmx.dev"
    }
    maven {
        url "https://maven.maxhenkel.de/repository/public"
    }
    maven {
        url = "https://api.modrinth.com/maven"
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings loom.layered() {
        officialMojangMappings()
        parchment("org.parchmentmc.data:parchment-1.16.5:2022.03.06@zip")
    }
    modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modImplementation "de.maxhenkel.voicechat:voicechat-api:${project.voicechat_api}"
    modImplementation "maven.modrinth:simple-voice-chat:fabric-${project.voicechat}"

    modImplementation "io.github.kosmx.emotes:emotesMain:${project.emotecraft}"
    modImplementation "dev.kosmx.player-anim:player-animation-lib-fabric:${project.player_animation_lib}"
    modImplementation "maven.modrinth:emotecraft:${project.emotecraft}+${project.minecraft_version}-fabric"
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    archivesBaseName = project.archives_base_name
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${archivesBaseName}+${version}" }
    }
}

unifiedPublishing {
    project {
        displayName = "[Fabric $project.minecraft_version] v$project.version"
        releaseType = "release"
        gameVersions = ["1.20.1"]
        gameLoaders = ["fabric"]

        mainPublication remapJar

        relations {
            depends {
                curseforge = modrinth = "emotecraft"
            }
            depends {
                curseforge = modrinth = "simple-voice-chat"
            }
        }

        if (project.hasProperty("curse_api_key") || System.getenv("curse_api_key") != null) {
            curseforge {
                token = project.hasProperty("curse_api_key") ? project.property("curse_api_key") : System.getenv("curse_api_key")
                id = project.curseforge_id
                gameVersions.addAll "Java 8"
            }
        }

        if (project.hasProperty("modrinth_key") || System.getenv("modrinth_key") != null) {
            modrinth {
                token = project.hasProperty("modrinth_key") ? project.property("modrinth_key") : System.getenv("modrinth_key")
                id = project.modrinth_id
                version = "$project.version+Fabric"
            }
        }
    }
}

task modPublish