build.gradle

plugins {
    id 'fabric-loom' version '1.7-SNAPSHOT'
    id 'maven-publish'
}

version = project.mod_version + "+" + project.minecraft_version
group = project.maven_group

base {
    archivesName = project.archives_base_name
}

repositories {
    maven { url 'https://maven.wispforest.io/releases/' }
    maven { url "https://maven.terraformersmc.com/releases/" }
}

loom {
    splitEnvironmentSourceSets()

    mods {
        "limelight" {
            sourceSet sourceSets.main
            sourceSet sourceSets.client
        }
    }

    runConfigs.configureEach {
        if (it.environment == "server") {
            ideConfigGenerated false
        }
    }

    accessWidenerPath = file("src/client/resources/limelight.accesswidener")
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${rootProject.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    implementation include("net.objecthunter:exp4j:${project.exp4j_version}")

    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    modImplementation annotationProcessor("io.wispforest:owo-lib:${project.owo_version}")
    api "io.wispforest:endec:${project.endec_version}" // this is provided to us by owo-lib, but we need to explicitly pass it on as API.

    // Optional dependencies
    modCompileOnly "io.wispforest:lavender:${project.lavender_version}"
    modLocalRuntime "io.wispforest:lavender:${project.lavender_version}"

    modCompileOnly "com.terraformersmc:modmenu:${project.modmenu_version}"
    modLocalRuntime "com.terraformersmc:modmenu:${project.modmenu_version}"
}

processClientResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 21
}

java {
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.base.archivesName.get()}"}
    }
}

publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    repositories {
        def ENV = System.getenv()

        if (ENV.MAVEN_URL) {
            repositories.maven {
                url ENV.MAVEN_URL
                credentials {
                    username ENV.MAVEN_USERNAME
                    password ENV.MAVEN_PASSWORD
                }
            }
        }
    }
}