Problem with startTrasmit again

[sexton10]

Hello, I have a stupid problem that I can not solve. Ι use new example PingPong. The example work great with delay, but for my work i want millis(). With millis cant make startTrasmit again. What a mistake I have made? Thanks .

#include<RadioLib.h>

SX1262 radio = new Module(10, 2, 3, 9);


int transmissionState = ERR_NONE;

bool transmitFlag = false;
volatile bool enableInterrupt = true;
volatile bool operationDone = false;

unsigned long SendTime = 1000;
unsigned long PreviousSend = 0;

void setFlag(void) {
  if(!enableInterrupt) {
    return;
  }
  operationDone = true;
}

void setup() {
  Serial.begin(9600);

  Serial.print(F("[SX1262] Initializing ... "));
  int state = radio.begin();
  if (state == ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true);
  }

  radio.setDio1Action(setFlag);

    transmissionState = radio.startTransmit("Hello World!");
    transmitFlag = true;
}

void loop() {

  unsigned long currentMillis = millis();

 
  if(operationDone) {
    enableInterrupt = false;
    operationDone = false;

    if(transmitFlag) {
      if (transmissionState == ERR_NONE) {
        Serial.println(F("transmission finished!"));
  
      } else {
        Serial.print(F("failed, code "));
        Serial.println(transmissionState);
  
      }
      radio.startReceive();
      transmitFlag = false;
      
    } else {
      String str;
      int state = radio.readData(str);

      if (state == ERR_NONE) {
        // packet was successfully received
        Serial.println(F("[SX1262] Received packet!"));
      
        // print data of the packet
        Serial.print(F("[SX1262] Data:\t\t"));
        Serial.println(str);
  
        // print RSSI (Received Signal Strength Indicator)
        Serial.print(F("[SX1262] RSSI:\t\t"));
        Serial.print(radio.getRSSI());
        Serial.println(F(" dBm"));
  
        // print SNR (Signal-to-Noise Ratio)
        Serial.print(F("[SX1262] SNR:\t\t"));
        Serial.print(radio.getSNR());
        Serial.println(F(" dB")); 
      }      
      if(currentMillis - PreviousSend > SendTime)
      {
        PreviousSend = currentMillis;
      transmissionState = radio.startTransmit("Hello World!");
      transmitFlag = true;
      }
     }
    enableInterrupt = true;   
  }
}

[jgromes]

Probably because you have placed the if() condition that checks the timing value inside the if(operationDone) block. Therefore, you will only check the timer value when you get an interrupt.

Try placing it in the loop() block.

[sexton10]

Thanks for the prompt reply. You mean :

void loop() {

  unsigned long currentMillis = millis();

 while(currentMillis - PreviousSend > SendTime)
      {
        PreviousSend = currentMillis;
  if(operationDone) {
    enableInterrupt = false;
    operationDone = false;

    if(transmitFlag) {
      if (transmissionState == ERR_NONE) {
        Serial.println(F("transmission finished!"));
  
      } else {
        Serial.print(F("failed, code "));
        Serial.println(transmissionState);
  
      }
      radio.startReceive();
      transmitFlag = false;
      
    } else {
      String str;
      int state = radio.readData(str);

      if (state == ERR_NONE) {
        // packet was successfully received
        Serial.println(F("[SX1262] Received packet!"));
      
        // print data of the packet
        Serial.print(F("[SX1262] Data:\t\t"));
        Serial.println(str);
  
        // print RSSI (Received Signal Strength Indicator)
        Serial.print(F("[SX1262] RSSI:\t\t"));
        Serial.print(radio.getRSSI());
        Serial.println(F(" dBm"));
  
        // print SNR (Signal-to-Noise Ratio)
        Serial.print(F("[SX1262] SNR:\t\t"));
        Serial.print(radio.getSNR());
        Serial.println(F(" dB")); 
      }      
      
        
      transmissionState = radio.startTransmit("Hello World!");
      transmitFlag = true;
      }
   
    enableInterrupt = true;   
  }
}
}

If you mean this i make it and print this and stop.

[jgromes]

No, that's not what I meant - I never mentioned a while loop (why are you trying to write code you don't seem to understand?). This is what I meant:

void loop() {
  if(millis() - PreviousSend > SendTime) {
    PreviousSend = currentMillis;
    transmissionState = radio.startTransmit("Hello World!");
    transmitFlag = true;
  }
  
  if(operationDone) {
   ...
  }
}

[sexton10]

thank you very much, it works.