build.gradle

import org.apache.tools.ant.taskdefs.condition.Os
/*
 * This build file was auto generated by running the Gradle 'init' task
 * by 'Silvio Wangler' at '10/27/16 7:17 AM' with Gradle 3.1
 *
 * This generated file contains a commented-out sample Java project to get you started.
 * For more details take a look at the Java Quickstart chapter in the Gradle
 * user guide available at https://docs.gradle.org/3.1/userguide/tutorial_java_projects.html
 */


// Apply the java plugin to add support for Java
apply plugin: 'groovy'
apply from: "gradle/osSpecificDownloads.gradle"

ext {
    // The drivers we want to use
    drivers = ["chrome", "firefox", "safari"]
}

// In this section you declare where to find the dependencies of your project
repositories {
    // Use 'jcenter' for resolving your dependencies.
    // You can declare any Maven/Ivy/file repository here.
    jcenter()
}

// In this section you declare the dependencies for your production and test code
dependencies {
    testCompile "org.codehaus.groovy:groovy-all:2.5.7"

    // If using Spock, need to depend on geb-spock
    testCompile "org.gebish:geb-spock:2.3.1"
    testCompile "org.spockframework:spock-core:1.2-groovy-2.5"

    // Need a driver implementation
    testRuntime "org.seleniumhq.selenium:selenium-support:$seleniumVersion"
    testCompile "org.seleniumhq.selenium:selenium-chrome-driver:$seleniumVersion"
    testCompile "org.seleniumhq.selenium:selenium-firefox-driver:$seleniumVersion"
    testCompile "org.seleniumhq.selenium:selenium-safari-driver:$seleniumVersion"
    
    testCompile "io.github.bonigarcia:webdrivermanager:3.5.0"

    testRuntime 'ch.qos.logback:logback-classic:1.2.3'

}

drivers.each { driver ->
    task "${driver}Test"(type: Test) {
        reports {
            html.destination = reporting.file("$name/tests")
            junitXml.destination = file("$buildDir/test-results/$name")
        }

        outputs.upToDateWhen { false }  // Always run tests

        systemProperty "geb.build.reportsDir", reporting.file("$name/geb")
        systemProperty "geb.env", driver

        // If you wanted to set the baseUrl in your build…
        // systemProperty "geb.build.baseUrl", "http://myapp.com"
    }
}

chromeTest {
    dependsOn unzipChromeDriver

    def chromedriverFilename = Os.isFamily(Os.FAMILY_WINDOWS) ? "chromedriver.exe" : "chromedriver"
    systemProperty "webdriver.chrome.driver", new File(unzipChromeDriver.outputs.files.singleFile, chromedriverFilename).absolutePath
}

test {
    dependsOn drivers.collect { tasks["${it}Test"] }
    enabled = false
}