build.gradle

buildscript {
    repositories {
        maven { url = 'https://files.minecraftforge.net/maven' }
        jcenter()
        mavenCentral()
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '4.1.+', changing: true
    }
}

apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'idea'

final def lib = project(':_Lollipop')

version = lib.minecraft_version + '-' + mod_version
group = lib.mod_group
archivesBaseName = mod_name

sourceCompatibility = targetCompatibility = compileJava.sourceCompatibility = compileJava.targetCompatibility = '1.8'

minecraft {
    mappings channel: lib.mappings_channel, version: lib.mappings_version
    accessTransformer = file('../Lollipop/src/main/resources/META-INF/accesstransformer.cfg')
}

sourceSets.main.resources { srcDirs = ["src/main/resources", "src/generated/resources"] }

tasks.withType(Jar) {
    def out = file("../_JARS")
    destinationDir = out
}

repositories {
    maven { url = "http://dvs1.progwml6.com/files/maven" } //JEI
    maven { url = "https://maven.theillusivec4.top" } //Curios
}

dependencies {
    minecraft 'net.minecraftforge:forge:' + lib.minecraft_version + '-' + lib.forge_version
    compileOnly fg.deobf("mezz.jei:jei-${lib.jei_version}:api")
    runtimeOnly fg.deobf("mezz.jei:jei-${lib.jei_version}")
    compile fg.deobf("top.theillusivec4.curios:curios-forge:${lib.curios_version}")
    compile lib
}

jar {
    manifest {
        attributes([
                'FMLAT'                   : 'accesstransformer.cfg',
                "Specification-Title"     : mod_name,
                "Specification-Vendor"    : lib.mod_group,
                "Specification-Version"   : mod_version,
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : mod_version,
                "Implementation-Vendor"   : lib.mod_group,
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ],)
    }
}