string.A51

#include <89c51rx2.inc>
#include "battleship.inc"

NAME STRING

EXTRN CODE (SEND_RS232)
EXTRN CODE (RECEIVE_COORD)
EXTRN CODE (RECEIVE_DIR)

PUBLIC SENDSTRMODE
PUBLIC SENDMODEINSRT
PUBLIC SENDSTRREADY
PUBLIC SEND_PRESENTPLYR	
PUBLIC SEND_STRGAMEOVER
PUBLIC WAITING_DIR
PUBLIC WAITING_COORD
PUBLIC SEND_STRSHIPNR
PUBLIC SEND_PB2START



STRINGCODE SEGMENT CODE
RSEG STRINGCODE

SEND_PB2START:
MOV DPTR,#STRPRESS
SEND_STR:
     CLR A
     MOVC A,@A+DPTR
     JZ ENDSTR
     LCALL SEND_RS232
     INC DPTR
     JMP SEND_STR
    ENDSTR:
        RET

SENDSTRREADY:
    ACALL SEND_PRESENTPLYR
	MOV DPTR,#STRREADY
	ACALL SEND_STR
	MOV A,#10
	LCALL SEND_RS232
	RET
		
SENDSTRMODE:
	MOV DPTR,#STRGAMEMODE
	ACALL SEND_STR
	MOV A,#10
	LCALL SEND_RS232
	RET
	
SENDMODEINSRT:
	MOV DPTR,#STRAUTOINSRT
	ACALL SEND_STR
	MOV A,#10
	LCALL SEND_RS232
	RET	

SEND_PRESENTPLYR:
    MOV DPTR,#STRPLYR
    ACALL SEND_STR
    CJNE R1,#BOARD_1HIT,SENDPLAYER2
    MOV A,#'1'
    LCALL SEND_RS232
    JMP RET_SENDPLYR
    SENDPLAYER2:
        MOV A,#'2'
        LCALL SEND_RS232
    RET_SENDPLYR:
    RET

WAITING_COORD:
    PUSH DPH
    PUSH DPL
    MOV DPTR,#STRCOORD
    ACALL SEND_STR
    LCALL RECEIVE_COORD		           ;espera para receção de coordenada valida	
    MOV A,#10 			;NL = New Line
    LCALL SEND_RS232
    POP DPL
    POP DPH
    RET

WAITING_DIR:
    PUSH DPH
    PUSH DPL
    MOV DPTR,#STRDIR
    ACALL SEND_STR
	LCALL RECEIVE_DIR
    MOV A,#10 			;NL = New Line
    LCALL SEND_RS232
    POP DPL
    POP DPH
    RET

SEND_STRSHIPNR:
    PUSH DPH
    PUSH DPL
    MOV DPTR,#STRSHIP
    ACALL SEND_STR
    MOV A,SHIP_NUMBER
	LCALL SEND_RS232
    MOV A,#10 			;NL = New Line
    LCALL SEND_RS232
    POP DPL
    POP DPH
    RET

SEND_STRGAMEOVER:
    MOV DPTR,#STRGAMEOVER
    LCALL SEND_STR 
    LCALL SEND_PRESENTPLYR
    MOV A,#10
    LCALL SEND_RS232
    MOV A,MINUTO
    MOV B,#10
    DIV AB
    ADD A,#'0'
    LCALL SEND_RS232
    MOV A,B
    ADD A,#'0'
    LCALL SEND_RS232
    MOV A,#':'
    LCALL SEND_RS232
    MOV A,SEGUNDO
    MOV B,#10
    DIV AB
    ADD A,#'0'
    LCALL SEND_RS232
    MOV A,B
    ADD A,#'0'
    LCALL SEND_RS232
    MOV A,#10
    LCALL SEND_RS232
    RET

STRGAMEMODE:
	DB 'MODO DE JOGO:',10,'1- HUMANO VS HUMANO',10,'2- HUMANO VS 8051',0
STRAUTOINSRT:
DB 10,'INSERIR AUTO.?(Y ou N)',0
STRSHIP:
    DB 'INSERT SHIP N.: ',0
STRDIR:
	DB 'DIR(V OU H): ',0
STRCOORD:
    DB 'COORD(LETRANUM): ',0
STRGAMEOVER:
    DB '     **GAMEOVER**',10,'        WINNER',10,0
STRPLYR:
    DB '       PLAYER ',0
STRPRESS:
    DB '*PRESS BUTTON 2 (P3.5) TO START*',10,0
STRREADY:
    DB 10,'READY?',10,'(PRESS PB2)',10,0

END