build.gradle

plugins {
    id "org.jetbrains.kotlin.jvm" version "$kotlin_version"
    id "application"
    id "com.exactpro.th2.gradle.component" version "0.1.3"
}

group = 'com.exactpro.th2'
version = release_version

kotlin.jvmToolchain(11)

ext {
    commonVersion = '5.14.0-dev'
    sailfishVersion = '3.3.241'
    excludeSailfish = { rcd ->
        rcd.excludeModule("com.exactpro.sf", "sailfish-core")
        rcd.excludeModule("com.exactpro.sf", "sailfish-common")
        rcd.excludeModule("com.exactpro.sf", "sailfish-rest-api-client")
        rcd.excludeModule("com.exactpro.sf", "service-http")
    }
}

repositories {
    maven {
        name 'Sonatype_snapshots'
        url 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
        content {
            excludeSailfish(it)
        }
    }

    // ignoreGradleMetadataRedirection is used for sonatype because
    // Sailfish dependencies have constrains that interfere with our BOM
    // so we exclude Gradle metadata for this repositories.
    // We've checked these versions - they are compatible and safe to use
    maven {
        name 'Sonatype_snapshots'
        url 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
        metadataSources {
            mavenPom()
            artifact()
            ignoreGradleMetadataRedirection()
        }
    }

    maven {
        name 'Sonatype_releases'
        url 'https://s01.oss.sonatype.org/content/repositories/releases/'
        content {
            excludeSailfish(it)
        }
    }

    maven {
        name 'Sonatype_releases'
        url 'https://s01.oss.sonatype.org/content/repositories/releases/'
        metadataSources {
            mavenPom()
            artifact()
            ignoreGradleMetadataRedirection()
        }
    }

    mavenCentral()
    mavenLocal()

    configurations.configureEach {
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
        resolutionStrategy.cacheDynamicVersionsFor 0, 'seconds'
    }
}

dependencies {
    implementation "com.exactpro.th2:common:$commonVersion"
    implementation "com.exactpro.th2:grpc-check1:4.4.1-dev"
    implementation "com.exactpro.th2:common-utils:2.3.0-dev"
    implementation("com.exactpro.th2:sailfish-utils:4.1.1-dev") {
        exclude group: "commons-configuration", module: "commons-configuration" // because of the vulnerability
        exclude group: 'com.fasterxml.jackson.dataformat', module: 'jackson-dataformat-yaml' // because of the vulnerability
        exclude group: 'junit', module: 'junit' // because of the vulnerability
        exclude group: 'com.exactpro.mina', module: 'apache-mina-core' // because of the vulnerability
    }

    implementation "org.slf4j:slf4j-api"

    implementation ("com.exactpro.sf:sailfish-common:$sailfishVersion") {
        exclude group: "commons-configuration", module: "commons-configuration" // because of the vulnerability
        exclude group: "com.fasterxml.jackson.dataformat", module: "jackson-dataformat-yaml" // because of the vulnerability
        exclude group: "com.exactpro.mina", module: "apache-mina-core" // because of the vulnerability
        exclude group: "javax.activation", module: "javax.activation-api" // because of the license
    }

    implementation "io.reactivex.rxjava2:rxjava:2.2.21" // https://github.com/salesforce/reactive-grpc/issues/202

    implementation("io.prometheus:simpleclient") {
        because('metrics from messages and rules')
    }

    testImplementation "org.junit.jupiter:junit-jupiter"
    testImplementation "org.jetbrains.kotlin:kotlin-test-junit5"
    testImplementation "org.mockito.kotlin:mockito-kotlin:5.4.0"
}

test.useJUnitPlatform()
application.mainClass = "com.exactpro.th2.check1.Check1Main"