Problem with blank.detect operator interrupting the stream. It should just execute a blankhandler which inserts metadata into the stream.

[mojikosu]

Dear community,
I am trying to create a vinyl record streaming station with automatic embedding of metadata into the stream using songrec.
Songrec is an opensource shazam client available under: https://github.com/marin-m/SongRec

Hardware:

• Turntable connected to
• USB Behringer UFO202 interface, which is the ALSA input device
• Raspberry Pi3 B (Raspbian bookworkm 32-bit)

Philosophy of the project:

1. Capture audio from Turntable via USB Interface.
2. Use liquidsoap to setup stream with some audio tweaks.
3. Liquidsoap should call songrec, whenever a track on the vinyl record is over. Songrec listens for the new song, identifies it, provides metadata in JSON format.
4. JSON format is parsed by liquidsoap and metadata is inserted into the stream.
5. Output to icecast

I fail with the behaviour, that after each track, blank.detect (?) interrupts the stream, making the Sonos speakers disconnect.

Please find the corresponding .liq file down below.

It's probably a ridiculously simple issue, but I cannot get my head around the solution.

Dear community, many thanks for your input.
Best regards.
Bien le bonjour du Luxembourg.

#!/home/kosuke/.opam/default/bin/liquidsoap
# set the path and permissions for the logfile
set("log.file.path","/var/log/liquidsoap/VinylfromWax.log")
set("log.file.perms",777)
set("log.unix_timestamps",true)
#input from soundcard
s = (input.alsa(device = "pcm.default"))

s = amplify(3.1 ,s)
s = bass_boost(frequency=160.0 ,gain=2.0 ,s)
#======================FORMATS======================================================
#-----------------MP3 Stream with floating point encoder
f = %mp3.cbr(samplerate=44100,bitrate=320)
#-----------------FLAC stream with OGG encapsulation
#fflac = %ogg(%flac(samplerate=44100,channels=2,compression=5,bits_per_sample=16))
#-----------------MP3 Stream with fixed point encoder SHINE
#f = %shine(channels=2,samplerate=44100,bitrate=320)
#-----------------OGG VORBIS stream
fvorbis = %ogg(%vorbis.cbr(samplerate=44100, channels=2, bitrate=128))
#===================================================================================


#======Prepare source to accept metadata injection=========
s = insert_metadata(s)
#================ Do something on Blank detection: ========
#======== Launch songrec to detect one song, output as JSON, print results on stdout, insert metadata into stream========
def blankhandler()

  json =  process.read("songrec recognize --json")
  let json.parse ({
    track = {
      subtitle,
      title,   
      images = {
        coverart }
     }
    } : {
     track : {
      subtitle : string,
      title : string,  
      images : {
       coverart: string }
    }
    }) = json
  print("Found track #{title}, artist is #{subtitle}, cover art url is #{coverart}")
  thread.run({
  s.insert_metadata([("title", title),("artist", subtitle)]) })
end

def print_metadata(m) =
  title = m["title"]
  artist = m["artist"]
  print("#{artist} - #{title}")
end

s.on_metadata(print_metadata)

s = blank.detect(
  threshold=-33., 
  max_blank=2., 
   blankhandler, 
   on_noise=blankhandler,
  s)

#=================OUTPUT TO ICECAST ==================
output.icecast(f, 
host = "127.0.0.1", 
port = 8000, 
password = "WaxVinyl", 
mount = "vinyl", 
name = "Vinyl from Wax",
id="Vinyl Station", 
send_icy_metadata=true,
description="Vinyl from Wax",
#url="http://IP-ADDRESS”,
s)

output.icecast(fvorbis,
host = "127.0.0.1",
port = 8000,
password = "WaxVinyl",
mount = "vinylogg.ogg",
name = "Vinyl from Wax",
id="Vinyl Station",
#send_icy_metadata=true,
description="Vinyl from Wax",
#url="http://IP-ADDRESS”,
s)

#output.icecast(fflac,
#host = "localhost",
#port = 8000,
#password = "WaxVinyl",
#mount = "vinylflac.ogg",
#name = "Vinyl from Wax",
#id="Vinyl Station",
#send_icy_metadata= "true",
#description="Vinyl from Wax",
#s)

output.dummy(meta, 
		#fallible=true
		)

[toots]

Hi! You should make sure that the whole handler is done in a thread. process.read is blocking and will interrupt the stream indeed.

I'm gonna make a task to make all those handlers asynchronous by default in the next major release.

[mojikosu]

Hi @toots
Thanks for your quick reply. And yes, how obvious the mistake was! Thank you! Here is the updated code, for reference.

#!/home/kosuke/.opam/default/bin/liquidsoap
# set the path and permissions for the logfile
set("log.file.path","/var/log/liquidsoap/VinylfromWax.log")
set("log.file.perms",777)
set("log.unix_timestamps",true)
#input from soundcard
s = (input.alsa(device = "pcm.default"))
#s = (input.alsa(device = "pcm.equal", clock_safe=false))
# nrj = normalisation plus compression
#s = nrj(s)
#s = normalize (s)
s = amplify(3.1 ,s)
s = bass_boost(frequency=160.0 ,gain=2.0 ,s)
#======================FORMATS======================================================
#-----------------MP3 Stream with floating point encoder
f = %mp3.cbr(samplerate=44100,bitrate=320)
#-----------------FLAC stream with OGG encapsulation
#fflac = %ogg(%flac(samplerate=44100,channels=2,compression=5,bits_per_sample=16))
#-----------------MP3 Stream with fixed point encoder SHINE
#f = %shine(channels=2,samplerate=44100,bitrate=320)
#-----------------OGG VORBIS stream
#fvorbis = %ogg(%vorbis.cbr(samplerate=44100, channels=2, bitrate=128))
#===================================================================================

#======Prepare source to accept metadata injection=========
s = insert_metadata(s)
#================ Metadata grab and update section =========================================
#======== Launch songrec to detect one song, output as JSON, insert metadata into source stream========
def metadataupdater()
  json =  process.read("songrec recognize --json")
  let json.parse ({
    track = {
      subtitle,
      title,   
      images = {
        coverart }
     }
    } : {
     track : {
      subtitle : string,
      title : string,  
      images : {
       coverart: string }
    }
    }) = json
#  print("Found track #{title}, artist is #{subtitle}, cover art url is #{coverart}")

  s.insert_metadata([("title", title),("artist", subtitle)]) 
end

#This is an intermediate function to be called from blank.detect and output.icecast on_start.
#This intermediate function runs the actual mediadata updater in a thread, so that the
#metadata update does *not* interrupt the stream.
def handleblank() 
 thread.run(metadataupdater)
end

s = blank.detect(
  threshold=-33., 
  max_blank=4., 
  on_noise=handleblank, 
  handleblank,
  s)

#=================OUTPUT==================
output.icecast(f, 
host = "127.0.0.1", 
port = 8000, 
password = "WaxVinyl", 
mount = "vinyl", 
name = "Vinyl from Wax",
id="Vinyl Station", 
on_start=handleblank,
send_icy_metadata=true,
description="Vinyl from Wax  - powered by Technics turntables",
#url="http://IP-ADDRESS”,
s)