build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:3.3.1'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:2.1'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}


plugins {
    id "com.diffplug.gradle.spotless" version "3.16.0"
}


allprojects {
    repositories {
        google()
        jcenter()
    }
}

subprojects {
    if (it.name != 'app') {
        apply plugin: 'com.diffplug.gradle.spotless'
        spotless {
            java {
                target fileTree('.') {
                    include '**/*.java'
                }
                googleJavaFormat('1.7').aosp()
                licenseHeaderFile project.rootProject.file('spotless/copyright.java')
            }
        }
    } else {
        apply plugin: 'com.diffplug.gradle.spotless'
        spotless {
            java {
                target '**/*.java'
                googleJavaFormat('1.7').aosp()
            }
        }
    }
}


ext {
    android = [
            compileSdkVersion: 28,
            buildToolsVersion: "28.0.3",
            minSdkVersion    : 14,
            targetSdkVersion : 28,
            versionCode      : 2,
            versionName      : "0.0.2"
    ]
    libs = [
            appcompatV7 : "com.android.support:appcompat-v7:28.0.0",
    ]
    bintray = [
            siteUrl       : 'https://github.com/dkzwm/EasySwipeLayout',
            gitUrl        : 'https://github.com/dkzwm/EasySwipeLayout.git',
            groupId       : "me.dkzwm.widget.esl",
            libVersion    : android.versionName,
            developerId   : "dkzwm",
            developerName : "Zhang Weiming",
            developerEmail: "aidkzwm@gmail.com",
            licenseName   : "MIT License",
            licenseUrl    : "https://opensource.org/licenses/MIT",
    ]
    allLicenses = ['MIT']
}