launcher.ks

// SCRIPT TO LAUNCH AND CIRCULARIZE FROM KERBIN

//VARIABLES
SET launch_count TO 3.
SET v_throttle TO 0.3.
SET angle_of_the_dangle TO 90.
SET let_em_fly TO 0.

//FUNCTIONS
FUNCTION drop_it_like_it_is_hot {
	IF (MAXTHRUST = 0 AND let_em_fly = 1) {
		STAGE.
		PRINT "JETTISONED SPENT STAGE".
		PRINT " ".
	}
}

FUNCTION steer_it {
	SET angle_of_the_dangle TO (90 * (0.9 - ALTITUDE / 25000)).
	LOCK STEERING TO HEADING (90,angle_of_the_dangle).
	IF ALTITUDE > 20000 {
		SET angle_of_the_dangle TO 20.
		LOCK STEERING TO HEADING (90,angle_of_the_dangle).
	}
}

FUNCTION throttle_it {
	PARAMETER howfast.
	IF (SHIP:SURFACESPEED > howfast AND v_throttle > 0.) {
		SET v_throttle TO v_throttle - 0.5.
	} ELSE IF v_throttle < 1 {
		SET v_throttle TO v_throttle + 0.5.
	}
	LOCK THROTTLE TO v_throttle.
}

//FAKE PRE-FLIGHT CHECK OUTPUT
WAIT 1.
CLEARSCREEN.
WAIT 1.
PRINT "=========================".
PRINT "STARTING LAUNCH SEQUENCE".
PRINT "=========================".
PRINT " ".
WAIT 1.5.
PRINT "CHECKING SYSTEMS...".
PRINT " ".
WAIT 2.
PRINT "STATUS IS SLIGHTLY BETTER THAN OK".
PRINT " ".
WAIT 0.5.
PRINT SHIP:NAME + " IS READY FOR LAUNCH...".
PRINT " ".
WAIT 1.

//COUNTDOWN & LAUNCH
UNTIL launch_count = 0 {
	PRINT "T-" + launch_count + "...".
	PRINT " ".
	SET launch_count TO launch_count -1.
	IF launch_count = 1 {
	}
	WAIT 1.
}
SET SHIP:CONTROL:MAINTHROTTLE TO 0.
PRINT "START ENGINES AND RELEASE STABALIZERS".
PRINT " ".
LOCK THROTTLE TO 1.
STAGE.
SET let_em_fly TO 1.
PRINT SHIP:NAME + " IS AWAY".
PRINT " ".

//MOVIN' ON UP
WAIT UNTIL SHIP:ALTITUDE > 200. 
PRINT "STARTING TURN".
PRINT " ".
WAIT 0.5.
LOCK STEERING TO HEADING (90,90).
WAIT 5.
UNTIL SHIP:APOAPSIS > 80000 {
	UNTIL SHIP:ALTITUDE > 45000 {
		IF SHIP:SURFACESPEED > 400 {
				throttle_it((400 + (SHIP:ALTITUDE / 10)) / 3).
				//PRINT "SURFACE SPEED = " + ROUND(SHIP:SURFACESPEED) + "M/S    LIMIT = " + ROUND((300 + (SHIP:ALTITUDE / 10)) / 3.25) + "M/S".
		}
		steer_it().
		drop_it_like_it_is_hot().
		WAIT 0.2.
	}
	LOCK THROTTLE TO 1.
	steer_it().
	drop_it_like_it_is_hot().
	WAIT 0.2.
}
LOCK THROTTLE TO 0.
LOCK STEERING TO PROGRADE.
PRINT "COASTING TO APOAPSIS".
PRINT " ".

//CIRCULARIZE
WAIT UNTIL SHIP:ALTITUDE > 70000.
WAIT 1.
PRINT "LEAVING " + BODY:NAME + " ATMOSPHERE".
PRINT " ".
PRINT "EXTENDING SOLAR PANELS AND POWERING LIGHTS".
PRINT " ".
WAIT 1.
ABORT ON.
PRINT "PREPARING FOR CIRCULARIZATION BURN".
PRINT " ".
WAIT UNTIL ETA:APOAPSIS < 8.
PRINT "CIRCULARIZATION BURN".
PRINT " ".
LOCK THROTTLE TO 1.
UNTIL SHIP:PERIAPSIS > 75000 {
	drop_it_like_it_is_hot().
	WAIT 0.1.
}
LOCK THROTTLE TO 0.
PRINT "YOU ARE NOW ORBITING KERBIN".
PRINT " ".
PRINT "SHUTTING DOWN PROGRAM".
PRINT " ".
WAIT 5.