# flake.nix
{
  description = "A flake to build a Statamic docker image";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
  };


  outputs = { self, nixpkgs }: {
    packages."x86_64-linux" =
      let
        pkgs = import nixpkgs { system = "x86_64-linux"; };
      in
      rec {
        default =
          pkgs.dockerTools.buildLayeredImage (
            let
              COMPOSER_HOME = "/tmp/composer";
            in
            rec {
              name = "statamic-demo-image";
              tag = "latest";

              contents = with pkgs; [
                dockerTools.usrBinEnv
                dockerTools.binSh
                dockerTools.caCertificates

                coreutils
                gnugrep
                git

                php81
                php81Packages.composer

                (writeTextDir "etc/passwd" ''
                  root:x:0:0::/root:${runtimeShell}
                '')
                (writeTextDir "root/.ssh/config" ''
                  Host *
                    StrictHostKeyChecking no
                '')

                (writeScriptBin "entrypoint" ''
                  #!${dockerTools.binSh}/bin/sh

                  ${pkgs.php81Packages.composer}/bin/composer global require statamic/cli

                  ${COMPOSER_HOME}/vendor/bin/statamic new -f -n -- test01
                  ${pkgs.php81Packages.composer}/bin/composer global show | grep prompts
                  ${dockerTools.binSh}/bin/sh
                '')
              ];

              config = {
                Entrypoint = [ "entrypoint" ];
                WorkingDir = "/project";
                Env = [
                  "COMPOSER_HOME=${COMPOSER_HOME}"
                  "COMPOSER_ALLOW_SUPERUSER=1"
                ];
                Volumes = {
                  "/project" = { };
                };
              };
            }
          );
      };
  };
}