flake.nix

{
  description = "Flake for the Elographics input driver for the Xorg X server";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
  };

  outputs = {
    self,
    nixpkgs,
  } @ inputs: let
    system = "x86_64-linux";
    pkgs = import nixpkgs {
      inherit system;
    };
  in {
    formatter.${system} = pkgs.alejandra;

    packages.${system} = {
      default = self.packages.${system}.xf86-input-elographics;
      xf86-input-elographics = pkgs.stdenv.mkDerivation rec {
        pname = "xf86-input-elographics";

        version = "1.4.4";

        src = pkgs.fetchFromGitLab {
          domain = "gitlab.freedesktop.org";
          owner = "xorg/driver";
          repo = "xf86-input-elographics";
          rev = "${pname}-${version}";
          hash = "sha256-Op3a4MBMk831IhUukP0hTThYZuJgNleoD5AdF71fhLw=";
        };

        nativeBuildInputs = with pkgs; [
          autoreconfHook
          pkg-config
        ];

        buildInputs = with pkgs; [
          udev
          xorg.xorgproto
          xorg.libX11
          xorg.libXext
          xorg.libXi
          xorg.libXinerama
          xorg.libXrandr
          xorg.libXrender
          xorg.pixman
          xorg.utilmacros
          xorg.xorgserver
        ];
      };
    };
  };
}