DCG variable substitution

[mvolkmann]

With the code below, entering phrase(demo1, S). outputs S = "start middle end".
I want to get the same result from phrase(demo2, S). where the word "middle" is supplied by a variable that is instantiated inside curly braces. I wasn't sure if I needed square brackets around the variable as shown below.
If I don't include the brackets, I get error(instantiation_error,phrase/3).
If I do include them, I get S = [s,t,a,r,t,' ',"middle"|" end"]. which is not quite the same as the demo1 result.
What can I change in demo2 to get the same result as demo1?

:- use_module(library(dcgs)).

demo1 -->
  "start ",
  "middle",
  " end".

demo2 -->
  "start ",
  [Var],
  " end",
  {
    Var = "middle"
  }.

[UWN]

In demo2//0 there is place for only a single character/term. If you want to include an arbitrary sequence, use seq//1. But beware, you are now having a definition that may not terminate! In fact:

demo3 -->
  "start ",
  seq(Middle),
  " end",
  { Middle = "middle" }.

?- phrase(demo3,Xs).
   Xs = "start middle end"
;  loops.

Note that you only see the loop, if you ask for the next answer.

Whereas

demo4 -->
  "start ",
  { Middle = "middle" },
  seq(Middle),
  " end".

?- phrase(demo4,Xs).
   Xs = "start middle end".

works as expected. To understand all of this, you need to master the notion of a failure slice. In this case, it would be

demo3 -->
  "start ",
  seq(Middle), {false},
  " end",
  {  Middle = "middle" }.

?- phrase(demo3,Xs), false.
   loops.

Now the following holds: If this failure slice does not terminate, then also your original program does not terminate (although it might still produce an answer here and there).

[mvolkmann]

Thanks so much! That was exactly what I needed.