build.gradle

/*
 * SPDX-License-Identifier: Apache-2.0
 *
 * The OpenSearch Contributors require contributions made to
 * this file be licensed under the Apache-2.0 license or a
 * compatible open source license.
 *
 * Modifications Copyright OpenSearch Contributors. See
 * GitHub history for details.
 */

/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

// Uses Gradle to build RPMs since that's what we use for the other plugins. When all you have is a hammer...
plugins {
   id "nebula.ospackage" version "5.3.0"
}

// To prevent conflicts with maven build under build/
buildDir = 'gradle-build'

ext {
    securityPluginVersion = '1.3.0.0'
    isSnapshot = "true" == System.getProperty("build.snapshot", "true")
}

group = "org.opensearch"
// Increment the final digit when there's a new plugin versions for the same opensearch version
// Reset the final digit to 0 when upgrading to a new opensearch version
version = "${securityPluginVersion}" + (isSnapshot ? "-SNAPSHOT" : "")

if (!project.hasProperty("archivePath")) {
    throw new GradleException("Missing -ParchivePath command line switch pointing to built plugin ZIP")
}
if (!project.file(archivePath).exists()) {
    throw new GradleException("Missing plugin zip file: $archivePath")
}

ospackage {
    packageName = "opensearch-security"
    release = isSnapshot ? "0.1" : '1'
    version = "${project.version}"

    into '/usr/share/opensearch/plugins'
    from(zipTree(project.file(archivePath).absolutePath)) {
        into "opensearch-security"
        permissionGroup 'opensearch'
    }

    user 'root'
    permissionGroup 'root'

    requires('opensearch-oss', "1.3.0", EQUAL)
    packager = 'Amazon'
    vendor = 'Amazon'
    os = 'LINUX'
    prefix '/usr'

    license 'ASL-2.0'
    maintainer 'OpenDistro for Elasticsearch Team <opendistro@amazon.com>'
    url 'https://opendistro.github.io/for-elasticsearch/downloads.html'
    summary '''
     OpenSearch Security plugin. 
     Reference documentation can be found at https://opendistro.github.io/for-elasticsearch-docs/.
     '''.stripIndent().replace('\n', ' ').trim()

    //TODO: Would be better if the install_demo_configuration.sh script is marked executable in the upstream plugin instead of running bash manually here
    postInstall "exec /bin/bash /usr/share/opensearch/plugins/opensearch-security/tools/install_demo_configuration.sh -y -i -s"
}

buildRpm {
    arch = 'NOARCH'
    addParentDirs = false
    archiveName "${packageName}-${version}.rpm"
}

buildDeb {
    arch = 'all'
    archiveName "${packageName}-${version}.deb"
}