build.gradle

/*
 * SPDX-FileCopyrightText: 2013, microG Project Team
 * SPDX-License-Identifier: Apache-2.0
 */

buildscript {
    ext.androidBuildGradleVersion = '3.6.3'

    ext.androidBuildVersionTools = '29.0.3'

    ext.androidMinSdk = 9
    ext.androidTargetSdk = 29
    ext.androidCompileSdk = 29

    repositories {
        jcenter()
        google()
    }

    dependencies {
        classpath "com.android.tools.build:gradle:$androidBuildGradleVersion"
    }
}

String gitDescribeVersion() {
    def stdout = new ByteArrayOutputStream()
    if (rootProject.file("gradlew").exists())
        exec { commandLine 'git', 'describe', '--tags', '--always', '--dirty'; standardOutput = stdout }
    else // automatic build system, don't tag dirty
        exec { commandLine 'git', 'describe', '--tags', '--always'; standardOutput = stdout }
    return stdout.toString().trim().substring(1)
}

allprojects {
    apply plugin: 'idea'

    group = 'org.microg'
    version = gitDescribeVersion()
}

subprojects {
    repositories {
        jcenter()
        google()
    }
}