How to change pname?

[s3igo]

Hello,

I started my project using the executable template from this repository.
In the dune file, specifying a public_name different from the name in the executable stanza changes the name of the executable file, making it impossible to run with $ nix run . Is there a way to fix this?

$ nix run .
error: unable to execute '/nix/store/vwlh6a1hfcp3683sr5bnry1a0pll0jwm-hello_world-dev/bin/hello_world': No such file or directory

$ ls -l /nix/store/vwlh6a1hfcp3683sr5bnry1a0pll0jwm-hello_world-dev/bin/
total 384
-r-xr-xr-x 1 root wheel 392048 Jan  1  1970 hello-world*

It seems that the problem is caused by the difference between the name of the executable and the pname of the created derivation. I considered changing the name stanza in the dune-project file, but it doesn't accept kebab-case, so that doesn't solve the problem.

Here is the source code for the reproduction:

flake.nix (only changed throw "Put the package name here!" to "hello_world")

{
  inputs = {
    opam-nix.url = "github:tweag/opam-nix";
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.follows = "opam-nix/nixpkgs";
  };
  outputs = { self, flake-utils, opam-nix, nixpkgs }@inputs:
    # Don't forget to put the package name instead of `throw':
    let package = "hello_world";
    in flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        on = opam-nix.lib.${system};
        devPackagesQuery = {
          # You can add "development" packages here. They will get added to the devShell automatically.
          ocaml-lsp-server = "*";
          ocamlformat = "*";
        };
        query = devPackagesQuery // {
          ## You can force versions of certain packages here, e.g:
          ## - force the ocaml compiler to be taken from opam-repository:
          ocaml-base-compiler = "*";
          ## - or force the compiler to be taken from nixpkgs and be a certain version:
          # ocaml-system = "4.14.0";
          ## - or force ocamlfind to be a certain version:
          # ocamlfind = "1.9.2";
        };
        scope = on.buildOpamProject' { } ./. query;
        overlay = final: prev: {
          # You can add overrides here
          ${package} = prev.${package}.overrideAttrs (_: {
            # Prevent the ocaml dependencies from leaking into dependent environments
            doNixSupport = false;
          });
        };
        scope' = scope.overrideScope' overlay;
        # The main package containing the executable
        main = scope'.${package};
        # Packages from devPackagesQuery
        devPackages = builtins.attrValues
          (pkgs.lib.getAttrs (builtins.attrNames devPackagesQuery) scope');
      in {
        legacyPackages = scope';

        packages.default = main;

        devShells.default = pkgs.mkShell {
          inputsFrom = [ main ];
          buildInputs = devPackages ++ [
            # You can add packages from nixpkgs here
          ];
        };
      });
}

dune-project

(lang dune 3.12)
(name hello_world)

(generate_opam_files true)

(package
 (name hello_world))

dune

(executable
 (name hello_world)
 (public_name hello-world)) ; different from hello_world

hello_world.opam

# This file is generated by dune, edit dune-project instead
opam-version: "2.0"
depends: [
  "dune" {>= "3.12"}
  "odoc" {with-doc}
]
build: [
  ["dune" "subst"] {dev}
  [
    "dune"
    "build"
    "-p"
    name
    "-j"
    jobs
    "@install"
    "@runtest" {with-test}
    "@doc" {with-doc}
  ]
]

hello_world.ml

let () = print_endline "Hello, world!"

[balsoft]

Is nix shell . -c hello-world not acceptable for you?

Otherwise, you can add apps.default = { type = "app"; program = "${self.packages.${system}.default}/bin/hello-world"; } to your flake, so that Nix knows which executable to run precisely.

[s3igo]

Thanks!
It seems my understanding of flakes was inadequate.