Short and Long Button Presses Callback #13

m-r-m-s · 2022-04-20T19:12:20Z

m-r-m-s
Apr 20, 2022

I am trying to come up with a callback method for short and long button presses using the EncoderTool library and my coding skills aren't that great in coming up with the solution. I've tried to adapt an example I have found on the web to this library and I am only able to get it working in the loop but I am overlooking something when I use the button callback. I can only get the short press to respond. Does this have something to do with how the Bounce2 library is configured by default in the EncoderTool library?

Here is the working code in the loop:

#include <Arduino.h>

#include "EncoderTool.h"
using namespace EncoderTool;
PolledEncoder encoder; // Polling encoder, please call corresponding tick() functions as often as possible, e.g. in loop

// Bourns PEL12D Rotary Encoder (2 LEDs, 1 button)
const int ENC_PIN_A   = 12; // encoder pin A
const int ENC_PIN_B   = 11; // encoder pin B
const int ENC_BUTTON  = 2;  // encoder button pin
const int LED_2_GREEN = 22; // encoder led green
const int LED_1_RED   = 23; // encoder led red

const int SHORT_PRESS_TIME = 1000; // 1000 milliseconds
const int LONG_PRESS_TIME  = 1000; // 1000 milliseconds
int previous_button_state  = LOW;  // the previous state from the input pin
int current_button_state;          // the current reading from the input pin
unsigned long pressed_time  = 0;
unsigned long released_time = 0;
int pressing_button         = 0;
int long_press_detected     = 0;

void onButtonChanged(int32_t state) { // button state

} // button state over

void setup() {

  pinMode(LED_2_GREEN, OUTPUT);
  pinMode(LED_1_RED, OUTPUT);
  pinMode(ENC_BUTTON, INPUT_PULLUP);

  digitalWrite(LED_1_RED, HIGH); // init red LED on

  encoder.begin(ENC_PIN_A, ENC_PIN_B, ENC_BUTTON);
  encoder.attachButtonCallback(onButtonChanged); // connect the button callback function

}

void loop() {

  encoder.tick();

  // read the state of the switch/button:
  current_button_state = encoder.getButton(); // is state HIGH OR LOW ?

  //////// SHORT PRESS ////////
  if (previous_button_state == HIGH && current_button_state == LOW) {
    pressed_time = millis();
    pressing_button = 1;
    long_press_detected = 0;
  }
  else if (previous_button_state == LOW && current_button_state == HIGH) {
    pressing_button = 0;
    released_time = millis();
    long press_duration = released_time - pressed_time;
    if (press_duration < SHORT_PRESS_TIME) {
      Serial.println("a short press is detected");
    }
  }
  //////// LONG PRESS ////////
  if (pressing_button == 1 && long_press_detected == 0) {
    long press_duration = millis() - pressed_time;
    if (press_duration > LONG_PRESS_TIME) {
      Serial.println("a long press is detected");
      long_press_detected = 1;
    }
  }

  // save the the last state
  previous_button_state = current_button_state;

}

Answered by luni64

Apr 23, 2022

In this case you can't do it in the callback alone since this is only invoked if the button changed. But it is easy to use a timer for this:

#include "Arduino.h"
#include "EncoderTool.h"

using namespace EncoderTool;
PolledEncoder encoder;

IntervalTimer btnTimer;
bool timerRunning                = false;     // unfortunately the timer has no built in way to find out if it's running
constexpr unsigned longPressTime = 1'000'000; // us

void onLongPress()
{
    btnTimer.end();                                 // trigger only once
    timerRunning = false;

    Serial.println("Long Press\n");
    // do whatever need to be done on a long press here...
}

void onButtonChanged(int32_t state)
{

View full answer

luni64 · 2022-04-22T09:16:05Z

luni64
Apr 22, 2022
Maintainer

This should work:

#include "Arduino.h"
#include "EncoderTool.h"

using namespace EncoderTool;
PolledEncoder encoder; // Polling encoder, please call corresponding tick() functions as often as possible, e.g. in loop

void onButtonChanged(int32_t state)
{
    static uint32_t lastTime;

    if (state == LOW)
    {
        Serial.println("Button Down");
        lastTime = millis();
    }
    else // button released
    {
        if (millis() - lastTime < 1000)
            Serial.println("Short Press\n");
        else
            Serial.println("Long Press\n");
    }
}

void setup()
{
    encoder.begin(0, 1, 2);
    encoder.attachButtonCallback(onButtonChanged); // connect the button callback function
}

void loop()
{
    encoder.tick();
}

Prints

Button Down
Short Press

Button Down
Long Press

Button Down
Short Press

Button Down
Short Press

Button Down
Short Press

Button Down
Long Press

1 reply

m-r-m-s Apr 22, 2022
Author

Ah - thank you!!! One point of clarification I forgot: the loop code that I posted detects a long press during pressing and not after. Is this possible with the callback? That is what I could not get working.

luni64 · 2022-04-23T05:49:50Z

luni64
Apr 23, 2022
Maintainer

In this case you can't do it in the callback alone since this is only invoked if the button changed. But it is easy to use a timer for this:

#include "Arduino.h"
#include "EncoderTool.h"

using namespace EncoderTool;
PolledEncoder encoder;

IntervalTimer btnTimer;
bool timerRunning                = false;     // unfortunately the timer has no built in way to find out if it's running
constexpr unsigned longPressTime = 1'000'000; // us

void onLongPress()
{
    btnTimer.end();                                 // trigger only once
    timerRunning = false;

    Serial.println("Long Press\n");
    // do whatever need to be done on a long press here...
}

void onButtonChanged(int32_t state)
{
    if (state == LOW)                               // button pressed
    {                                               //
        btnTimer.begin(onLongPress, longPressTime); // start timer to detect long press
        timerRunning = true;
        Serial.println("Button down");
    }
    else                                            // button released
    {
        if (timerRunning)                           // timer not elapsed when button was released -> short press
        {
            btnTimer.end();                         // stop the timer since we detected a short press

            Serial.println("Short Press\n");
            // do whatever need to be done on a short press here...
        }
    }
}

void setup()
{
    encoder.begin(0, 1, 2);
    encoder.attachButtonCallback(onButtonChanged);
}

void loop()
{
    encoder.tick();
}

1 reply

m-r-m-s Apr 24, 2022
Author

Ok, thank you so much for this example. It is very helpful as always! Pardon my naive questions: Would a millis based approach not work or is the IntervalTimer approach just more efficient?

Also, would using IntervalTimer in this context present any issues with the following library that also uses IntervalTimer: https://github.com/midilab/uClock/blob/master/src/uClock.cpp ?

Also, I am still wanting to eventually use the EncoderTool library on the Seeeduino Xiao but haven't gotten there yet. Do you know if IntervalTimer can be used on the Xiao?

luni64 · 2022-04-25T06:14:03Z

luni64
Apr 25, 2022
Maintainer

Would a millis based approach not work or is the IntervalTimer approach just more efficient?

You definitely need some timing mechanism if you want the long press event asynchronous to the actual button changes. You could of course make you own timer using millis but you would probably end up with the same mess as shown in your first post.

Also, would using IntervalTimer in this context present any issues with the following library that also uses IntervalTimer:

There are 4 IntervalTimers available. As long as you don't use them up completely you should be fine.

Also, I am still wanting to eventually use the EncoderTool library on the Seeeduino Xiao but haven't gotten there yet. Do you know if IntervalTimer can be used on the Xiao?

There is a XIAO branch of the library. Did you try this? I don't know much about the XIAO but I assume there will be a similar timer for the board which you could use.

0 replies

m-r-m-s · 2022-04-26T14:48:00Z

m-r-m-s
Apr 26, 2022
Author

You definitely need some timing mechanism if you want the long press event asynchronous to the actual button changes. You could of course make you own timer using millis but you would probably end up with the same mess as shown in your first post.

Understood - definitely trying to avoid methods that could prove problematic going forward.

There are 4 IntervalTimers available. As long as you don't use them up completely you should be fine.

Ok great! This shouldn't be an issue.

There is a XIAO branch of the library. Did you try this? I don't know much about the XIAO but I assume there will be a similar timer for the board which you could use.

I am aware of the XIAO branch but haven't tried yet. From what little I have read, there does not seem to be IntervalTimer support but there are interrupt timers: https://www.sigmdel.ca/michel/ha/xiao/seeeduino_xiao_01_en.html#timers and here.

I have the XIAO and need to get the circuit on a breadboard. I will let you know how it goes asap. Thank you again for all your help so far. I am learning so much!

0 replies

m-r-m-s · 2022-05-05T23:47:07Z

m-r-m-s
May 5, 2022
Author

I just wanted to report back that the XIAO branch of the library works great! Also, I modified the above example for use with TimerTC3 on the XIAO in place of the IntervalTimer . Thank you again for all your help and patience!

0 replies

luni64 · 2022-05-07T04:29:45Z

luni64
May 7, 2022
Maintainer

Great!
Do you mind posting the XIAO code? Might be interesting for other users as well.

1 reply

m-r-m-s May 7, 2022
Author

Great!
Do you mind posting the XIAO code? Might be interesting for other users as well.

Of course! Here's my working attempt:

/*
*   DETECT LONG PRESS DURING PRESSING
*/
#include <Arduino.h>

#include <TimerTC3.h>

#include "EncoderTool.h"
using namespace EncoderTool;
PolledEncoder encoder; // Polling encoder, please call corresponding tick() functions as often as possible, e.g. in loop

// encoder and button pins
const int ENC_PIN_A   = 1; // encoder pin A
const int ENC_PIN_B   = 2; // encoder pin B
const int ENC_BUTTON  = 3;  // encoder button pin

bool timer_running = false; // unfortunately the timer has no built in way to find out if it's running
byte time = 0;

void on_long_press() {

  TimerTc3.detachInterrupt(); // trigger only once
  timer_running = false;
  time = 0;
  Serial.println("Long Press\n");
  // do whatever need to be done on a long press here...
}

void onButtonChanged(int32_t state) {

  if (state == LOW) {
    
    time++;
    if (time == 1) {
      TimerTc3.attachInterrupt(on_long_press); // start timer to detect long press
      timer_running = true;
      Serial.println("Button down");
    }

  }

  else {

    if (timer_running) { // timer not elapsed when button was released -> short press

      TimerTc3.detachInterrupt();
      time = 0;
      Serial.println("Short Press\n"); // stop the timer since we detected a short press
      // do whatever need to be done on a short press here...

    }
  }
}

void setup() {

  pinMode(ENC_BUTTON, INPUT_PULLUP);

  TimerTc3.initialize(1000000);
  TimerTc3.attachInterrupt(on_long_press); 

  encoder.begin(ENC_PIN_A, ENC_PIN_B, ENC_BUTTON);
  encoder.attachButtonCallback(onButtonChanged); // connect the button callback function

}

void loop() {

  encoder.tick();

}

Prints: 

Button down
Short Press

Button down
Short Press

Button down
Long Press

Button down
Short Press

Button down
Long Press

Button down
Long Press

Button down
Short Press

Button down
Short Press

Button down
Short Press

Button down
Long Press

luni64 · 2022-05-09T14:34:51Z

luni64
May 9, 2022
Maintainer

@m-r-m-s I just released a new version (v3.0.0) which should be platform independent. Would be great if you could test it for the XIAO as well :-)

2 replies

m-r-m-s May 10, 2022
Author

Ok, great! Congrats on the release! I will try the new version and report bck =-)

m-r-m-s May 24, 2022
Author

@luni64 apologies for the delay! I am getting a compile error on the singleEncCallback example in the repository and same error in the sketch linked here:

/Documents/Arduino/2022-05-24-singleEncCallback-v3/2022-05-24-singleEncCallback-v3.ino: In function 'void setup()':
2022-05-24-singleEncCallback-v3:25:38: error: invalid conversion from 'void (*)(int32_t, int32_t) {aka void (*)(long int, long int)}' to 'EncoderTool::encCallback_t {aka void (*)(int, int)}' [-fpermissive]
     enc.attachCallback(onValueChanged);        // call 'onValueChanged' whenever the encoder value changed
                                      ^
In file included from /Documents/Arduino/libraries/EncoderTool/src/Multiplexed/EncPlexBase.h:4:0,
                 from /Documents/Arduino/libraries/EncoderTool/src/Multiplexed/EncPlex74165.h:7,
                 from /Documents/Arduino/libraries/EncoderTool/src/EncoderTool.h:3,
                 from /Documents/Arduino/2022-05-24-singleEncCallback-v3/2022-05-24-singleEncCallback-v3.ino:2:
/Documents/Arduino/libraries/EncoderTool/src/EncoderBase.h:24:22: note:   initializing argument 1 of 'EncoderTool::EncoderBase& EncoderTool::EncoderBase::attachCallback(EncoderTool::encCallback_t)'
         EncoderBase &attachCallback(encCallback_t);
                      ^~~~~~~~~~~~~~
2022-05-24-singleEncCallback-v3:26:45: error: invalid conversion from 'void (*)(int32_t) {aka void (*)(long int)}' to 'EncoderTool::encBtnCallback_t {aka void (*)(int)}' [-fpermissive]
     enc.attachButtonCallback(onButtonChanged); // call 'onButtonChanged' whenever the button state changed
                                             ^
In file included from /Documents/Arduino/libraries/EncoderTool/src/Multiplexed/EncPlexBase.h:4:0,
                 from /Documents/Arduino/libraries/EncoderTool/src/Multiplexed/EncPlex74165.h:7,
                 from /Documents/Arduino/libraries/EncoderTool/src/EncoderTool.h:3,
                 from /Documents/Arduino/2022-05-24-singleEncCallback-v3/2022-05-24-singleEncCallback-v3.ino:2:
/Documents/Arduino/libraries/EncoderTool/src/EncoderBase.h:25:22: note:   initializing argument 1 of 'EncoderTool::EncoderBase& EncoderTool::EncoderBase::attachButtonCallback(EncoderTool::encBtnCallback_t)'
         EncoderBase &attachButtonCallback(encBtnCallback_t);
                      ^~~~~~~~~~~~~~~~~~~~
In file included from /Documents/Arduino/libraries/EncoderTool/src/Single/Encoder.h:6:0,
                /Documents/Arduino/libraries/EncoderTool/src/EncoderTool.h:6,
                 /Documents/Arduino/2022-05-24-singleEncCallback-v3/2022-05-24-singleEncCallback-v3.ino:2:
/Documents/Arduino/libraries/EncoderTool/src/Single/../HAL/pinInterruptHelper.h: In instantiation of 'static void HAL::PinInterruptHelper<TYPE, MEMBER>::attachInterrupt(uint8_t, TYPE*, int) [with TYPE = EncoderTool::Encoder; void (TYPE::* MEMBER)() = &EncoderTool::Encoder::doUpdate; uint8_t = unsigned char]':
/Documents/Arduino/libraries/EncoderTool/src/Single/Encoder.h:61:18:   required from here
/Documents/Arduino/libraries/EncoderTool/src/Single/../HAL/pinInterruptHelper.h:45:91: warning: unused parameter 'mode' [-Wunused-parameter]
     void PinInterruptHelper<TYPE, MEMBER>::attachInterrupt(uint8_t pin, TYPE* object, int mode)
                                                                                           ^~~~
Using library EncoderTool at version 3.0.0 in folder: /Documents/Arduino/libraries/EncoderTool 
Using library Bounce2 at version 2.57 in folder: /Documents/Arduino/libraries/Bounce2 
exit status 1
invalid conversion from 'void (*)(int32_t, int32_t) {aka void (*)(long int, long int)}' to 'EncoderTool::encCallback_t {aka void (*)(int, int)}' [-fpermissive]

The encoderButton example works with no issues.

luni64 · 2022-05-25T05:05:47Z

luni64
May 25, 2022
Maintainer

Thanks for testing.
Wherever possible I changed types from int32_t /uint32_t to the more platform independent int. Even if int32_t and int are both 32 bit integers for the XIAO, for compiler they are different. To fix it, please change int32_t to int in your definition of onButtonChanged.

I'll fix the examples accordingly. Let me know if this fixes it for you.
(edit: done in v.3.0.2)

1 reply

m-r-m-s May 25, 2022
Author

Thanks so much for the explanation and everything works great with int instead of int32_t =)

Provide feedback

Saved searches

Use saved searches to filter your results more quickly

Short and Long Button Presses Callback #13

{{title}}

{{editor}}'s edit

{{editor}}'s edit

Replies: 8 comments 6 replies

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{title}}

{{editor}}'s edit

{{editor}}'s edit

{{title}}

Select a reply

Short and Long Button Presses Callback #13

m-r-m-s Apr 20, 2022

Replies: 8 comments · 6 replies

luni64 Apr 22, 2022 Maintainer

m-r-m-s Apr 22, 2022 Author

luni64 Apr 23, 2022 Maintainer

m-r-m-s Apr 24, 2022 Author

luni64 Apr 25, 2022 Maintainer

m-r-m-s Apr 26, 2022 Author

m-r-m-s May 5, 2022 Author

luni64 May 7, 2022 Maintainer

m-r-m-s May 7, 2022 Author

luni64 May 9, 2022 Maintainer

m-r-m-s May 10, 2022 Author

m-r-m-s May 24, 2022 Author

luni64 May 25, 2022 Maintainer

m-r-m-s May 25, 2022 Author

m-r-m-s
Apr 20, 2022

Replies: 8 comments 6 replies

luni64
Apr 22, 2022
Maintainer

m-r-m-s Apr 22, 2022
Author

luni64
Apr 23, 2022
Maintainer

m-r-m-s Apr 24, 2022
Author

luni64
Apr 25, 2022
Maintainer

m-r-m-s
Apr 26, 2022
Author

m-r-m-s
May 5, 2022
Author

luni64
May 7, 2022
Maintainer

m-r-m-s May 7, 2022
Author

luni64
May 9, 2022
Maintainer

m-r-m-s May 10, 2022
Author

m-r-m-s May 24, 2022
Author

luni64
May 25, 2022
Maintainer

m-r-m-s May 25, 2022
Author