Question: Add build flags to specific package

[leana8959]

Hello,

First of all, apologies for opening an issue, I don't know where else to ask it.

I'm trying to put why3 v1.6.0 in a flake. The problem is that, I need to enable the IDE with the --enable-ide flag at build time (similar to configureFlags). Is there a way to do this currently?
I've tried to use the overlay mechanism to add the flag, but it didn't work since it's more designed for env variables as far as I understand.

Here's the nix file I currently have:

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    opam-nix.url = "github:tweag/opam-nix";
  };

  outputs = {
    self,
    nixpkgs,
    opam-nix,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      why3 = let
        inherit (opam-nix.lib.${system}) queryToScope;
        scope = queryToScope {} {
          why3 = "1.6.0";
          ocaml-base-compiler = "*";
        };
        overlay = self: super: {
          why3 = super.why3.overrideAttrs (
            oa: { }
          );
        };
      in (scope.overrideScope' overlay).why3;

      pkgs = nixpkgs.legacyPackages.${system};
    in {
      devShell = pkgs.mkShell {
        packages = [
          why3
        ];
      };
    });
}

Thank you for your time :)

[balsoft]

Hey @leana8959 , I've added Discussions to the repo, so that people can ask questions without opening issues.

As for your issue, why not use the why3-ide package? It has the --enable-ide flag already.

If you really want to override the why3 package, something like this could work:

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    opam-nix.url = "github:tweag/opam-nix";
    nix-optics.url = "github:balsoft/nix-optics";
  };

  outputs = { self, nixpkgs, opam-nix, flake-utils, nix-optics, }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        why3 = let
          inherit (opam-nix.lib.${system}) queryToScope;
          scope = queryToScope { } {
            why3 = "1.6.0";
            ocaml-base-compiler = "*";
          };
          overlay = self: super: {
            why3 = super.why3.overrideAttrs (with nix-optics.lib;
              (optics set fn).path [ "passthru" "pkgdef" "build" ]
              ((optics list fn).path [ 1 ] (flags:
                nixpkgs.lib.remove "--disable-ide" flags
                ++ [ "--enable-ide" ])));
          };
        in (scope.overrideScope' overlay).why3;

        pkgs = nixpkgs.legacyPackages.${system};
      in {
        devShell = pkgs.mkShell {
          packages = [ why3 ];
        };
      });
}

This modifies the second element (which is the ./configure call) of why3's passthru.pkgdef.build list (which is the list of build commands as defined in the opam file), removing "--disable-ide" and inserting "--enable-ide".

Alternatively, just replace --disable-ide with --enable-ide in the buildPhase:

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.11";
    opam-nix.url = "github:tweag/opam-nix";
    nix-optics.url = "github:balsoft/nix-optics";
  };

  outputs = { self, nixpkgs, opam-nix, flake-utils, nix-optics, }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        why3 = let
          inherit (opam-nix.lib.${system}) queryToScope;
          scope = queryToScope { } {
            why3 = "1.6.0";
            ocaml-base-compiler = "*";
          };
          overlay = self: super: {
            why3 = super.why3.overrideAttrs (oa: {
              buildPhase =
                builtins.replaceStrings ["--disable-ide"] ["--enable-ide"]
                oa.buildPhase;
            });
          };
        in (scope.overrideScope' overlay).why3;

        pkgs = nixpkgs.legacyPackages.${system};
      in {
        devShell = pkgs.mkShell {
          packages = [ why3 ];
        };
      });
}

[leana8959]

Thank you for opening the discussion feature!

As for your issue, why not use the why3-ide package? It has the --enable-ide flag already.

Maybe I'm missing something obvious, but I can't get why3-ide to work. Here's a simple test:

nix shell 'github:tweag/opam-nix#why3-ide."1.6.0"'

Running this command should drop me into a shell with why3 with IDE support. However, why3 is not a command in the new shell, and upon further inspections I found that /nix/store/...-why3-ide-1.6.0/ only contains a lib/ folder, there's no bin/. What would you suggest trying in this case? I checked why3-ide's opam page, and I'm perplexed that this doesn't work...

I tried both of your solutions, technically they answer my question (add the compile flag), however I'm getting build errors since there are missing dependencies and I feel like that isn't the cleanest solution if I go down the rabbit hole, sadly.

[balsoft]

Huh, that's a weird problem with why3-ide. I'll take a look.