build.gradle

// vim: ft=groovy
import org.kt3k.gradle.plugin.coveralls.domain.CoberturaSourceReportFactory

ext.coberturaSourceReportFactory = new CoberturaSourceReportFactory()
project(':').ext.map = [:]

defaultTasks 'clean', 'build', 'allTestReport'
description = 'Gradle configuration for stubby4j'

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.bmuschko:gradle-nexus-plugin:2.3'
        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.3.1'
        classpath 'info.solidsoft.gradle.pitest:gradle-pitest-plugin:1.1.4'
    }
}

allprojects {
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'eclipse'
    project.buildDir = 'target'
}

subprojects {
    subproject ->
        repositories {
            mavenLocal()
            mavenCentral()
            jcenter()
        }
        sourceCompatibility = 1.8
        targetCompatibility = 1.8
        [compileJava, compileTestJava]*.options*.encoding = 'UTF-8'
        [compileJava]*.options*.compilerArgs = [
                "-Xlint:-varargs", "-Xlint:cast", "-Xlint:classfile",
                "-Xlint:dep-ann", "-Xlint:divzero", "-Xlint:empty", "-Xlint:finally",
                "-Xlint:overrides", "-Xlint:path", "-Xlint:processing",
                "-Xlint:try", "-Xlint:-fallthrough", "-Xlint:-rawtypes", "-Xlint:-deprecation",
                "-Xlint:-unchecked", "-Xlint:-options"]
        apply from: "$rootDir/conf/gradle/dependency.gradle"
}

apply from: "$rootDir/conf/gradle/ides.gradle"
apply from: "$rootDir/conf/gradle/tasks.gradle"