nf_rnaseq

#!/usr/bin/env nextflow
nextflow.enable.dsl=2


/* ========================================================================================
    OUTPUT DIRECTORY
======================================================================================== */
params.outdir = false
if(params.outdir){
    outdir = params.outdir
} else {
    outdir = '.'
}


/* ========================================================================================
    PARAMETERS
======================================================================================== */
params.genome       = ''
params.strand       = 'reverse' // default is reverse
params.verbose      = false
params.single_end   = false  // default mode is auto-detect. NOTE: params are handed over automatically  
params.help         = false
params.list_genomes = false

params.fastqc_args         = ''
params.fastq_screen_args   = ''
params.trim_galore_args    = ''
params.hisat2_args         = ''
params.featurecounts_args  = ''
params.multiqc_args        = ''
params.samtools_sort_args  = ''
params.samtools_index_args = '' 


/* ========================================================================================
    MESSAGES
======================================================================================== */
// Show help message and exit
if (params.help){
    helpMessage()
    exit 0
}

// Validate strandedness
assert params.strand == 'forward' || params.strand == 'reverse' || params.strand == 'unstranded' || params.strand == 'smartseq2' : "Invalid strand orientation option: >>${params.strand}<<. Valid options are: 'forward', 'reverse', 'unstranded' or 'smartseq2'\n\n"
println ("Using strand orientation: " + params.strand)

if (params.list_genomes){
    println ("[WORKLFOW] List genomes selected")
}

if (params.verbose){
    println ("[WORKFLOW] FASTQC ARGS: "            + params.fastqc_args)
    println ("[WORKFLOW] FASTQ SCREEN ARGS ARE: "  + params.fastq_screen_args)
    println ("[WORKFLOW] TRIM GALORE ARGS: "       + params.trim_galore_args)
    println ("[WORKFLOW] HISAT2 ARGS ARE: "        + params.hisat2_args)
    println ("[WORKFLOW] SAMTOOLS SORT ARGS: "     + params.samtools_sort_args)
    println ("[WORKFLOW] SAMTOOLS INDEX ARGS: "    + params.samtools_index_args)
    println ("[WORKFLOW] FEATURECOUNTS ARGS ARE: " + params.featurecounts_args)
    println ("[WORKFLOW] MULTIQC ARGS: "           + params.multiqc_args)
}


/* ========================================================================================
    GENOMES
======================================================================================== */
include { getGenome; listGenomes } from './nf_modules/genomes.mod.nf'

if (params.list_genomes){
    listGenomes()  // this lists all available genomes, and exits
}
genome = getGenome(params.genome)


/* ========================================================================================
    FILES CHANNEL
======================================================================================== */
include { makeFilesChannel; getFileBaseNames } from './nf_modules/files.mod.nf'
file_ch = makeFilesChannel(args)


/* ========================================================================================
    WORKFLOW
======================================================================================== */
include { FASTQC }                     from './nf_modules/fastqc.mod.nf'
include { FASTQC as FASTQC2 }          from './nf_modules/fastqc.mod.nf'
include { FASTQ_SCREEN }               from './nf_modules/fastq_screen.mod.nf'
include { TRIM_GALORE }                from './nf_modules/trim_galore.mod.nf'
include { HISAT2 }                     from './nf_modules/hisat2.mod.nf'  params(genome: genome, bam_output: false)
include { SAMTOOLS_SORT }              from './nf_modules/samtools.mod.nf'  params(bam_output: params.bam_output)
include { SAMTOOLS_INDEX }             from './nf_modules/samtools.mod.nf'  params(bam_output: params.bam_output)
include { FEATURECOUNTS }              from './nf_modules/subread.mod.nf' params(genome: genome, strand: params.strand)
include { FEATURECOUNTS_MERGE_COUNTS } from './nf_modules/subread.mod.nf'
include { MULTIQC }                    from './nf_modules/multiqc.mod.nf' 

workflow {

    main:
        FASTQC                      (file_ch, outdir, params.fastqc_args, params.verbose)
        FASTQ_SCREEN                (file_ch, outdir, params.fastq_screen_args, params.verbose)
        TRIM_GALORE                 (file_ch, outdir, params.trim_galore_args, params.verbose)
        FASTQC2                     (TRIM_GALORE.out.reads, outdir, params.fastqc_args, params.verbose)
        HISAT2                      (TRIM_GALORE.out.reads, outdir, params.hisat2_args, params.verbose)
        SAMTOOLS_SORT               (HISAT2.out.bam, outdir, params.samtools_sort_args, params.verbose)
        SAMTOOLS_INDEX              (SAMTOOLS_SORT.out.bam, outdir, params.samtools_index_args, params.verbose)
        FEATURECOUNTS               (SAMTOOLS_SORT.out.bam, HISAT2.out.single_end, outdir, params.featurecounts_args, params.verbose)

        featurecounts_merge_counts_ch = FEATURECOUNTS.out.counts.collect()
        FEATURECOUNTS_MERGE_COUNTS  (featurecounts_merge_counts_ch, outdir, params.verbose)

        // merging channels for MultiQC
        multiqc_ch = FASTQC.out.report.mix(
            TRIM_GALORE.out.report,
            FASTQ_SCREEN.out.report.ifEmpty([]),
            FASTQC2.out.report.ifEmpty([]),
            HISAT2.out.stats.ifEmpty([]),
            FEATURECOUNTS.out.summary.ifEmpty([]),
        ).collect()

        MULTIQC                          (multiqc_ch, outdir, params.multiqc_args, params.verbose)
}

workflow.onComplete {

    def msg = """\
        Pipeline execution summary
        ---------------------------
        Jobname     : ${workflow.runName}
        Completed at: ${workflow.complete}
        Duration    : ${workflow.duration}
        Success     : ${workflow.success}
        workDir     : ${workflow.workDir}
        exit status : ${workflow.exitStatus}
        """
    .stripIndent()

    sendMail(to: "${workflow.userName}@ethz.ch", subject: 'Minimal pipeline execution report', body: msg)
}


/* ========================================================================================
    HELP MESSAGE
======================================================================================== */
def helpMessage() {
 
    log.info"""
    >>

    SYNOPSIS:

    In a nutshell, this workflow runs an entire RNA-seq processing pipeline on FastQ files, including QC, contamination QC,
    quality-/adapter trimming, splice -aware alignments to a genome using HISAT2, and finally generate an aggregate QC report.
    The workflow is suitable for RNA-seq data, or any other form of sequencing that requires standard alignments to a genome
    when you would like to use HISAT2 as the underlying aligner (in such a case you might want to consider turning off spliced
    alignments). Here is a graphical representation of the workflow:

    --- FastQC
    --- FastQ Screen
    --- Trim Galore
        |
        --- FastQC
        --- HISAT2 
            |
            --- Samtools sort
            --- Samtools index
                |
                featureCounts
    --- MultiQC*
        
    * This step runs only once ALL other jobs have completed.

    By default, the involved tools are run in the following way:
    ------------------------------------------------------------
    FastQC:         defaults (-q)
    FastQ Screen:   defaults (Bowtie 2; local mode)
    Trim Galore:    defaults (adapter auto-detection)
    HISAT2:         end-to-end mode ('--no-softclip'); '--no-unal'; for PE files: '--no-mixed --no-discordant' (concordant PE alignmnents only)
    featureCounts:  defaults (-B -C)
    Samtools sort:  defaults
    Samtools index: defaults
                    
    To add additional parameters to any of the programs, consider supplying tool-specific arguments (see --toolname_args="..." below).

            
    ==============================================================================================================


    USAGE:
    
    nf_rnaseq [options] --genome <genomeID> <input files>
    
    Mandatory arguments:
    ====================

      <input files>                   List of input files, e.g. '*fastq.gz' or '*fq.gz'. Files are automatically processed as
                                      single-end (SE) or paired end (PE) files (if file pairs share the same base-name, and differ only
                                      by a read number, e.g. 'base_name_R1.fastq.gz' and 'base_name_R2.fastq.gz' (or R3, R4). For
                                      PE files, only Read 1 is run through FastQ Screen (as typically R1 and R2 produce nearly identical
                                      contamination profiles). To run PE files in single-end mode, please see '--single_end' below.

      --genome [str]                  Genome build ID to be used for the alignment, e.g. GRCh38 (latest human genome) or GRCm38
                                      (latest mouse genome build). To list all available genomes, see '--list_genomes' below.


    Tool-specific options:
    ======================

    For all following options, please note that the format: ="your options" needs to be strictly adhered to in order to work correctly.

      --fastqc_args="[str]"           This option can take any number of options that are compatible with FastQC to modify its default
                                      behaviour. For more detailed information on available options please refer to the FastQC documentation,
                                      or run 'fastqc --help' on the command line. As an example, to run FastQC without grouping of bases when
                                      reads are >50bp and use a specific file with non-default adapter sequences, use: 
                                      ' --fastqc_args="--nogroup --adapters ./non_default_adapter_file.txt" '. [Default: None]

      --fastq_screen_args="[str]"     This option can take any number of options that are compatible with FastQ Screen to modify its
                                      default behaviour. For more detailed information on available options please refer to the FastQ Screen
                                      documentation, or run 'fastq_screen --help' on the command line. For instance, to process a bisulfite
                                      converted library with fairly relaxed parameters, you could use: 
                                      ' --fastq_screen_args="--bisulfite --score_min L,0,-0.6" '. [Default: None]

      --trim_galore_args="[str]"      This option can take any number of options that are compatible with Trim Galore to modify its
                                      default trimming behaviour. For more detailed information on available options please refer
                                      to the Trim Galore User Guide, or run 'trim_galore --help' on the command line. As an example, to trim
                                      off the first 10bp from the 5' of R1 and 5bp of R2, use: 
                                      ' --trim_galore_args="--clip_r1 10 --clip_r2 5" '. [Default: None]

      --hisat2_args="[str]"           This option can take any number of options that are compatible with HISAT2 to modify its
                                      default mapping behaviour. For more detailed information on available options please refer
                                      to the HISAT2 User Guide, or run 'hisat2 --help' on the command line. As an example, to disable
                                      spliced alignments and tolerate a miximum fragment length of 1500 bp, use: 
                                      ' --hisat2_args="--no-spliced-alignment --maxins 1500" '. [Default: None]

      --featurecounts_args="[str]"    This option can take any number of options that are compatible with featureCounts to modify its
                                      default mapping behaviour. For more detailed information on available options please refer
                                      to the featureCounts User Guide, or run 'featureCounts --help' on the command line. 
                                      As an example, to change the minimum number of overlapping bases in a read
                                      that is required for read assignment to 5, use: 
                                      ' --featurecounts_args="--minOverlap 5" '. [Default: --minOverlap 1]

      --samtools_sort_args="[str]"    This option can take any number of options that are compatible with 'samtools sort' to modify its default
                                      behaviour. For more detailed information on available options please refer to the Samtools documentation,
                                      or run 'samtools sort' on the command line. Please note that the format ="your options" needs to be
                                      strictly adhered to in order to work correctly. [Default: None]

      --samtools_index_args="[str]"   This option can take any number of options that are compatible with 'samtools index' to modify its
                                      default behaviour. For more detailed information on available options please refer
                                      to the Samtools documentation, or run 'samtools index' on the command line. Please note that the format 
                                      ="your options" needs to be strictly adhered to in order to work correctly. [Default: None]                                          
   

    Other options:
    ==============

      --outdir [str]                  Path to the output directory. [Default: current working directory]

      --list_genomes                  List all genome builds that are currently available to choose from. To see this list
                                      of available genomes with more detailed information about paths and indexes, run
                                      the command as '--list_genomes --verbose'
    
      --single_end                    Force files of a read pair to be treated as single-end files. [Default: auto-detect]
      
      --verbose                       More verbose status messages. [Default: OFF]
      --help                          Displays this help message and exits.


    Workflow options:
    =================

    Please note the single '-' hyphen for the following options!

      -resume                         If a pipeline workflow has been interrupted or stopped (e.g. by accidentally closing a laptop),
                                      this option will attempt to resume the workflow at the point it got interrupted by using
                                      Nextflow's caching mechanism. This may save a lot of time.

      -bg                             Sends the entire workflow into the background, thus disconnecting it from the terminal session.
                                      This option launches a daemon process (which will keep running on the headnode) that watches over
                                      your workflow, and submits new jobs to the SLURM queue as required. Use this option for big pipeline
                                      jobs, or whenever you do not want to watch the status progress yourself. Upon completion, the
                                      pipeline will send you an email with the job details. This option is HIGHLY RECOMMENDED!

      -process.executor=local         Temporarily changes where the workflow is executed to the 'local' machine. See also Nextflow config
                                      file for more details. [Default: slurm] 
    
    <<
    """.stripIndent()
}