build.gradle

//
//
allprojects {
	apply plugin: 'maven'
	apply plugin: 'java'
	apply plugin: 'maven-publish'

	group = 'com.peterlavalle' // group = 'org.flexdock'

	version = '1.3'

	sourceCompatibility = 1.7
	targetCompatibility = 1.7

	repositories {
		maven { url "https://oss.sonatype.org/content/repositories/snapshots" }
		mavenCentral()
		jcenter()
		maven { url "http://peterlavalle.com/m2-repo/" }
	}

	tasks.withType(JavaCompile) {
		options.encoding = 'UTF-8'
	}

	publishing {
		repositories {
			maven { url project.rootProject.file('.m2repo/') }
		}

		publications {
			mavenJava(MavenPublication) {
				from components.java
			}
		}
	}
}

subprojects {

	task packageSources(type: Jar) {
		classifier = 'sources'
		from sourceSets.main.allSource
	}

	artifacts.archives packageSources

	configurations.all {
	}

	dependencies {
		compile group: 'net.sf.squirrel-sql.thirdparty-non-maven', name: 'skinlf', version: '6.7'
	}
}

project(':flexdock-demo') {
	jar {
		manifest {
			attributes 'Main-Class': 'org.flexdock.demos.AllDemos'
		}

		from {
			configurations.compile.collect {
				it.isDirectory() ? it : zipTree(it)
			}
		}
	}

	dependencies {
		compile project(':flexdock-core')
		compile group: 'com.jgoodies', name: 'jgoodies-looks', version: '2.7.0'
		compile project(':flexdock-view')
		compile project(':flexdock-perspective')
		compile project(':flexdock-drag')
		compile group: 'javax.media', name: 'jmf', version: '2.1.1e'
	}
}

project(':flexdock-drag') {
	dependencies {
		compile project(':flexdock-core')
	}
}

project(':flexdock-perspective') {
	dependencies {
		compile project(':flexdock-core')
	}
}

project(':flexdock-view') {
	dependencies {
		compile project(':flexdock-core')
		compile project(':flexdock-perspective')
	}
}