Error: unpacker produced multiple directories when installing timedesc

[MarcCoquand]

Heya! Thanks for developing this awesome package.

I ran into an issue when trying to install the timedesc opam package. It runs into an error "unpacker produced multiple directories".

I don't really know how to debug this issue, but here is the full error

error: builder for '/nix/store/2xrb8jjl70y9bph3340fhc6yp8yi5yfc-timedesc-tzdb-2.0.0.drv' failed with exit code 1;
       last 3 log lines:
       > unpacking sources
       > unpacking source archive /nix/store/7vk36zdb2sfy4x6sv7grfm87jgq414hk-timedesc-2.0.0.tar.gz
       > unpacker produced multiple directories
       For full logs, run 'nix log /nix/store/2xrb8jjl70y9bph3340fhc6yp8yi5yfc-timedesc-tzdb-2.0.0.drv'.
error: 1 dependencies of derivation '/nix/store/59v5x4spz0pb4dd797skhdh1xih2c3x9-timedesc-2.0.0.drv' failed to build
error: 1 dependencies of derivation '/nix/store/vbh1kdyxsixsccya94xqfrprwjv5p17y-nix-shell-env.drv' failed to build

and the flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
    opam-nix.url = "github:tweag/opam-nix";
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.follows = "opam-nix/nixpkgs";
  };
  outputs = { self, flake-utils, opam-nix, nixpkgs }@inputs:
    let package = "fixgen";
    in flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        on = opam-nix.lib.${system};
        devPackagesQuery = {
          ocaml-lsp-server = "*";
          ocamlformat = "*";
          ocamlfind = "1.9.5";
          utop = "*";
        };
        query = devPackagesQuery // {
          ocaml-base-compiler = "*";
        };
        scope = on.buildOpamProject' { } ./. query;
        overlay = final: prev: {
          # You can add overrides here
          ${package} = prev.${package}.overrideAttrs (_: {
          });
        };
        scope' = scope.overrideScope' overlay;
        # The main package containing the executable
        main = scope'.${package};
        # Packages from devPackagesQuery
        devPackages = builtins.attrValues
          (pkgs.lib.getAttrs (builtins.attrNames devPackagesQuery) scope');
      in {
        legacyPackages = scope';

        packages.default = main;

        devShells.default = pkgs.mkShell {
          inputsFrom = [ main ];
          buildInputs = devPackages ++ [
          ];
        };
      });
}

as well as the opam file

# This file is generated by dune, edit dune-project instead
opam-version: "2.0"
synopsis: "Generate fixtures for testing"
description: "Generate fixtures for testing"
maintainer: ["Marc Coquand"]
authors: ["Marc Coquand"]
license: "AGPL-3.0-only"
doc: "https://url/to/documentation"
depends: [
  "ocaml"
  "dune" {>= "3.11"}
  "ppx_inline_test"
  "ppx_deriving"
  "uuidm"
  "alcotest"
  "cmdliner"
  "timedesc"
  "odoc" {with-doc}
]
build: [
  ["dune" "subst"] {dev}
  [
    "dune"
    "build"
    "-p"
    name
    "-j"
    jobs
    "@install"
    "@runtest" {with-test}
    "@doc" {with-doc}
  ]
]

The latest entry "timedesc" is the one that broke the build. Any clue what I am missing?

[balsoft]

It seems that the timedesc archive contains multiple top-level directories. The proper way to deal with this is to just fix it (by adding an issue upstream). Until that is fixed, you could try adding an override for packages which use this archive, something like this:

        overlay = final: prev: {
          # You can add overrides here
          timedesc-tzdb = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });
          timedesc-tzlocal = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });
          timedesc = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });
        };

This just tells nixpkgs stdenv to use archive's top-level instead of trying to change to a directory.

[ajbt200128]

helpful answer! Got stuck on this for awhile though because you wrote:

          timedesc-tzdb = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });
          timedesc-tzlocal = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });
          timedesc = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });

but really it should be

          timedesc-tzdb = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; });
          timedesc-tzlocal = prev.timedesc-tzlocal.overrideAttrs (_: { sourceRoot = "."; });
          timedesc = prev.timedesc.overrideAttrs (_: { sourceRoot = "."; });

note that you accidentally copypasted the overrideattrs line and never switched the package name
:D

[balsoft]

Actually, this reminded me that I should just add those overrides to opam-nix itself. Done in 464863f :)

[MarcCoquand]

Adding the overrides worked! Thank you! I'll see if I can get around to opening an issue upstream later.

…

On Fri Dec 29, 2023 at 3:56 AM CST, Alexander Bantyev wrote: It seems that the `timedesc` archive contains multiple top-level directories. The proper way to deal with this is to just fix it (by adding an issue upstream). Until that is fixed, you could try adding an override for packages which use this archive, something like this: ```nix overlay = final: prev: { # You can add overrides here timedesc-tzdb = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; }); timedesc-tzlocal = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; }); timedesc = prev.timedesc-tzdb.overrideAttrs (_: { sourceRoot = "."; }); }; ``` This just tells nixpkgs stdenv to use archive's top-level instead of trying to change to a directory.