build.gradle

import java.text.SimpleDateFormat

def globalVersion = new Version(currentVersion)

allprojects {
	apply plugin: 'idea'

	configurations.all {
	    resolutionStrategy {
	        failOnVersionConflict()
    	    force "org.springframework:spring-core:${springVersion}",
    	          "org.springframework:spring-context:${springVersion}",
    	          "org.springframework:spring-expression:${springVersion}",
                  "org.springframework:spring-beans:${springVersion}",
                  "org.springframework:spring-tx:${springVersion}",
                  "org.hamcrest:hamcrest-core:1.3",
                  'org.slf4j:slf4j-api:1.7.2',
                  'junit:junit:4.11',
                  'xml-apis:xml-apis:2.0.2'
	    }
	}
    group = 'com.u6f6o.apps.moviedb'
    version = globalVersion
    status = version.status
}

subprojects {
	apply plugin: 'java'
	apply plugin: 'groovy'
    apply plugin: 'findbugs'

	sourceCompatibility = 1.6
	targetCompatibility = 1.6

    repositories {
        maven {
            url "${artifactory_repositoryUrl}"
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.7'
    distributionUrl = "${artifactory_repositoryUrl}/gradle-${gradleVersion}-bin.zip"
}

class Version {
    String originalVersion
    String thisVersion
    String status
    Date buildTime

    Version(String versionValue) {
        buildTime = new Date()
        originalVersion = versionValue
        if (originalVersion.endsWith('-SNAPSHOT')) {
            status = 'integration'
            thisVersion = originalVersion.substring(0, originalVersion.length() - 'SNAPSHOT'.length()) + getTimestamp()
        } else {
            status = 'release'
            thisVersion = versionValue
        }
    }

    String getTimestamp() {
        // Convert local file timestamp to UTC
        def format = new SimpleDateFormat('yyyyMMddHHmmss')
        format.setCalendar(Calendar.getInstance(TimeZone.getTimeZone('UTC')));
        return format.format(buildTime)
    }

    String toString() {
        thisVersion
    }
}