-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
158 lines (146 loc) · 4.05 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
{
description = "Rennsax's Nix configuration, for Unix systems like macOS and GNU/Linux";
inputs = {
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
nix-darwin.url = "github:LnL7/nix-darwin";
nix-darwin.inputs.nixpkgs.follows = "nixpkgs";
home-manager.url = "github:nix-community/home-manager";
home-manager.inputs.nixpkgs.follows = "nixpkgs";
flake-utils.url = "github:numtide/flake-utils";
nur-rennsax = {
url = "github:rennsax/nur-packages";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs =
inputs@{
self,
nixpkgs,
nix-darwin,
home-manager,
flake-utils,
nur-rennsax,
...
}:
let
lib = nixpkgs.lib;
varsFor = system: import ./vars { inherit system; };
libFor =
system:
import ./lib {
pkgs = nixpkgs.legacyPackages.${system};
myVars = varsFor system;
inherit lib;
};
overlays = import ./overlays { };
myModules = import ./modules { };
specialArgsFor = system: {
inherit inputs;
myLib = libFor system;
myVars = varsFor system;
nur-rennsax-pkgs = nur-rennsax.packages.${system};
};
# Workaround found at https://github.com/nix-community/home-manager/issues/3075#issuecomment-1593969080.
systemAttrs =
systems: prefix: f:
with lib;
listToAttrs (flip builtins.map systems (system: nameValuePair "${prefix}-${system}" (f system)));
defaultSystemAttrs = systemAttrs flake-utils.lib.defaultSystems;
/**
Generate an attribute list for homeConfigurations:
{ "${name}-x86_64-linux": ..., "${name}-aarch64-darwin": ..., ... }
*/
combinedHome =
name: modules:
defaultSystemAttrs name (
system:
home-manager.lib.homeManagerConfiguration {
pkgs = nixpkgs.legacyPackages.${system};
modules = lib.unique (
modules
++ [
myModules.home
{
nixpkgs = {
inherit overlays;
};
}
]
);
extraSpecialArgs = specialArgsFor system // {
homeVariant = name;
};
}
);
in
{
darwinConfigurations = {
"sonoma" = nix-darwin.lib.darwinSystem {
system = "aarch64-darwin";
modules = [
myModules.darwin
{
nixpkgs = {
inherit overlays;
};
}
./config/darwin.nix
];
specialArgs = specialArgsFor "aarch64-darwin";
};
};
nixosConfigurations = {
"nixos" = nixpkgs.lib.nixosSystem {
system = "x86_64-linux";
modules = [
{
nixpkgs = {
inherit overlays;
};
}
./config/nixos.nix
];
specialArgs = specialArgsFor "x86_64-linux";
};
};
}
// {
homeConfigurations =
combinedHome "worker" [
./config/home/general.nix
./config/home/base.nix
./config/home/nix-scripts.nix
./config/home/develop.nix
]
// combinedHome "minimal" [
./config/home/general.nix
./config/home/mini.nix
]
// combinedHome "typical" [
./config/home/general.nix
./config/home/base.nix
./config/home/nix-scripts.nix
];
}
// flake-utils.lib.eachDefaultSystem (
system:
let
pkgs = import nixpkgs {
inherit system overlays;
};
in
{
devShells.default = pkgs.mkShell {
packages = with pkgs; [
nil
nixfmt-rfc-style
];
};
}
)
// {
# Expose the package set, including overlays, for convenience.
darwinPackages = self.darwinConfigurations."sonoma".pkgs;
nixosPackages = self.nixosConfigurations."nixos".pkgs;
};
}