how to parse attr for space #595

zhuxiujia · 2022-04-18T07:28:52Z

zhuxiujia
Apr 18, 2022

for example:

this is a html element have attr suffixOverrides = ‘, ’ , end of one 'space'

<trim suffixOverrides=', '></trim>

but... when i use pair.into_inner() will be remove the space ' ' attr.

  fn build_node_element(pairs: Pairs<Rule>, dom: &mut Dom) {
        let mut element = Element::default();
        for pair in pairs {
            println!("p='{}'",pair.as_str());
            let c=pair.clone();
            let inner= c.into_inner();
            println!("p_inner='{}'",inner.as_str());
            println!("rule='{:?}'",pair.as_rule());
       }
}

//print
p='suffixOverrides=', ''
p_inner='suffixOverrides=','
rule='attr'
attr='suffixOverrides'
attr=','

this is rules.pest

//
// HTML
//
html = _{
    SOI
    ~ node_comment*
    ~ doctype?
    ~ node*
    ~ EOI
}

//
// DOCTYPE
//
doctype = { chevron_left_bang ~ ^"doctype" ~ attr* ~ chevron_right_normal}

//
// NODES
//
node = _{ node_comment | node_element | node_text }
node_comment = _{ comment_if | comment_normal }
node_text = { (!(node_element | comment_tag_start) ~ ANY)+ }
node_element = { el_void | el_void_xml | el_process_instruct | el_raw_text | el_normal | el_dangling }

//
// COMMENTS
//
comment_normal = _{ comment_tag_start ~ (!comment_tag_end ~ ANY)* ~ comment_tag_end }
comment_tag_start = _{ chevron_left_bang ~ "--" }
comment_tag_end = _{ "--" ~ chevron_right_normal }

// Compatability with old IE browsers... This is not necessary for newer browsers
comment_if = _{ comment_if_start ~ (!comment_if_end ~ ANY)* ~ comment_if_end }
comment_if_start = _{ comment_tag_start ~ "[" ~ ^"if" }
comment_if_end = _{ chevron_left_bang ~ "[" ~ ^"endif" ~ "]" ~ comment_tag_end }

//
// ATTRIBUTES
//
attr = { attr_key ~ (equal ~ (attr_non_quoted | attr_quoted ))? }
attr_quoted =  _{PUSH(quote) ~ attr_value ~ POP }
attr_non_quoted = @{ !quote ~ (!(WHITESPACE | chevron_right) ~ ANY)* }
attr_key = { ASCII_ALPHA ~ text_chars* }
attr_value = { (!PEEK ~ ANY)* }

//
// ELEMENTS
//
el_name = @{ ASCII_ALPHA ~ text_chars* }

// Void element aka self-closing element
// Ex: <hr>
el_void_name_html = @{
    ^"area"
    | ^"base"
    | ^"br"
    | ^"col"
    | ^"command"
    | ^"embed"
    | ^"hr"
    | ^"img"
    | ^"input"
    | ^"keygen"
    | ^"link"
    | ^"meta"
    | ^"param"
    | ^"source"
    | ^"track"
    | ^"wbr"
    | ^"meta"
}
// NOTE: This should not have to be a rule, but people doesn't know what void elements are...
el_void_name_svg = @{
    ^"path"
    | ^"polygon"
    | ^"rect"
    | ^"circle"
}
el_void_name = @{ el_void_name_html | el_void_name_svg }
el_void = _{ chevron_left_normal ~ el_void_name ~ attr* ~ (chevron_right_normal | chevron_right_closed) }
el_void_xml = _{ chevron_left_normal ~ el_name ~ attr* ~ chevron_right_closed }

// Open elements are default element that can take children 
// and have both a start tag and an end tag
// Ex: <html lang="en"></html>
el_normal = _{ el_normal_start ~ (!el_normal_end ~ node)* ~ el_normal_end }
el_normal_start = _{ chevron_left_normal ~ PUSH(el_name) ~ attr* ~ chevron_right_normal}
el_normal_end = { chevron_left_closed ~ POP ~ chevron_right_normal}

// Raw text elements are elements with text/script content that
// might interfere with the normal html syntax
el_raw_text_name = {
    ^"style"
    | ^"script"
    | ^"title"
    | ^"textarea"
}
el_raw_text_content = { (!el_raw_text_end ~ ANY)* }
el_raw_text = _{ el_raw_text_start ~ el_raw_text_content ~ el_raw_text_end }
el_raw_text_start = _{ chevron_left_normal ~ PUSH(el_raw_text_name) ~ attr* ~ chevron_right_normal}
el_raw_text_end = { chevron_left_closed ~ POP ~ chevron_right_normal}

// XML processing instruction
// Ex: <?xml version="1.0" ?>
el_process_instruct = { chevron_left_question ~ el_name? ~ attr* ~ chevron_right_question }

// Catch dangling elements
// Ex: <div/></div>
el_dangling = { chevron_left_closed ~ el_name ~ chevron_right_normal}

//
// SYMBOLS / CHARACTERS
//
text_chars = _{'a'..'z' | 'A'..'Z' | "_" | "-" | ":" |'0'..'9'}

chevron_left_normal = _{ "<" }
chevron_left_closed = _{ "</" }
chevron_left_bang = _{ "<!" }
chevron_left_question = _{ "<?" }

chevron_right_normal = _{ ">" }
chevron_right_closed = _{ "/>" }
chevron_right_question = _{ "?>" }
chevron_right = _{
    chevron_right_normal
    | chevron_right_closed
    | chevron_right_question
}

equal = _{ "=" }
quote_dubble = _{ "\"" }
quote_single = _{ "'" }
quote = _{ quote_dubble | quote_single }
WHITESPACE = _{ " " | "\t" | "\r" | "\n" }

glyn · 2022-04-18T08:04:25Z

glyn
Apr 18, 2022

I'm only learning pest myself, but did you try making attr_quoted atomic? My understanding is that non-atomic rules permit whitespace.

I think it would also be helpful to reduce the above to a minimal example which reproduces the problem. (Often the exercise of producing a minimal reproducing example helps me solve problems myself.) In particular, if you don't define WHITESPACE does the problem go away?

0 replies

zhuxiujia · 2022-04-18T09:02:25Z

zhuxiujia
Apr 18, 2022
Author

I have tested deleting WHITESPACE in rules.pest。 this is invalid

So I guess PEST removed the WHITESPACE already（call into_inner() emthod） , so I submit the problem here

0 replies

glyn · 2022-04-18T09:41:32Z

glyn
Apr 18, 2022

(It may have been better to raise this question as a discussion since it is not clear there is a bug in pest.)

Here's a cut-down example of the issue you are seeing (checked using the editor):

Grammar:

attr = _{ SOI ~ (equal ~ attr_quoted)? ~ EOI }
attr_quoted =  _{PUSH(quote) ~ attr_value ~ POP }
attr_value = { (!PEEK ~ ANY)* }
equal = _{ "=" }
quote_single = _{ "'" }
quote = _{ quote_single }
WHITESPACE = _{ " " }

Input:

=', '

Result:

- attr_value: ","
- EOI: ""

Deleting WHITESPACE like I suggested produces the result you want:

- attr_value: ", "
- EOI: ""

This gives a good clue to what is going on.

So here is the solution I suggest...

Grammar:

attr = _{ SOI ~ (equal ~ attr_quoted)? ~ EOI }
attr_quoted =  _{PUSH(quote) ~ attr_value ~ POP }
attr_value = @{ (!PEEK ~ ANY)* }
equal = _{ "=" }
quote_single = _{ "'" }
quote = _{ quote_single }
WHITESPACE = _{ " " }

Input:

=', '

Result:

- attr_value: ", "
- EOI: ""

0 replies

glyn · 2022-04-19T09:48:17Z

glyn
Apr 19, 2022

Can this issue now be closed?

0 replies

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

how to parse attr for space #595

{{title}}

{{editor}}'s edit

{{editor}}'s edit

Replies: 4 comments

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

Select a reply

how to parse attr for space #595

zhuxiujia Apr 18, 2022

Replies: 4 comments

glyn Apr 18, 2022

zhuxiujia Apr 18, 2022 Author

glyn Apr 18, 2022

glyn Apr 19, 2022

zhuxiujia
Apr 18, 2022

glyn
Apr 18, 2022

zhuxiujia
Apr 18, 2022
Author

glyn
Apr 18, 2022

glyn
Apr 19, 2022