formatting.gradle

allprojects {
    spotless {
        java {
            // Normally this isn't necessary, but we have Java sources in
            // non-standard places
            target '**/*.java'

            removeUnusedImports()
            importOrder(
                    'de.thetaphi',
                    'com.carrotsearch',
                    'com.fasterxml',
                    'com.avast',
                    'com.sun',
                    'com.maxmind|com.github|com.networknt|groovy|nebula',
                    'org.antlr',
                    'software.amazon',
                    'com.azure|com.microsoft|com.ibm|com.google|joptsimple|org.apache|org.bouncycastle|org.codehaus|org.opensearch|org.objectweb|org.joda|org.hamcrest|org.openjdk|org.gradle|org.junit',
                    'javax',
                    'java',
                    '',
                    '\\#java|\\#org.opensearch|\\#org.hamcrest|\\#'
            )
            eclipse().configFile rootProject.file('formatter/formatterConfig.xml')
            trimTrailingWhitespace()
            endWithNewline();

            // See DEVELOPER_GUIDE.md for details of when to enable this.
            if (System.getProperty('spotless.paddedcell') != null) {
                paddedCell()
            }
        }
        format 'misc', {
            target '*.md', '*.gradle', '**/*.json', '**/*.yaml', '**/*.yml', '**/*.svg'

            trimTrailingWhitespace()
            endWithNewline()
            indentWithSpaces()
        }
        format("license", {
            licenseHeaderFile("${rootProject.file("formatter/license-header.txt")}", "package ");
            target("src/*/java/**/*.java")
        })
    }
}