build.gradle

plugins {
    id 'com.android.application'
    id 'kotlin-android'
}


apply from: '../signing/signing.gradle'
apply from: '../dependencies.gradle'

android {
    compileSdk rootProject.ext.compileSdkVersion

    defaultConfig {
        namespace = "net.helpscout.samples.beacon"
        applicationId "net.helpscout.samples.beacon.kotlin"

        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.targetSdkVersion

        versionCode 1
        versionName "1.0"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    sourceSets {
        main.java.srcDirs += 'src/main/kotlin'
        test.java.srcDirs += 'src/test/kotlin'
    }

    buildFeatures {
        viewBinding = true
    }

    buildTypes {
        debug {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
        release {
            signingConfig signingConfigs.release
            // Beacon SDK supports Proguard, no additional config is needed.
            // Since version 2.3.2 support for proguard-android-optimize.txt
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        // Since SDK 4.0.0 we moved to Android Gradle Plugin 7.x which requires the sourceCompatibility and
        // targetCompatibility to Java 11
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    kotlinOptions {
        // recommend Kotlin jvm target to be Java 11
        jvmTarget = JavaVersion.VERSION_11.toString()
    }

    lint {
        disable 'MissingTranslation'
        ignoreWarnings true
    }
}

dependencies {
    implementation "com.google.android.material:material:$materialVersion"
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlinVersion"

    // Add this to your dependencies to install Beacon SDK to your app
    implementation "com.helpscout:beacon:$beaconVersion"

    testImplementation "junit:junit:$jUnitVersion"
}