build.gradle

buildscript {
	repositories {
	    jcenter()
		maven { url 'https://maven.rapidminer.com/content/groups/public/' }
	}
    dependencies {
        classpath 'commons-lang:commons-lang:2.6'
    }
}

plugins { id 'com.rapidminer.extension' version '0.9.4' }

// Define Maven artifact repositories
repositories {
    jcenter()
	maven { url 'https://maven.rapidminer.com/content/groups/public/' }
}

ext {
    // The language tag to be provided as specified here: https://www.oracle.com/java/technologies/javase/jdk8-jre8-suported-locales.html
    // This can be a locale as well, e.g. EN, DE, IT etc.
    language = 'EN'
    // The extend of what to prepare for translation. Possible values are:
    // core:      Only core i18n keys; this means all core keys and keys of all extensions that are shipped directly with RapidMiner
    // supported: All from core, and additionally all keys from supported extensions from marketplace (Vendor: RapidMiner)
    //            These are: Mozenda Connector, NoSQL Connector, Python Scripting, Qlik Connector, R Scripting,
    //            RapidMiner Radoop, SAS Connector, Solr Connector, Splunk Connector, Tableau Table Writer,
    //            Text Processing, Web Mining, In-Database Processing
    i18n_pack = 'core'
}

extensionConfig {

    // The extension name
    name "Language Pack " + project.language.replaceAll('([ -_])([a-zA-Z])', { Object[] x -> x[2].toUpperCase() }).capitalize()

    /*
     * The artifact group which will be used when publishing the extensions Jar
     * and for package customization when initializing the project repository.
     *
     * It is 'com.rapidminer.extension' by default.
     */
    //groupId = 'com.rapidminer.extension'

    /*
     * The extension vendor which will be displayed in the extensions about box
     * and for customizing the license headers when initializing the project repository.
     *
     * It is 'RapidMiner GmbH' by default.
     */
    //vendor = "RapidMiner GmbH"

    /*
     * The vendor homepage which will be displayed in the extensions about box
     * and for customizing the license headers when initializing the project repository.
     *
     * It is 'www.rapidminer.com' by default.
     */
    //homepage = "www.rapidminer.com"

    // define RapidMiner version and extension dependencies
    dependencies {
        rapidminer '10.3.0'
    }
    def groupID = project.group.replace('.', '/')
    def extName = name.replace(' ', '')
    resources {
        errorDescription = groupID + '/resources/i18n/Errors' + extName + '.properties'
        userErrors = groupID + '/resources/i18n/UserErrorMessages' + extName + '.properties'
        guiDescription = groupID + '/resources/i18n/GUI' + extName + '.properties'
        settingsDescriptor = groupID + '/resources/i18n/Settings' + extName + '.properties'
    }
}

// Define third party library dependencies
dependencies {
	//compile 'com.google.guava:guava:26.0'
}
if (file('loadI18N.gradle').exists()) {
    apply from: 'loadI18N.gradle'
}

shadowJar {
    baseName 'rapidminer-language-pack-' + project.language.toLowerCase()
}