build.gradle

apply {
    plugin "base"
    plugin "java"
    plugin "checkstyle"
    plugin "jacoco"
    plugin "idea"
    plugin "eclipse"
}

task wrapper(type: Wrapper) {
  gradleVersion = '4.6'
}

repositories {
    mavenLocal()
    mavenCentral()
}

sourceCompatibility = JavaVersion.VERSION_1_8
group = "io.krakens"
archivesBaseName = "java-grok"

ext {
    checkStyleToolVersion = "6.19"
    jacocoToolVersion = "0.7.9"

    commonsLang3Version = "3.7"

    junitVersion = "4.12"
    assertjVersion = "3.9.1"
    guavaVersion = "24.0-jre"
}

dependencies {
    compile "org.apache.commons:commons-lang3:$commonsLang3Version"

    testCompile "junit:junit:$junitVersion"
    testCompile "org.assertj:assertj-core:$assertjVersion"
    testCompile "com.google.guava:guava:$guavaVersion"
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

// Needed to avoid including all the jar signing and sonatype setup.
if (project.hasProperty("withDeployment")) {
    apply from: "$rootProject.projectDir/gradle/sonatype.gradle"
}

checkstyle {
    configFile = file("${project.projectDir}/extra/checkstyle/checkstyle.xml")
    toolVersion = "$checkStyleToolVersion"
}

checkstyleMain {
    source = 'src/main/java'
    doLast {
        project.ext.checkType = "main"
    }
}

jacoco {
    toolVersion = "$jacocoToolVersion"
}

jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
    }
}