From fb5afd6252132e881e1179316cde9c522b59e993 Mon Sep 17 00:00:00 2001
From: condy <condy0919@gmail.com>
Date: Sat, 10 Jul 2021 02:59:00 +0800
Subject: [PATCH] Add "zg" and "zG" bindings

Implements evil-ispell-mark-word-as-good and evil-ispell-mark-word-as-locally-good
---
 evil-commands.el | 33 +++++++++++++++++++++++++++++++++
 evil-maps.el     |  2 ++
 2 files changed, 35 insertions(+)

diff --git a/evil-commands.el b/evil-commands.el
index 477ee49c6..d544c9ae7 100644
--- a/evil-commands.el
+++ b/evil-commands.el
@@ -33,6 +33,7 @@
 (require 'evil-jumps)
 (require 'evil-vars)
 (require 'flyspell)
+(require 'ispell)
 (require 'cl-lib)
 (require 'reveal)
 
@@ -636,6 +637,38 @@ and jump to the corresponding one."
           (when ov
             (goto-char (overlay-start ov))))))))
 
+(defun evil-ispell-mark-word-as-good (word)
+  "Add WORD under the cursor as a good word to the Ispell dictionary."
+  (interactive (list (substring-no-properties (thing-at-point 'word))))
+  ;; accept and insert word into personal dictionary.
+  (ispell-send-string (concat "*" word "\n"))
+  ;; dictionary modified!
+  (setq ispell-pdict-modified-p '(t))
+  (ispell-pdict-save ispell-silently-savep)
+  (when (bound-and-true-p flyspell-mode)
+    (let ((start (car (bounds-of-thing-at-point 'word))))
+      (when start
+        (flyspell-unhighlight-at start))))
+  (message "Word '%s' added to personal dictionary" (upcase word)))
+
+(defun evil-ispell-mark-word-as-locally-good (word &optional buffer-local)
+  "Add WORD under the cursor to the session dictionary.
+If BUFFER-LOCAL is non-nil, the word will be added to current buffer."
+  (interactive (list (substring-no-properties (thing-at-point 'word)) current-prefix-arg))
+  ;; accept word without insertion
+  (ispell-send-string (concat "@" word "\n"))
+  (add-to-list 'ispell-buffer-session-localwords word)
+  ;; session localwords might conflict.
+  (unless ispell-buffer-local-name
+    (setq ispell-buffer-local-name (buffer-name)))
+  (when buffer-local
+    (ispell-add-per-file-word-list word))
+  (when (bound-and-true-p flyspell-mode)
+    (let ((start (car (bounds-of-thing-at-point 'word))))
+      (when start
+        (flyspell-unhighlight-at start))))
+  (message "Word '%s' added to local dictionary" (upcase word)))
+
 (evil-define-motion evil-next-flyspell-error (count)
   "Go to the COUNT'th spelling mistake after point."
   (interactive "p")
diff --git a/evil-maps.el b/evil-maps.el
index 7429acdb1..7e9875e38 100644
--- a/evil-maps.el
+++ b/evil-maps.el
@@ -82,6 +82,8 @@
 (define-key evil-normal-state-map "za" 'evil-toggle-fold)
 (define-key evil-normal-state-map "zr" 'evil-open-folds)
 (define-key evil-normal-state-map "zm" 'evil-close-folds)
+(define-key evil-normal-state-map "zg" 'evil-ispell-mark-word-as-good)
+(define-key evil-normal-state-map "zG" 'evil-ispell-mark-word-as-locally-good)
 (define-key evil-normal-state-map "z=" 'ispell-word)
 (define-key evil-normal-state-map "\C-n" 'evil-paste-pop-next)
 (define-key evil-normal-state-map "\C-p" 'evil-paste-pop)