Destroy/replace of databases inconsistent

[rdvansloten]

When destroying a database and attempting to re-create planetscale_database, the API simply returns an error during the plan phase:

│ Error: Client Error
│ 
│   with planetscale_database.main,
│   on planetscale.tf line 1, in resource "planetscale_database" "main":
│    1: resource "planetscale_database" "main" {
│ 
│ Unable to read database, got error: error not_found: Not Found

Missing a resource should trigger a create during plan phase, not an error. (unless the database already exists outside state, but this is not the case.

Also, when deleting a database, any dependent planetscale_password is not tainted. During a follow-up run, the password will simply throw the same "Not found" error during the plan phase.

Configuration:

resource "planetscale_database" "main" {
  organization = var.planetscale_database["organization"]
  name         = var.planetscale_database["name"]
  plan         = "developer"
  region       = "eu-west"
}

resource "planetscale_password" "main" {
  organization = var.planetscale_database["organization"]
  database     = planetscale_database.main.name
  branch       = var.planetscale_database["branch"]
  name         = var.planetscale_database["password_name"]
}

[mscoutermarsh]

Another reproduction:

• create a password with terraform
• delete it in UI
• run terraform refresh
• Will error instead of understanding it was removed

[joemiller]

Handling of 404's should be fixed in #62

The automatic tainting of planetscale_password after a planetscale_database is still an open issue, and I will likely leave this issue open as we determine how to handle this.

In the meantime, you should be able to trigger a recreation of the password when the database is deleted/recreated by using an attribute from the database resource as an input to the password resource, creating a link in the state model, eg:

Starting from your example, doing this instead:

resource "planetscale_database" "main" {
  organization = var.planetscale_database["organization"]
  name         = var.planetscale_database["name"]
  plan         = "developer"
  region       = "eu-west"
}

resource "planetscale_password" "main" {
  organization = var.planetscale_database["organization"]
  database     = planetscale_database.main.name
  branch       = planetscale_database.main.default_branch
  name         = var.planetscale_database["password_name"]
}

Part of the issue is that passwords are really connected to branches not databases. For the default_branch case the above example with only db + password resources it would then make sense to use the default_branch attr from the database to make the linkage.

Or, when using db + branch + password:

resource "planetscale_database" "main" {
  organization = var.planetscale_database["organization"]
  name         = var.planetscale_database["name"]
  plan         = "developer"
  region       = "eu-west"
}

resource "planetscale_branch" "my-branch" {
  name          = "mybranch"
  organization  = var.planetscale_database["organization"]
  database      = planetscale_database.main.name
  parent_branch = planetscale_database.main.default_branch
}

resource "planetscale_password" "my-branch" {
  organization = var.planetscale_database["organization"]
  database     = planetscale_database.main.name
  branch       = planetscale_branch.my-branch.name
  name         = var.planetscale_database["password_name"]
}