build.gradle

plugins {
	id 'org.springframework.boot' version '2.7.9'
	id 'io.spring.dependency-management' version '1.0.11.RELEASE'
	id 'java'
	id 'idea'
	id "com.github.node-gradle.node" version "3.1.1"
	id "org.owasp.dependencycheck" version "7.0.4.1" //for security scanning of dependencies
}

group = 'com.jmonkeyengine'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '17'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

dependencyCheck {
	failBuildOnCVSS=5
}

bootJar {
	//this config is basically to get it to stop putting "-0.0.0-SNAPSHOT" on the end of the jar name
	archiveFileName = "${archiveBaseName.get()}.${archiveExtension.get()}"
}

node {
	download = true
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-actuator'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springdoc:springdoc-openapi-ui:1.6.4'
	implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.17.1'
	implementation group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.17.1'
	implementation group: 'org.apache.commons', name: 'commons-text', version: '1.10.0'
	implementation group: 'com.google.guava', name: 'guava', version: '31.0.1-jre'
	compileOnly 'org.projectlombok:lombok'

	implementation 'com.fasterxml.jackson.module:jackson-module-jsonSchema:2.13.2'
	implementation 'org.apache.commons:commons-collections4:4.4'
	implementation 'org.apache.commons:commons-compress:1.21' //commons-compress allows us to set executable permissions for use on linux

	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.junit.jupiter:junit-jupiter-api:5.0.3'
	testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.0.3'
}

test {
	useJUnitPlatform()
}

task buildReactApp(type: NodeTask, dependsOn: 'npmInstall') {
	script = project.file('node_modules/webpack/bin/webpack.js')
	args = [
			'--mode', 'development',
			'--entry', './src/main/resources/react/reactGameForm.jsx',
			'-o', './src/main/resources/static/js/dist/'
	]
}

test {
	useJUnitPlatform {
		excludeTags 'TemplateTests'
	}
}

task templateTest(type: Test)  {
	useJUnitPlatform {
		includeTags 'TemplateTests'
	}
}

processResources.dependsOn 'buildReactApp'
clean.delete << file('node_modules')
clean.delete << file('src/main/resources/static/js/dist')