Using Prolog to unravel the foundations of oncology dose-escalation trial designs

[dcnorris]

A longstanding collaboration with @triska, applying Prolog to the specification and analysis of oncology dose-escalation trial designs, has yielded some interesting progress that I'd like to share. It seems to me that the current thrust of this work employs Prolog — and indeed some new techniques like if_/3 (Neumerkel & Kral 2017) — in a manner that is somehow essential to our successful attack on certain problems in this field. As such, I think our collaboration reflects in some interesting ways on Prolog itself. I'll try to get across the main gist of the application without belaboring the details. The work I'll describe here is contained in this self-contained file from the precautionary package.

Background & motivation

Dose-finding studies in oncology continue to follow the inveterate '3+3' design described with a DCG in this arXiv paper and also demonstrated 'organically' in this video. This holds despite 3 decades of effort (mainly by biostatisticians) to replace 3+3 with statistically more sophisticated designs. Thus, for all its many deficiencies, the 3+3 design continues to enjoy 'mind-share' with oncology trialists. Consequently, a demonstration that 3+3 naturally generalizes toward more desirable designs, could potentiate progress in this field. This would be especially true, if a domain-specific language (DSL) could be developed, enabling trialists' direct exploration of this larger class.

Because of its perverse nature, this '3+3' design has long been regarded by dose-finding methodologists as a kind of 'other' — an aberrant and pathological design supposedly bearing no relation to the newer innovations. Markus and I have however already shown that the 3+3 is in fact a special case of a larger class of designs, and indeed of the Bayesian Optimal INterval (BOIN) designs, which are a leading contender among the design classes under active research development.

In order to effect such a demonstration, we are now working to express the 3+3 design in terms of constraints imposed by the potential 'regret' we might have about toxic outcomes observed in the trial. Here's how we're doing that currently:

Enrollment

In the 3+3 trial, participants are enrolled in cohorts of 3. Each cohort is assigned to a single dose level, and (classically) dosed simultaneously. After some period elapses (often 4 weeks), patients are assessed for the occurrence of an intolerable level of toxicity called a 'dose-limiting toxicity' (DLT). Each cohort thus generates a tally T/3 of T toxicities. When multiple cohorts are enrolled at a given dose level, the result in general is a tally T/N at that dose.

%% During the course of a dose-escalation trial, at any given dose-level
%% there is some current tally T/N, T,N ∈ ℕ recording T toxic responses
%% ('toxicities') out of N participants enrolled at that dose. Enrollment
%% of a further 'cohort' at this dose-level increases the denominator and
%% possibly also the numerator. Initially, we constrain enrollment to
%% cohorts of size 3, and limit total enrollment at any one dose to 6.
%% (The 'toxicity assessment period' that must elapse before a toxicity
%% determination can be made is NOT explicitly modeled, and is thus elided
%% as if it were instantaneous.)
enroll(T0/N0, T1/N1) :-
    #Nnew #= 3, % hard-coding cohorts of 3 for now
    #N1 #= #N0 + #Nnew,
    Tnew in 0..Nnew, indomain(Tnew),
    #T1 #= #T0 + #Tnew,
    #N1 #=< 6. % Maximum enrollment per cohort
    
%?- enroll(0/0, T/N).
%@    T = 0, N = 3
%@ ;  T = 1, N = 3
%@ ;  T = 2, N = 3
%@ ;  T = 3, N = 3.

State of the trial

Typically escalation occurs over some pre-specified set of dose levels, starting with a very low level that is presumed to be quite safe, and escalating gradually up to higher dose levels as the lower ones are shown to cause few DLTs. The state of the trial at any given time is thus representable as the history (a list of tallies accumulated thus far), together with an indication of which dose level is considered the 'current' dose most suitable for enrolling the next patient. Since most dose-finding designs escalate or de-escalate between adjacent doses, we can very conveniently represent this state as a pair of lists:

%% We model the state of the whole trial (comprising multiple dose-levels)
%% as a pair of lists of tallies, the left-hand list in *descending* dose
%% order with the 'current dose' at its head, and the right-hand list in
%% *ascending* order, with the next-higher dose at its head. Thus doses
%% adjacent to the 'current dose' are immediately accessible. Dose-skipping
%% is generally not done in dose-escalation trials, in which case there are
%% 3 main dose-escalation decisions: ESCalate, STAy and DeEScalate:
state0_decision_state(Ls - [R0|Rs], esc, [R|Ls] - Rs) :- enroll(R0, R).
state0_decision_state([L0|Ls] - Rs, sta, [L|Ls] - Rs) :- enroll(L0, L).
state0_decision_state([L,D0|Ls] - Rs, des, [D|Ls] - [L|Rs]) :- enroll(D0, D).

Regret

The key clinical input is expressed in the form of possible regrets that the trialist might have.

%% regret(A, [Q|Qs]) holds if we regret having taken action A if it
%% results in a tally history [Q|Qs] -- which reads backwards in time.
%% This allows for the relevant history to go back either 1 or 2 tallies,
%% which is fully suffient for practical purposes. (Regrets based on long
%% histories would hardly be intuitive for clinical trialists, and a key
%% aim here is of course to capture the definitive intuitions.)

%% This says that, regardless of the resulting tally, we would regret
%% having de-escalated from an 'insufficiently toxic' tally of 1-/3+.
regret(des, [_,T/N]) :-
    #T #=< 1 #/\ #N #>= 3.

%% We regret having stayed at the current dose upon seeing a 5+/6 tally.
regret(sta, [T/N|_]) :-
    #N #= 6 #/\ #T #>= 5. % regret excess toxicity

regret(esc, [T/N, T0/N0]) :-
    #N #>= #T, % condition for T/N to be a valid tally
    (	#T #> 0, % We will regret even 1 toxicity when escalating after..
	 #N0 #< 3 % having enrolled less than 3 at previous dose.
    ;	#T #> 1, % We regret >1 toxicities after..
	#T0 * 6 #> N0 % having seen tox rate T0/N0 > 1/6 at prev dose.
    ;	#T #>= 5 % We regret net 5+ toxicities after any escalation.
	%% NB:
	%% The need for this final case is not obvious. It arises when
	%% we have accumulated 0/6 toxicities at current dose, having
	%% de-escalated from a higher dose with tally 2+/3. That this
	%% case is so nontrivial perhaps points toward a need for some
	%% new concept to render it 'obvious' or 'natural'.
    ).

Interpretation

On the view that higher doses generally deliver greater efficacy, and that the starting doses in these trials are quite likely too low to be efficacious, we have a preference for dose escalation (esc) over staying at the same dose (sta), which in turn is preferable to de-escalation (des). Given this ordering, avoidance of 'regret' may determine the trial decisions by something resembling dynamic programming. This seems to me the point where Prolog becomes indispensable to our work:

%% This goal that reifies to 'true' for precisely those decisions
%% which are BOTH feasible AND non-regrettable; it otherwise
%% reifies to 'false'.
state0_decision_noregrets(S0, A, Truth) :-
    state_si(S0),
    regrettable_decision(A),
    if_(state0_decision_feasible(S0, A),
	(   state0_decision_state(S0, A, S),
	    S0 = [T0/N0|_] - _, % TODO: Factor this pattern matching
	    S  = [T /N |_] - _, %       into a regret/3 predicate?
	    %% I introduce the (->) below to avert backtracking over
	    %% possibly multiple scenarios for regret -- one is enough!
    	    regret(A, [T/N, T0/N0]) -> Truth = false
	;   Truth = true
	),
	Truth = false
       ).

%% These are the 3 dose-escalation decisions to which the 'regret' concept applies:
regrettable_decision(esc).
regrettable_decision(sta).
regrettable_decision(des).

state0_decision_feasible(S0, A, Truth) :-
    state_si(S0),
    regrettable_decision(A), % this instantiates A
    (	state0_decision_state(S0, A, _) -> Truth = true
    ;	Truth = false
    ).

%?- state0_decision_noregrets([0/3,1/6]-[], E, Truth).
%@    E = esc, Truth = false
%@ ;  E = sta, Truth = false
%@ ;  false.

state_si(L - R) :- list_si(L), list_si(R).

%?- state0_decision_noregrets([1/3]-[0/0], E, T).
%@    E = esc, T = false
%@ ;  E = sta, T = true
%@ ;  false.

%% This code reflects the primacy of REGRET as the crucial user-level
%% concept shaping these designs.

cascading_decision_otherwise([], Os, _, _, _) :- maplist(call, Os).
cascading_decision_otherwise([D|Ds], Os, E, S0, S) :-
        if_(state0_decision_noregrets(S0, D),
            (   E = D,
                state0_decision_state(S0, E, S)
            ),
            cascading_decision_otherwise(Ds, Os, E, S0, S)).

path(declare_mtd(_)) --> [].
path(S0) --> { cascading_decision_otherwise([esc,sta,des],
                                            [E = stop, % ..and otherwise, STOP.
                                             MTD = todo, % TODO: Actually obtain MTD as integer >= 0.
                                             S = declare_mtd(MTD)], E, S0, S) },
	     [E, S],
	     path(S). % TODO: Implement declare_mtd possibility

Demonstrating equivalence with earlier DCG

The script concludes with a demonstration that the counts of trial paths match those of the earlier DCG formulation:

%?- J+\(length(D,1), maplist(=(0/0), D), findall(Path, phrase(path([]-D), Path), Paths), length(Paths, J)).
%@    J = 10.
%?- J+\(length(D,2), maplist(=(0/0), D), findall(Path, phrase(path([]-D), Path), Paths), length(Paths, J)).
%@    J = 46.
%?- J+\(length(D,3), maplist(=(0/0), D), findall(Path, phrase(path([]-D), Path), Paths), length(Paths, J)).
%@    J = 154.
%?- J+\(length(D,4), maplist(=(0/0), D), findall(Path, phrase(path([]-D), Path), Paths), length(Paths, J)).
%@    J = 442.
%?- J+\(length(D,5), maplist(=(0/0), D), findall(Path, phrase(path([]-D), Path), Paths), length(Paths, J)).
%@    J = 1162.
%?- J+\(length(D,6), maplist(=(0/0), D), findall(Path, phrase(path([]-D), Path), Paths), length(Paths, J)).
%@    J = 2890.
%% These path counts match Table 1 from https://arxiv.org/abs/2012.05301.

[aarroyoc]

Do you want to cross post this article in PrologHub? I can do it from my account or I can create an account for you to post it (and later, more things)

[dcnorris]

Thank you, @aarroyoc! I would be grateful if you cross-posted this, and would be glad to have an account at PrologHub too!

[aarroyoc]

I sent you an email with all the details! Thanks!