Help with consult-preview-allowed-hooks to soft-wrap previews?

[mcarmosi]

Hello, I am using consult-notes and I write in the "one line is a paragraph" convention. So I use olivetti and visual-line-mode to center and soft-wrap my notes. This is basically an amazing setup, except when I use consult-notes to find a note the live preview does not activate my soft-wrapping modes even though I added them to consult-preview-allowed-hooks. How can I soft-wrap my previews?

Here is what I tried so far.

It seems consult-notes defines a thin wrapper around consult--temporary-files (defined in consult.el, so I'm asking here) to generate previews, which for a file that hasn't been opened yet will call consult--find-file-temporarily. Now, consult--find-file-temporarily allows only a few "known efficient" hooks to run by default. This is well documented in the middle of the preview sections of the consult README. So I tried using this variable to activate soft-wrapping during preview:

(add-to-list 'consult-preview-allowed-hooks 'olivetti-mode)
(add-to-list 'consult-preview-allowed-hooks 'visual-line-mode)
(add-to-list 'consult-preview-allowed-hooks 'turn-on-visual-line-mode)

I have olivetti hooked in all text-mode buffers like so:

(use-package olivetti
  :hook
  (text-mode . olivetti-mode)
  :config
  (setq olivetti-style t))

And for good measure I added it explicitly to org mode hooks:

(add-hook 'org-mode-hook 'turn-on-visual-line-mode)
(add-hook 'org-mode-hook 'olivetti-mode)

But I still can't get olivetti or visual-line-mode turned on when previewing notes that aren't open in a buffer already. I'm trying to step through consult--find-file-temporarily to understand why it isn't calling these hooks, but it is very slow going for me because I don't know elisp.

At the very least (memq x consult-preview-allowed-hooks) should pass for the modes I added, but I don't know how to trace consult--filter-find-file-hook because it is used as advice. Any pointers or advice on how to proceed would be very much appreciated.

[minad]

Take a look at the consult-preview-allowed-hooks, hooks which enable global minor modes after find-file. What you are adding there does not match that. See this example:

(defun my-hook ()
    ;; Here you can enable modes depending on the current buffer/file.
  )
(add-to-list 'consult-preview-allowed-hooks 'my-hook)
(add-hook 'find-file-hook 'my-hook)

[mcarmosi]

Oh, wow, the below works perfectly for soft-wrapping previews, thank you so much!

(defun my-hook ()
  (when (eq major-mode 'org-mode)
    (olivetti-mode)))

(add-to-list 'consult-preview-allowed-hooks 'my-hook)
(add-hook 'find-file-hook 'my-hook)

Clearly I don't understand how olivetti-mode gets turned on in a "standard" file visit as compared to the consult preview, which calls find-file-noselect and so somehow "misses" my text-mode hooks ? I'm going to read the manual about hooks to try and figure it out.

If you have any other suggestions for reading material I'd appreciate it. Thanks again!

[minad]

The find file hooks are used by global modes. For example global-olivetti-mode registers itself there. Mode hooks, e.g., org-mode-hook, are completely delayed by Consult preview and never executed. Therefore something like (add-hook 'org-mode-hook 'olivetti-mode) does not work with preview.

[mcarmosi]

Aha, and if I wanted to change how consult handles mode hooks for everything, I could issue

(setf (alist-get 'delay-mode-hooks consult-preview-variables) nil)

in my init.el right? This also works to soft-wrap the previews. And now I think I understand the two pcase-dolist invocations inside consult--find-file-temporarily --- they swap in and out consult-preview-variables around invocation of consult--find-file-temporarily-1 so the default values are restored afterwards.

Overall it seems like people who want to customize previews have two options:

1. Add a personal function to both find-file-hook and consult-preview-allowed-hooks. Inside there, match the file-type you want to customize previews for and execute whatever minor modes you want. Advantage: specificity, performance. Disadvantage: more code.
2. Globally disable the delay on mode hooks using the snippet above and pay (serious?) performance penalties if the mode hooks are slow to start up. Advantage: one line of code.

Does this seem right? Am I missing additional dimensions of the tradeoffs?

I wonder if there is a sensible "third option", like providing consult with a customizable allowlist of major-modes that the user says are "not too slow" to interfere with the preview experience. In consult--find-file-temporarily we could check if an auto-detected mode is on this list, and then set delay-mode-hooks accordingly?

Apologies if this is way out of scope for the discussion forum, I'm trying to understand the situation thoroughly so I can write this up and contribute a succinct and approachable explanation to the README or something. I think the "large collection of notes, lines as paragraphs" use case is pretty common, but many people using emacs for prose (like myself) are pretty ignorant of elisp.

If there is a better place to ask these kinds of implementation and design questions about consult please let me know, and thanks again for your prompt replies and work on consult.

[minad]

I think you got it right. I don't want to add an option/complication regarding delay-mode-hooks. You can of course tweak this setting via consult-preview-variables and make sure that mode hooks don't enable expensive minor modes.