Button Latch with encoder.buttonChanged() function?

[m-r-m-s]

Hi @luni64,

I am trying to create a button latch using the encoderButton example you provide in the repo but having a bit of trouble.

I am coming from the bounce2 library over to using the EncoderTool library with the code below. However, when I try to implement with the encoder.buttonChanged() function like in the example, it does not latch as expected. Could you please explain and provide an alternative on how to implement? Thank you so much for your time.

#include <Bounce2.h> // Import the Bounce2 library into the sketch

Bounce push_button = Bounce(); // Create a Bounce2 object associated with a name

int debounce_interval_time = 5; // The interval time for debouncing is 5 milliseconds

const int button_pin = 2; // encoder button pin

int  mode = 0;

void setup() {

  pinMode(button_pin, INPUT_PULLUP);

  push_button.attach(button_pin); // In the setup() function, attach the digital pin to the Bounce2 object
  push_button.interval(debounce_interval_time); // In the setup() function, set an interval time in milliseconds to debounce the input - 5 - 50 milliseconds is recommended, the shorter the better (as long as a clear and stable signal can be read

}

void loop() {

  push_button.update(); // In the loop() function, update the Bounce2 object regularly

  if (push_button.fell() == true) {

    mode++;
    if (mode > 1) {
      mode = 0;

    }

    Serial.print("mode=");
    Serial.println(mode);

  } //button if over

  if (mode == 0) {
    
    // do this
    
  }
  
  if (mode == 1) {
    
    // do that
    
  }

}

[luni64]

Here a straight forward solution:

#include "EncoderTool.h"
using namespace EncoderTool;

PolledEncoder enc;

bool btnActive = false;

void setup()
{
    pinMode(LED_BUILTIN, OUTPUT);
    enc.begin(0, 1, 2);
}

void loop()
{
    enc.tick();

    if (enc.buttonChanged() && enc.getButton() == LOW)  // assume button = LOW when pressed
    {
        btnActive = !btnActive;
    }

    if (btnActive)
    {
        digitalWriteFast(LED_BUILTIN, HIGH);
    }
    else
    {
        digitalWriteFast(LED_BUILTIN, LOW);
    }
}

You can also use a button callback to get the state change code out of loop:

#include "EncoderTool.h"
using namespace EncoderTool;

PolledEncoder enc;

bool btnActive = false;

void cbButton(int32_t state)  // will be called whenever the button state changes
{
    if(state == LOW)  btnActive = !btnActive;
}

void setup()
{
    pinMode(LED_BUILTIN, OUTPUT);
    enc.begin(0, 1, 2);  // A=0, B=1, Button=2

    enc.attachButtonCallback(cbButton);
}

void loop()
{
    enc.tick();
    if (btnActive)
    {
        digitalWriteFast(LED_BUILTIN, HIGH);
    }
    else
    {
        digitalWriteFast(LED_BUILTIN, LOW);
    }
}

[m-r-m-s]

Perfect - thank you so much! Very helpful as always !
This is where it clicked for me with my understanding: if (enc.buttonChanged() && enc.getButton() == LOW)
I was missing this and now I understand. Cheers,
=D