build.gradle

plugins {
	id "fabric-loom" version "1.8-SNAPSHOT"
}

version = project.mod_version
group = project.maven_group

repositories {
	maven { url "https://maven.nucleoid.xyz" }
	maven { url "https://maven.terraformersmc.com" }
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"

	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api}"
	modImplementation include("eu.pb4:placeholder-api:${project.placeholder_api}")
	modImplementation include("eu.pb4:polymer-virtual-entity:${project.polymer_version}")
}

sourceSets {
	testmod {
		compileClasspath += main.compileClasspath
		runtimeClasspath += main.runtimeClasspath

		dependencies {
			testmodImplementation sourceSets.main.output
		}
	}
}

loom {
	runs {
		testmodClient {
			client()
			name = "Test Client"
			runDir = "testrun"
			source = sourceSets.testmod
		}
		testmodServer {
			server()
			name = "Test Server"
			runDir = "testrun"
			source = sourceSets.testmod
		}
	}

	accessWidenerPath = file("src/main/resources/entity-health-display.accesswidener")
}

base {
	archivesName = project.archives_base_name
}

processResources {
    def expandProps = [
            "version": rootProject.mod_version,
            "minecraft_version_range": rootProject.minecraft_version_range,
    ]

    filesMatching(["fabric.mod.json"]) {
        expand expandProps
    }

    inputs.properties(expandProps)
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	it.options.release = 21
}

java {
	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}" }
	}
}